Pileus Git - ~andy/fetchmail/blob - configure.ac

   1 dnl Autoconfigure input file for fetchmail
   2 #
   3 # Fetchmail automatic configuration support
   4 #
   5 # Eric S. Raymond <esr@thyrsus.com>
   6 # 2004 - 2010 Matthias Andree <matthias.andree@gmx.de>
   7 #
   8 dnl Process this file with autoconf to produce a configure script.
   9 dnl
  10
  11 dnl XXX - if bumping version here, check fetchmail.man, too!
  12 AC_INIT([fetchmail],[6.3.17],[fetchmail-users@lists.berlios.de])
  13 AC_CONFIG_SRCDIR([fetchmail.h])
  14 AC_CONFIG_HEADERS([config.h])
  15 AC_CONFIG_LIBOBJ_DIR([.])
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl automake options are in Makefile.am
  20 AC_PREREQ(2.60)
  21 dnl 2.60 required for AC_USE_SYSTEM_EXTENSIONS
  22 AM_INIT_AUTOMAKE
  23
  24 dnl python is optional
  25 #
  26 # you can pass PYTHON=: in environment or on the command line
  27 # to disable python detection and continue without building/installing
  28 # fetchmail.conf -- be sure to check README.packaging, too!
  29 #
  30 AM_PATH_PYTHON(2.0,,AC_MSG_WARN([Disabling fetchmailconf: python 2.0 or greater not found]))
  31 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
  32
  33 AC_PROG_AWK
  34 AC_PROG_CC
  35 AM_PROG_CC_C_O
  36 AC_PROG_INSTALL
  37 AC_PROG_CPP                     dnl Later checks need this.
  38 AC_PROG_RANLIB
  39 AM_PROG_CC_C_O
  40 AC_USE_SYSTEM_EXTENSIONS
  41
  42 AC_ISC_POSIX
  43 dnl AC_ISC_POSIX: - XXX FIXME: remove in fetchmail 6.4.
  44 dnl This macro adds `-lcposix' to output variable `LIBS' if necessary
  45 dnl for Posix facilities.  Sun dropped support for the obsolete
  46 dnl INTERACTIVE Systems Corporation Unix on 2006-07-23.  New programs
  47 dnl need not use this macro.  It is implemented as
  48 dnl `AC_SEARCH_LIBS([strerror], [cposix])'
  49
  50 dnl check for b0rked Solaris (and other shells) and find one that works
  51 AC_MSG_CHECKING(for a working shell...)
  52 for i in /usr/xpg6/bin/sh /usr/xpg4/bin/sh /usr/ccs/bin/sh /bin/sh /usr/bin/sh /bin/ksh /bin/bash /usr/local/bin/bash ; do
  53     $i -c 'if ! false ; then echo $(echo ok) ; fi' >config.$$ 2>/dev/null
  54     j=`cat config.$$`
  55     rm -f config.$$
  56     if test "x$j" = "xok" ; then
  57         SHELL=$i
  58         AC_SUBST(SHELL)
  59         break
  60     fi
  61 done
  62 AC_MSG_RESULT($SHELL)
  63 if test "x$SHELL" = "x" ; then
  64     AC_MSG_ERROR(no SUS compliant shell found - on Solaris, install SUNWxcu4)
  65 fi
  66
  67
  68 AC_HEADER_STDC
  69 AC_HEADER_TIME
  70 AC_TYPE_SIZE_T
  71 AC_TYPE_PID_T
  72 AC_TYPE_SIGNAL
  73 AC_CHECK_HEADERS([unistd.h termios.h termio.h sgtty.h stdarg.h \
  74         sys/itimer.h fcntl.h sys/fcntl.h memory.h sys/wait.h \
  75         arpa/inet.h arpa/nameser.h netinet/in.h net/socket.h netdb.h \
  76         sys/select.h sys/socket.h sys/time.h langinfo.h md5.h])
  77 if test _$ac_cv_header_stdarg_h != _yes ; then
  78 AC_MSG_WARN([stdarg.h is not defined. Unsupported configuration, proceed at your own risk.])
  79 fi
  80 AC_CHECK_TYPE(u_int32_t,,
  81         AC_DEFINE(u_int32_t,unsigned int,
  82                 [Define to unsigned int if <sys/types.h> does not define.]),
  83         [AC_INCLUDES_DEFAULT
  84 #ifdef HAVE_ARPA_NAMESER_H
  85 #include <arpa/nameser.h>
  86 #endif])
  87 AC_CHECK_HEADERS([resolv.h],,,[
  88 #include <sys/types.h>
  89 #ifdef HAVE_NETINET_IN_H
  90 #include <netinet/in.h>
  91 #endif
  92 #ifdef HAVE_ARPA_NAMESER_H
  93 #include <arpa/nameser.h>
  94 #endif
  95 ])
  96
  97 AC_CHECK_DECLS([h_errno],,,[
  98         AC_INCLUDES_DEFAULT
  99         #ifdef HAVE_NETDB_H
 100         #include <netdb.h>
 101         #endif
 102 ])
 103
 104 AC_C_CONST                      dnl getopt needs this.
 105
 106 AM_PROG_LEX
 107 AC_PROG_MAKE_SET
 108 AC_PROG_YACC
 109
 110 # Check for OS special cases
 111 case $host_os in
 112 darwin*)
 113     AC_MSG_NOTICE(found Darwin - Adding -DBIND_8_COMPAT to CFLAGS)
 114     CPPFLAGS="$CPPFLAGS -DBIND_8_COMPAT"
 115     ;;
 116 # Check for FreeBSD special case: more libs needed
 117 freebsd*)
 118     AC_MSG_NOTICE(found FreeBSD - Adding -lkvm -lcom_err to standard libraries)
 119     LIBS="$LIBS -lkvm -lcom_err"
 120     ;;
 121 # Check for LynxOS special case: -lbsd needed (at least on 2.3.0) and -s
 122 # not working.
 123 lynxos*)
 124     AC_MSG_NOTICE(found LynxOS - Adding -lbsd to standard libraries)
 125     LIBS="$LIBS -lbsd"
 126     LDFLAGS=`echo $LDFLAGS | sed "s/-s //"`
 127     AC_MSG_NOTICE(found LynxOS - Prepending standard include path to gcc flags)
 128     CPPFLAGS="$CPPFLAGS -I/usr/include"
 129     ;;
 130 # Check for Rhapsody special case: it doesn't like -s
 131 rhapsody*)
 132     AC_MSG_NOTICE(found Rhapsody - Removing -s load flag)
 133     LDFLAGS=`echo $LDFLAGS | sed "s/-s //"`
 134     ;;
 135 esac
 136
 137 AC_CACHE_SAVE
 138
 139 dnl i18n
 140 AM_GNU_GETTEXT([external], [need-ngettext])
 141 AM_GNU_GETTEXT_VERSION([0.14.6])
 142 dnl end i18n
 143
 144 # Under sysV68, socket and friends are provided by the C library.
 145 # -linet does not provide socket, but causes multiple definition
 146 # errors at link-time.  It is thus better to only use the C library.
 147 # So don't add -linet to the link list unless it's necessary
 148 AC_CHECK_FUNC(socket,
 149     AC_MSG_RESULT(using libc's socket),
 150     AC_CHECK_LIB(socket,socket)
 151     AC_CHECK_LIB(inet,socket))
 152
 153 # The condition in this test copes with the presence of inet_addr in libc6.
 154 AC_CHECK_FUNC(inet_addr,
 155     AC_MSG_RESULT(using libc's inet_addr),
 156     AC_CHECK_LIB(nsl,inet_addr))
 157
 158 dnl Port hack for Interactive UNIX System V/386 Release 3.2
 159 AC_CHECK_LIB(cposix, strchr,
 160                 [DEFS="$DEFS -D_SYSV3"
 161                 LIBS="$LIBS -lcposix"])
 162
 163 dnl Port hack for Sparc/NetBSD-1.5
 164 dnl
 165 dnl NB: this has been disabled as it causes the unconditional
 166 dnl addition of libintl to the build, which is both undesired
 167 dnl and breaks on Solaris/Blastwave.org machines.
 168 dnl
 169 dnl AC_CHECK_LIB(intl, gettext,
 170 dnl             [LIBS="$LIBS -lintl"])
 171
 172 AC_REPLACE_FUNCS([strstr strcasecmp memmove stpcpy strlcpy strlcat])
 173
 174 have_md5=no
 175 if test "$ac_cv_header_md5_h" != no ; then
 176     AC_SEARCH_LIBS(MD5Init, [md], [have_md5=yes])
 177 fi
 178
 179 if test "$have_md5" != yes ; then
 180     AC_LIBSOURCE(md5c.c)
 181     EXTRAOBJ="$EXTRAOBJ md5c.\$(OBJEXT)"
 182 fi
 183
 184 AC_CHECK_FUNC(getopt_long, [],
 185               [AC_LIBSOURCES([getopt.c, getopt1.c])
 186                EXTRAOBJ="$EXTRAOBJ getopt.\$(OBJEXT) getopt1.\$(OBJEXT)"])
 187
 188 AC_FUNC_VPRINTF
 189
 190 AC_SUBST(EXTRAOBJ)
 191
 192 AC_CHECK_FUNCS(tcsetattr stty setsid geteuid seteuid dnl
 193   strerror syslog snprintf vprintf vsnprintf vsyslog dnl
 194   atexit inet_aton strftime setrlimit socketpair dnl
 195   sigaction strdup setlocale)
 196
 197 AC_CHECK_DECLS([strerror,getenv])
 198 dnl INET6 is used by KAME/getnameinfo
 199 AC_CACHE_CHECK(for AF_INET6/PF_INET6,ac_cv_inet6,
 200 AC_COMPILE_IFELSE([
 201   AC_LANG_PROGRAM([[
 202     #ifdef HAVE_SYS_TYPES_H
 203     #include <sys/types.h>
 204     #endif
 205     #ifdef HAVE_SYS_SOCKET_H
 206     #include <sys/socket.h>
 207     #endif
 208   ]],[[
 209     int foo = AF_INET6;
 210     int bar = PF_INET6;
 211   ]])],
 212   ac_cv_inet6=yes , ac_cv_inet6=no
 213 ))
 214 if test "x$ac_cv_inet6" = xyes
 215 then
 216     AC_DEFINE(INET6,1,Define to 1 if your system defines AF_INET6 and PF_INET6.)
 217 fi
 218
 219 # Under Red Hat 4.0 (and many other Linuxes) -lresolv is seriously flaky
 220 # and breaks gethostbyname(2).  It's better to use the bind stuff in the C
 221 # library.  So don't add -lresolv to the link list unless it's necessary
 222 # (It will be necessary when using GNU libc6).
 223 old_LIBS="$LIBS"
 224 for lib in '' -lresolv; do
 225     if test -z "$lib"; then
 226        AC_MSG_CHECKING([for res_search in libc])
 227     else
 228        AC_MSG_CHECKING([for res_search in $lib])
 229     fi
 230     LIBS="$old_LIBS $lib"
 231     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 232 #include <sys/types.h>
 233 #ifdef HAVE_NETINET_IN_H
 234 #include <netinet/in.h>
 235 #endif
 236 #ifdef HAVE_ARPA_NAMESER_H
 237 #include <arpa/nameser.h>
 238 #endif
 239 #ifdef HAVE_RESOLV_H
 240 #include <resolv.h>
 241 #endif
 242 extern int res_search();
 243 ]], [[res_search(0, 0, 0, 0, 0); dn_skipname(0,0);]])],
 244     [AC_MSG_RESULT([found])
 245      AC_DEFINE(HAVE_RES_SEARCH, [1],
 246                [Define to 1 if you have the 'res_search' and 'dn_skipname' functions.])
 247      break], [AC_MSG_RESULT([not found])])
 248      LIBS=$old_LIBS
 249 done
 250
 251 dnl Check for libcrypt -- it may live in libc or libcrypt, as on IRIX
 252 AC_CHECK_FUNC(crypt, , AC_CHECK_LIB(crypt,crypt))
 253
 254 dnl Check for usable void pointer type
 255 AC_MSG_CHECKING(use of void pointer type)
 256 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[char *p;
 257     void *xmalloc();
 258     p = (char *) xmalloc(1);
 259    ]])],[AC_DEFINE(HAVE_VOIDPOINTER,1,[Define if your C compiler allows void * as a function result]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 260
 261 dnl Check for ANSI volatile
 262 AC_C_VOLATILE
 263
 264 dnl Check out the wait reality.  We have to assume sys/wait.h is present.
 265 AC_CHECK_FUNCS(waitpid wait3)
 266 AC_MSG_CHECKING(for union wait);
 267 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 268 #include <sys/wait.h>]], [[union wait status; int pid; pid = wait (&status);
 269 #ifdef WEXITSTATUS
 270 /* Some POSIXoid systems have both the new-style macros and the old
 271    union wait type, and they do not work together.  If union wait
 272    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 273 if (WEXITSTATUS (status) != 0) pid = -1;
 274 #endif
 275 #ifdef HAVE_WAITPID
 276 /* Make sure union wait works with waitpid.  */
 277 pid = waitpid (-1, &status, 0);
 278 #endif
 279 ]])],[AC_DEFINE(HAVE_UNION_WAIT,1,Define if 'union wait' is the type of the first arg to wait functions.) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 280
 281 AC_MSG_CHECKING(sys_siglist declaration in signal.h or unistd.h)
 282 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>
 283 /* NetBSD declares sys_siglist in <unistd.h>.  */
 284 #ifdef HAVE_UNISTD_H
 285 #include <unistd.h>
 286 #endif]], [[char *msg = *(sys_siglist + 1);]])],[AC_DEFINE(SYS_SIGLIST_DECLARED,1,[Define if 'sys_siglist' is declared by <signal.h>.]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 287
 288 # Find the right directory to put the root-mode PID file in
 289 for dir in "/var/run" "/etc"
 290 do
 291         if test -d $dir
 292         then
 293                 break;
 294         fi
 295 done
 296 AC_MSG_RESULT(root-mode pid file will go in $dir)
 297 AC_DEFINE_UNQUOTED(PID_DIR, "$dir", directory for PID lock files)
 298
 299 # We may have a fallback MDA available in case the socket open to the
 300 # local SMTP listener fails.  Best to use procmail for this, as we know
 301 # it won't try delivering through local SMTP and cause a mail loop.
 302 # Sendmail without the -t option to use the message headers will work too,
 303 # not just for sendmail itself but for workalikes like exim.
 304 #
 305 # Note1: A disadvantage of using procmail is that local alias expansion
 306 # according to /etc/aliases won't get done if we fall back.  This doesn't
 307 # matter in single-drop mode.
 308 #
 309 # Note2: it would be a very bad idea to use any MDA that doesn't return
 310 # a refuse-to-deliver status on disk- or process-table-full
 311 # conditions; mail could get lost that way.  Sendmail and all of the MDAs
 312 # like exim that might be lurking under a sendmail alias) do the right
 313 # thing in this circumstance.  Matthias Andree warns that procmail does
 314 # not.
 315 #
 316 # Note3: Defalt value of fallback is now off.  Matthias writes:
 317 #
 318 # 1. there is no way to predict when the fallback is used. With some MTAs
 319 #    (such as those limiting load average), outer circumstances can cause
 320 #    the fallback to kick in.
 321 #
 322 # 2. the fallback changes fetchmail behaviour in unpredictable ways. It's
 323 #    not only about alias expansion, .forwards to special filters won't
 324 #    work, mail may end up in a different place (users claim "mail loss"
 325 #    for that).
 326 #
 327 # 3. The claim procmail did the right thing with its exit codes is plain
 328 #    wrong. I've seen procmail exit with code 1 when it should have exited
 329 #    with code 75, like, configuration errors. Procmail is a dangerous
 330 #    beast and is best replaced by maildrop.
 331 #
 332 # 4. if multiple choices exist (like procmail and maildrop), fetchmail
 333 #    cannot tell which one it should choose. Say, your MTA is configured
 334 #    to use maildrop to deliver to user's mailboxes, if fetchmail then
 335 #    chooses procmail, this is plain wrong.
 336 #
 337
 338 AC_PATH_PROG(procmail, procmail, "", $PATH:/usr/sbin)
 339 AC_PATH_PROG(sendmail, sendmail, "", $PATH:/usr/sbin:/usr/lib)
 340 AC_PATH_PROG(maildrop, maildrop, "", $PATH:/usr/local/bin)
 341
 342 ###     use option --disable-fallback to disable fallback MDA
 343 ###     use option --enable-fallback=procmail or
 344 ###                --enable-fallback=sendmail to select
 345 AC_ARG_ENABLE(fallback,
 346         [  --enable-fallback=procmail    enable procmail as fallback
 347   --enable-fallback=sendmail    enable /usr/sbin/sendmail as fallback
 348   --enable-fallback=maildrop    enable maildrop as fallback
 349   --enable-fallback=no          disable fallback],,[enable_fallback=no])
 350
 351 case "$enable_fallback" in
 352         sendmail)       if test -z "$sendmail" ; then
 353                                 AC_MSG_ERROR([Sendmail selected as fallback, but not found])
 354                                 #not reached
 355                         fi
 356                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$sendmail -i %T", Fallback MTA to use if defined)
 357                         AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 358                         ;;
 359         procmail)       if test -z "$procmail" ; then
 360                                 AC_MSG_ERROR([procmail selected as fallback, but not found])
 361                                 #not reached
 362                         fi
 363                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$procmail -d %T")
 364                         AC_MSG_NOTICE(Will use $procmail as fallback MDA.)
 365                         ;;
 366         maildrop)       if test -z "$maildrop" ; then
 367                                 AC_MSG_ERROR([maildrop selected as fallback, but not found])
 368                                 #not reached
 369                         fi
 370                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$maildrop -d %T")
 371                         AC_MSG_NOTICE(Will use $maildrop as fallback MDA.)
 372                         ;;
 373         no|unset)       AC_MSG_NOTICE(Will not use a fallback MDA.)
 374                         ;;
 375         auto|yes|set)   if test -n "$sendmail" ; then
 376                                 AC_DEFINE_UNQUOTED(FALLBACK_MDA,"$sendmail -i %T")
 377                                 AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 378                         else
 379                                 AC_MSG_WARN(No fallback MDA available.  procmail and maildrop are not eligible)
 380                                 AC_MSG_WARN(for automatic fallback MDA configuration for reliability reasons.)
 381                         fi
 382                         ;;
 383         *)              AC_MSG_ERROR([unkown value for --enable-fallback given: $enable_fallback])
 384                         #notreached
 385                         ;;
 386 esac
 387
 388 AC_CHECK_SIZEOF(short)
 389 AC_CHECK_SIZEOF(int)
 390 AC_CHECK_SIZEOF(long)
 391
 392 ###     use option --enable-POP2 to compile in the POP2 support
 393 AC_ARG_ENABLE(POP2,
 394         [  --enable-POP2           compile in POP2 protocol support (obsolete)],
 395         [with_POP2=$enableval],
 396         [with_POP2=no])
 397 test "$with_POP2" = "yes" && AC_DEFINE(POP2_ENABLE,1,Define if you want POP2 support compiled in)
 398 AM_CONDITIONAL(POP2_ENABLE, test "$with_POP2" = yes)
 399
 400 ###     use option --disable-POP3 to omit the POP3 support
 401 AC_ARG_ENABLE(POP3,
 402         [  --disable-POP3          don't compile in POP3 protocol support],
 403         [with_POP3=$enableval],
 404         [with_POP3=yes])
 405 test "$with_POP3" = "yes" && AC_DEFINE(POP3_ENABLE,1,Define if you want POP3 support compiled in)
 406 AM_CONDITIONAL(POP3_ENABLE, test "$with_POP3" = yes)
 407
 408 ###     use option --disable-IMAP to omit the IMAP support
 409 AC_ARG_ENABLE(IMAP,
 410         [  --disable-IMAP          don't compile in IMAP protocol support],
 411         [with_IMAP=$enableval],
 412         [with_IMAP=yes])
 413 test "$with_IMAP" = "yes" && AC_DEFINE(IMAP_ENABLE,1,Define if you want IMAP support compiled in)
 414 AM_CONDITIONAL(IMAP_ENABLE, test "$with_IMAP" = yes)
 415
 416 ###     use option --disable-ETRN to omit the ETRN support
 417 AC_ARG_ENABLE(ETRN,
 418         [  --disable-ETRN          don't compile in ETRN protocol support],
 419         [with_ETRN=$enableval],
 420         [with_ETRN=yes])
 421 test "$with_ETRN" = "yes" && AC_DEFINE(ETRN_ENABLE,1,Define if you want ETRN support compiled in.)
 422 AM_CONDITIONAL(ETRN_ENABLE, test "$with_ETRN" = yes)
 423
 424 ###     use option --disable-ODMR to omit the ODMR support
 425 AC_ARG_ENABLE(ODMR,
 426         [  --disable-ODMR          don't compile in ODMR protocol support],
 427         [with_ODMR=$enableval],
 428         [with_ODMR=yes])
 429 test "$with_ODMR" = "yes" && AC_DEFINE(ODMR_ENABLE,1,Define if you want ODMR support compiled in)
 430 AM_CONDITIONAL(ODMR_ENABLE, test "$with_ODMR" = yes)
 431
 432 ###     use option --enable-RPA to compile in the RPA support
 433 AC_ARG_ENABLE(RPA,
 434         [  --enable-RPA            compile in RPA protocol support],
 435         [with_RPA=$enableval],
 436         [with_RPA=no])
 437 test "$with_RPA" = "yes" && AC_DEFINE(RPA_ENABLE,1,Define if you want RPA support compiled in)
 438 AM_CONDITIONAL(RPA_ENABLE, test "$with_RPA" = yes)
 439
 440 ###     use option --enable-NTLM to compile in the NTLM support
 441 AC_ARG_ENABLE(NTLM,
 442         [  --enable-NTLM           compile in NTLM authentication support],
 443         [with_NTLM=$enableval],
 444         [with_NTLM=no])
 445 test "$with_NTLM" = "yes" && AC_DEFINE(NTLM_ENABLE,1,Define if you want NTLM authentication)
 446
 447 ###     use option --enable-SDPS to compile in the SDPS support
 448 AC_ARG_ENABLE(SDPS,
 449         [  --enable-SDPS           compile in SDPS protocol support],
 450         [with_SDPS=$enableval],
 451         [with_SDPS=no])
 452 if test "$with_SDPS" = yes ; then
 453    if test "$with_POP3" != yes ; then
 454        AC_MSG_WARN([SDPS cannot be enabled with POP3 disabled. Disabling SDPS.])
 455        with_SDPS=no
 456    else
 457        AC_DEFINE(SDPS_ENABLE,1,Define if you want SDPS support compiled in)
 458    fi
 459 fi
 460 if test "$with_POP3" != yes && test "$with_POP2" != yes \
 461     && test "$with_IMAP"  != yes ; then
 462     AC_MSG_ERROR([You must enable at least one of POP2, POP3 and IMAP.])
 463 fi
 464
 465 AC_CACHE_SAVE
 466
 467 ###     use option --enable-opie to compile in the OPIE support
 468 AC_ARG_ENABLE(opie,
 469         [  --enable-opie           support OTP through the OPIE library],
 470         [ AC_CHECK_HEADER(opie.h,, [AC_MSG_ERROR(cannot find <opie.h>, which is required for OPIE support.)])
 471           AC_CHECK_LIB(opie,opiegenerator,, [AC_MSG_ERROR(cannot find libopie, which is required for OPIE support.)])
 472           with_opie=$enableval],
 473         [with_opie=no])
 474 test "$with_opie" = "yes" && AC_DEFINE(OPIE_ENABLE,1,Define if you want OPIE support compiled in)
 475
 476 dnl Mostly stolen from gnulib's getaddrinfo.m4
 477 AC_SEARCH_LIBS(getaddrinfo, [nsl socket])
 478 AC_CACHE_CHECK([for getaddrinfo],[fm_cv_getaddrinfo],[
 479   AC_TRY_LINK([
 480 #include <sys/types.h>
 481 #ifdef HAVE_SYS_SOCKET_H
 482 #include <sys/socket.h>
 483 #endif
 484 #ifdef HAVE_NETDB_H
 485 #include <netdb.h>
 486 #endif
 487   ], [getaddrinfo(0, 0, 0, 0);],
 488     [ fm_cv_getaddrinfo=yes],
 489     [ fm_cv_getaddrinfo=no ])
 490 ])
 491
 492 if test x"$fm_cv_getaddrinfo" = "xyes"; then
 493      AC_DEFINE(HAVE_GETADDRINFO, 1,
 494       [Define to 1 if you have the getaddrinfo function.])
 495 fi
 496
 497 AC_CACHE_CHECK([for getnameinfo],[fm_cv_getnameinfo],[
 498   AC_TRY_LINK([
 499 #include <sys/types.h>
 500 #ifdef HAVE_SYS_SOCKET_H
 501 #include <sys/socket.h>
 502 #endif
 503 #ifdef HAVE_NETDB_H
 504 #include <netdb.h>
 505 #endif
 506 #ifndef NULL
 507 #define NULL 0
 508 #endif
 509   ], [getnameinfo(NULL,0, NULL,0, NULL, 0, 0);],
 510     [ fm_cv_getnameinfo=yes],
 511     [ fm_cv_getnameinfo=no ])
 512 ])
 513 if test $fm_cv_getnameinfo = yes ; then
 514     AC_DEFINE(HAVE_GETNAMEINFO,1,[Define to 1 if your system has getnameinfo()])
 515 fi
 516
 517 AM_CONDITIONAL(NEED_GETADDRINFO, test "$fm_cv_getaddrinfo" != yes)
 518 AM_CONDITIONAL(NEED_GETNAMEINFO, test "$fm_cv_getnameinfo"   != yes)
 519
 520 AC_CHECK_FUNCS(inet_ntop)
 521 dnl Check if getaddrinfo is async-signal-safe - most implementations aren't
 522 if test "$fm_cv_getaddrinfo" = yes ; then
 523     AC_MSG_CHECKING(if your getaddrinfo is async-signal-safe)
 524     gai_ts=no
 525     dnl we have getaddrinfo() - check if the OS is known to have a async-signal-safe implementation
 526     case $host_os in
 527         darwin9*)                               gai_ts=yes ;;
 528         linux*)                                 gai_ts=yes ;;
 529         freebsd5.5|freebsd6*|freebsd7*)         gai_ts=yes ;;
 530         solaris2.8|solaris2.9|solaris2.10)      gai_ts=yes ;;
 531     esac
 532     AC_MSG_RESULT($gai_ts)
 533     if test $gai_ts = yes ; then
 534         AC_DEFINE(GETADDRINFO_ASYNCSAFE, 1, [define to 1 if you know your getaddrinfo function is async-signal-safe])
 535     fi
 536 fi
 537
 538 # This version of the Kerberos 4 and 5 options addresses the follwing issues:
 539 #
 540 # * Build correctly under Heimdal kerberos if it is compiled with db2 and
 541 #   OpenSSL support (Debian's is)
 542 # * Build the kerberos.c stuff (KPOP) only for kerberosIV, to avoid breakage.
 543 #   I don't know if this is 100% correct, but now at least IMAP and POP3
 544 #   behave the same way regarding kerberosV.
 545 # * Build without any fuss for both kerberosIV and V at the same time.
 546 # * Move all the kerberos header mess to kerberos.h, and #include that
 547 #   in driver.c and kerberos.c.
 548 #
 549 # Tested using the Heimdal Kerberos V libs, Kungliga Tekniska Högskolan (the
 550 # Royal Institute of Technology in Stockholm, Sweden)'s kerberos IV libs, and
 551 # the MIT reference implementation of KerberosV (all as packaged in Debian).
 552
 553 ###    use option --with-kerberos5=DIR to point at a Kerberos 5 directory
 554 ### make sure --with-ssl is run before --with-kerberos* !
 555 AC_ARG_WITH(kerberos5,
 556        [  --with-kerberos5=DIR    point fetchmail compilation at a Kerberos 5 directory],
 557 [
 558 if test "$with_kerberos5" != "no"
 559 then
 560 # Check for a OpenBSD special case
 561 if test "$with_kerberos5" = "yes" && ( test `uname` = "OpenBSD" )
 562 then
 563   AS_MESSAGE(checking kerberosV for OpenBSD...)
 564   AC_DEFINE(HEIMDAL,1,Define if you have HEIMDAL kerberos 5)
 565   AC_DEFINE(KERBEROS_V5,1,Define if you have Kerberos V5)
 566   CFLAGS="$CFLAGS -I/usr/include/kerberosV"
 567   LIBS="$LIBS -lasn1 -lkrb5 -lcom_err -lkafs"
 568 elif krb5-config 2> /dev/null >/dev/null ; then
 569   krb5_prefix=`krb5-config --prefix krb5`
 570   AC_MSG_RESULT([krb5-config points to kerberosV under $krb5_prefix])
 571   if test -f ${krb5_prefix}/include/et/com_err.h && \
 572    ! test -f ${krb5_prefix}/include/com_err.h  ; then
 573     CFLAGS="$CFLAGS -I${krb5_prefix}/include/et"
 574   fi
 575   unset krb5_prefix
 576   CFLAGS="$CFLAGS `krb5-config --cflags krb5`"
 577   LIBS="$LIBS `krb5-config --libs krb5`"
 578   AC_DEFINE(KERBEROS_V5)
 579 else
 580   if test "$with_kerberos5" != "yes"
 581   then
 582       LDFLAGS="$LDFLAGS -L${with_kerberos5}/lib"
 583       searchdirs="$with_kerberos5"
 584   else
 585       searchdirs="/usr/kerberos /usr/local/krb5 /usr/athena /usr"
 586   fi
 587   with_kerberos5=
 588   for dir in $searchdirs
 589   do AC_MSG_CHECKING([for Kerberos V in $dir])
 590      if test -f "$dir/include/krb5.h" || test -f "$dir/include/krb5/krb5.h"
 591      then
 592         if test -d "$dir/include/krb5" ; then CPPFLAGS="$CPPFLAGS -I$dir/include/krb5" ; fi
 593         ac_krblibs=
 594         if test -f "$dir/include/roken.h" || test -f "$dir/include/krb5/roken.h"
 595         then
 596            ac_krblibs="-lasn1 -lroken -lcom_err"
 597            AC_MSG_RESULT([Heimdal found])
 598           dnl Attempt to detect if we need to -ldb2 to link Heimdal
 599           dnl we assume we do if it is available
 600            AC_CHECK_LIB(db2, db_open, ac_krblibs="$ac_krblibs -ldb2", [],
 601                 ${LDFLAGS})
 602            AC_CHECK_LIB(des, des_string_to_key, libk5crypto=-ldes,
 603               AC_CHECK_LIB(crypto, MD5_Init, [],
 604                 AC_MSG_ERROR([DES libraries not found. Try adding --with-ssl to enable OpenSSL support]),
 605                 ${LDFLAGS} ${ac_krblibs}),
 606            ${LDFLAGS} ${ac_krblibs})
 607            AC_DEFINE(HEIMDAL)
 608         else
 609           AC_MSG_RESULT([found])
 610           ac_krblibs="-lcom_err"
 611            AC_CHECK_LIB(crypto,
 612              krb5_des_string_to_key,
 613              libk5crypto=-lcrypto,
 614                 AC_CHECK_LIB(k5crypto,
 615                    krb5_des_string_to_key,
 616                    libk5crypto=-lk5crypto,
 617                       AC_MSG_ERROR([Kerberos 5 DES libraries not found]),
 618                    ${LDFLAGS} ${ac_krblibs}),
 619                  ${LDFLAGS} ${ac_krblibs})
 620         fi
 621         AC_CHECK_LIB(krb5, krb5_init_context,[],
 622            continue,
 623            ${LDFLAGS} ${ac_krblibs})
 624         AC_DEFINE(KERBEROS_V5)
 625         test "$dir" != "/usr" && CFLAGS="$CFLAGS -I$dir/include"
 626         LDFLAGS="$LDFLAGS -L$dir/lib"
 627        LIBS="$LIBS $ac_krblibs $libk5crypto"
 628         with_kerberos5=$dir
 629         break
 630      else
 631         AC_MSG_RESULT([not found])
 632      fi
 633   done
 634   if test -z "$with_kerberos5" ; then
 635      AC_MSG_ERROR([Kerberos 5 libraries not found])
 636   fi
 637 fi
 638 fi
 639 ]) dnl --with-kerberos5=DIR
 640
 641 ###    use option --with-kerberos=DIR to point at a Kerberos 4 directory
 642 KERBEROS_V4=0
 643 AC_ARG_WITH(kerberos,
 644        [  --with-kerberos=DIR     point fetchmail compilation at a Kerberos 4 directory],
 645 [
 646 if test "$with_kerberos" != "no"
 647 then
 648     AC_MSG_WARN([Kerberos IV support is obsolete. Use --with-kerberos5 if possible.])
 649 # Check for a NetBSD/OpenBSD special case
 650 if test "$with_kerberos" = "yes" && ( test `uname` = "NetBSD" || test `uname` = "OpenBSD" )
 651 then
 652   AS_MESSAGE(checking kerberosIV for `uname`...)
 653   KERBEROS_V4=1
 654   CFLAGS="$CFLAGS -I/usr/include/kerberosIV"
 655   case `uname` in
 656       NetBSD)  LIBS="$LIBS -lkrb -ldes -lroken -lcom_err" ;;
 657       OpenBSD) LIBS="$LIBS -lkrb -ldes" ;;
 658   esac
 659 elif krb4-config 2> /dev/null >/dev/null ; then
 660   krb4_prefix=`krb4-config --prefix`
 661   AC_MSG_RESULT([krb4-config points to kerberosIV under $krb4_prefix])
 662   unset krb4_prefix
 663   CFLAGS="$CFLAGS `krb4-config --cflags`"
 664   LIBS="$LIBS `krb4-config --libs`"
 665   KERBEROS_V4=1
 666 elif krb5-config 2> /dev/null >/dev/null ; then
 667   krb4_prefix=`krb5-config --prefix krb4`
 668   AC_MSG_RESULT([krb5-config points to kerberosIV under $krb4_prefix])
 669   if test -f ${krb4_prefix}/include/kerberosIV/krb.h ; then
 670     AC_DEFINE(KERBEROS_V4_V5,1,Define if you have Kerberos V4 headers under a kerberosIV directory)
 671   fi
 672   unset krb4_prefix
 673   CFLAGS="$CFLAGS `krb5-config --cflags krb4`"
 674   LIBS="$LIBS `krb5-config --libs krb4`"
 675   KERBEROS_V4=1
 676 else
 677   #we need to detect when we're building under a kerberosV compatibility
 678   #layer, btw...
 679   if test "$with_kerberos" != "yes" ; then
 680      searchdirs="$with_kerberos"
 681   else
 682      searchdirs="$with_kerberos5 /usr/kerberos /usr/kerberosIV /usr/athena /usr"
 683   fi
 684   with_kerberos=
 685   ac_saveLDFLAGS="$LDFLAGS"
 686   for dir in $searchdirs
 687   do
 688      AC_MSG_CHECKING([for Kerberos IV in $dir])
 689      if test -f "$dir/include/krb.h" || test -f "$dir/include/krb4.h" \
 690             || test -f "$dir/include/kerberosIV/krb.h"
 691      then
 692         AC_MSG_RESULT([found])
 693      else
 694         AC_MSG_RESULT([not found])
 695        continue
 696      fi
 697      #Find libs
 698      if test -f "$with_kerberos5/roken.h" ; then
 699        AC_CHECK_LIB(45, krb_mk_req)
 700      fi
 701      LDFLAGS="-L$dir/lib $ac_saveLDFLAGS"
 702      if test `uname` = "FreeBSD"; then
 703         AC_SEARCH_LIBS(_ossl_old_des_string_to_key, [des425 des crypto], [], continue)
 704      else
 705         AC_SEARCH_LIBS(des_string_to_key, [crypto], [], continue)
 706      fi
 707      AC_SEARCH_LIBS(krb_realmofhost, [krb4 krb], [], continue)
 708      with_kerberos="$dir"
 709      if test -f "$dir/include/kerberosIV/krb.h" ; then
 710         dir="$dir/include/kerberosIV"
 711      else
 712        dir="$dir/include"
 713      fi
 714      KERBEROS_V4=1
 715      test -f "$with_kerberos5/roken.h" && AC_DEFINE(HEIMDAL)
 716      test "$dir" != "/usr/include" && CFLAGS="$CFLAGS -I$dir"
 717      LDFLAGS="$LDFLAGS -L$with_kerberos/lib"
 718      break
 719   done
 720   if test -z "$with_kerberos" ; then
 721      AC_MSG_ERROR([Kerberos 4 libraries not found])
 722   fi
 723   LDFLAGS="$ac_saveLDFLAGS"
 724 fi
 725 fi
 726 ]) dnl --with-kerberos=DIR
 727 if test "$KERBEROS_V4" = 1 ; then
 728     AC_DEFINE(KERBEROS_V4,1,Define if you have Kerberos V4)
 729 fi
 730 AM_CONDITIONAL(KERBEROS_V4_ENABLE, test "$KERBEROS_V4" = 1)
 731
 732 ###     use option --with-ssl to compile in the SSL support
 733 AC_ARG_WITH(ssl,
 734         [  --with-ssl=[DIR]        enable SSL support using libraries in DIR],
 735         [with_ssl=$withval],
 736         [with_ssl=no])
 737 test "$with_ssl" != "no" && AC_DEFINE(SSL_ENABLE,1,Define if you want SSL support compiled in)
 738
 739 if test "$with_ssl" = "yes"
 740 then
 741     #   User didn't specify an SSL location.  Let's look at some common
 742     #   directories where SSL has been found in the past and try and auto
 743     #   configure for SSL.  OpenSSL determination will be made later.
 744     #   This will screw up if an OpenSSL install is located in a later
 745     #   directory than an older SSLeay install, but the user should fix that
 746     #   anyways and he can override on the configure line.
 747     #   Just testing for directories is not sufficient, /usr exists on
 748     #   all systems!
 749     for ac_dir in \
 750       /usr/local/ssl \
 751       /usr/local \
 752       /usr/ssl \
 753       /usr \
 754       /local/ssl \
 755       /opt/ssl \
 756       /opt/csw \
 757       ; \
 758     do
 759         if test -r "$ac_dir/include/openssl/ssl.h" ; then
 760             with_ssl=$ac_dir
 761             break;
 762         fi
 763     done
 764 fi
 765
 766 if test -n "$with_ssl" -a "$with_ssl" != "no"
 767 then
 768   # With the autoconfigure above, the only time this is going to be
 769   # true is going to be when we could not find the headers.  If they
 770   # are not in system standard locations, we are going to be broken.
 771   if test "$with_ssl" = "yes"
 772   then
 773     # Let's just define the standard location for the SSLeay root
 774     with_ssl="/usr/local/ssl"
 775   fi
 776   if test -r $with_ssl/include/openssl/ssl.h
 777   then
 778     ### ssl.h found under openssl.  Use openssl configuration preferentially,
 779     AC_MSG_NOTICE(Enabling OpenSSL support in $with_ssl.)
 780     test "$with_ssl" != "/usr" && CFLAGS="$CFLAGS -I$with_ssl/include"
 781     ### In Red Hat 9, this file includes a reference to <krb5.h>, so we
 782     ### force the Kerberos direcory onto the include path so it will build.
 783     CFLAGS="$CFLAGS -I/usr/kerberos/include"
 784     ### OpenBSD comes with ssl headers
 785   else
 786     AC_MSG_ERROR([SSL support enabled, but OpenSSL not found])
 787   fi
 788   LDFLAGS="$LDFLAGS -L$with_ssl/lib"
 789   LIBS="$LIBS -lssl -lcrypto"
 790   dnl check if -ldl is needed
 791   AC_MSG_CHECKING([for additional library dependencies of SSL])
 792   found=0
 793   save_LIBS="$LIBS"
 794   for i in "" "-ldl" ; do
 795       LIBS="$LDFLAGS $save_LIBS $i"
 796       AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <openssl/ssl.h>],[SSL_library_init()])],[found=1; break])
 797   done
 798   if test $found = 0 ; then
 799       AC_MSG_RESULT([error])
 800       AC_MSG_ERROR([cannot link with SSL - check config.log])
 801   fi
 802   LIBS="$save_LIBS $i"
 803   if test "$i" = "" ; then i="(none)" ; fi
 804   AC_MSG_RESULT($i)
 805   dnl XXX FIXME: use pkg-config if available!
 806   AC_DEFINE(SSL_ENABLE)
 807 else
 808   AC_MSG_NOTICE(Disabling SSL support.)
 809 fi
 810
 811 ###     use option --with-socks=DIR to point at SOCKS library
 812 AC_ARG_WITH(socks,
 813         [  --with-socks[=DIR]      add built-in SOCKS firewall access],
 814 [
 815 if test "$with_socks" != no
 816 then
 817     if test "$with_socks" != yes
 818     then
 819         LDFLAGS="$LDFLAGS -L$with_socks"
 820     else
 821         AC_CHECK_LIB(socks, Rconnect,,
 822                AC_MSG_ERROR([could not find libsocks which is needed for built-in SOCKS support]))
 823     fi
 824     AC_DEFINE(HAVE_SOCKS,1,Define if you want built-in SOCKS support)
 825     CFLAGS="$CFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 826     LIBS="-lsocks $LIBS"
 827 fi])
 828
 829 ###     use option --with-socks5=DIR to point at SOCKS library
 830 AC_ARG_WITH(socks5,
 831         [  --with-socks5[=DIR]     add built-in SOCKS5 firewall access],
 832 [
 833 if test "$with_socks5" != no
 834 then
 835   if test "$with_socks5" != yes
 836   then
 837     LDFLAGS="$LDFLAGS -L$with_socks5"
 838   fi
 839   ac_savedLDFLAGS="$LDFLAGS"
 840   LDFLAGS="$LDFLAGS $LDFLAGS"
 841   AC_CHECK_LIB(socks5, SOCKSconnect,,
 842         AC_MSG_ERROR([could not find libsocks5 which is needed for built-in SOCKS5 support]))
 843   AC_DEFINE(HAVE_SOCKS)
 844   CFLAGS="$CFLAGS -Dconnect=SOCKSconnect -Dgetsockname=SOCKSgetsockname -Dbind=SOCKSbind -Daccept=SOCKSaccept -Dlisten=SOCKSlisten -Dselect=SOCKSselect -Drecvfrom=SOCKSrecvfrom -Dsendto=SOCKSsendto -Drecv=SOCKSrecv -Dsend=SOCKSsend -Dread=SOCKSread -Dwrite=SOCKSwrite -Drresvport=SOCKSrresvport -Dshutdown=SOCKSshutdown -Dlisten=SOCKSlisten -Dclose=SOCKSclose -Ddup=SOCKSdup -Ddup2=SOCKSdup2 -Dgethostbyname=SOCKSgethostbyname"
 845   AC_CHECK_FUNC(SOCKSfclose, [CFLAGS="$CFLAGS -Dfclose=SOCKSfclose"])
 846   LDFLAGS="$ac_savedLDFLAGS"
 847 fi])
 848
 849 dnl for libesmtp/ modules:
 850 ACX_WHICH_GETHOSTBYNAME_R
 851
 852 ###     use option --with-hesiod=DIR to point at a HESIOD directory
 853 AC_ma_SEARCH_PACKAGE(hesiod, hesiod_getmailhost, /usr/athena /usr /usr/local,hesiod, hesiod.h)
 854
 855 ###     use option --with-gssapi=DIR to compile in GSSAPI support
 856 AC_ARG_WITH(gssapi,
 857         [  --with-gssapi[=DIR]     compile in GSSAPI support using libraries in DIR],
 858 [
 859 if test "$with_gssapi" != "no"
 860 then
 861   if test "$with_gssapi" = "yes" -a -n "$with_kerberos5"
 862   then
 863     with_gssapi=$with_kerberos5
 864   fi
 865
 866   if test "$with_gssapi" != "yes" -a -n "$with_gssapi"
 867   then
 868     CFLAGS="$CFLAGS -I$with_gssapi/include"
 869     LDFLAGS="$LDFLAGS -L$with_gssapi/lib"
 870   fi
 871
 872   dnl obtain gssapi default libs
 873   if krb5-config --libs gssapi 2>/dev/null >/dev/null ; then
 874       LIBS="$LIBS `krb5-config --libs gssapi`"
 875   else
 876     AC_CHECK_LIB(gss, gss_check_version, LIBS="$LIBS -lgss", nogss=t)
 877     if test -n "$nogss"
 878     then
 879       # -lgss not found
 880       if test "$with_gssapi" = yes ; then
 881           with_gssapi=/usr
 882       fi
 883       if test -f "$with_gssapi/include/roken.h" -o -f "$with_gssapi/include/krb5/roken.h"
 884       then
 885          # have roken.h, assume Heimdal
 886          case `uname` in
 887              NetBSD) LIBS="$LIBS -lkrb5" ;;
 888              *)      LIBS="$LIBS -lkrb5 -lasn1 -ldes -lroken -ldb -ldl" ;;
 889          esac
 890          AC_CHECK_LIB(gssapi, gss_init_sec_context,LIBS="$LIBS -lgssapi",
 891                       AC_MSG_ERROR([could not find libgssapi which is needed for GSSAPI support]), )
 892          AC_DEFINE(HEIMDAL)
 893       else
 894          # no roken.h, assume MIT
 895          AC_CHECK_LIB(gssapi_krb5, gss_init_sec_context,LIBS="$LIBS -lgssapi_krb5",
 896                       AC_MSG_ERROR([could not find libgssapi_krb5 which is needed for GSSAPI support]), -lkrb5)
 897       fi
 898     fi
 899   fi
 900   AC_DEFINE(GSSAPI,1,Define if you want GSSAPI authentication)
 901   if test "$with_gssapi" != yes ; then
 902     CPPFLAGS="$CPPFLAGS -I$with_gssapi/include"
 903   fi
 904   AC_CHECK_HEADERS(gss.h gssapi.h gssapi/gssapi.h gssapi/gssapi_generic.h)
 905   if test "$ac_cv_header_gssapi_h" = "yes"; then
 906     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE,1,Define if you have MIT kerberos))
 907   else
 908     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi/gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE))
 909   fi
 910 fi])
 911
 912 dnl ,------------------------------------------------------------------
 913 dnl Check if we need TRIO
 914 needtrio=0
 915 if test "$FORCE_TRIO" = "yes" ; then
 916     needtrio=1
 917     ac_cv_func_vsnprintf=no
 918     ac_cv_func_snprintf=no
 919 fi
 920 if test "x$ac_cv_func_snprintf" != "xyes" ; then
 921     AC_DEFINE(snprintf, trio_snprintf,
 922               [Define to trio_snprintf if your system lacks snprintf])
 923     needtrio=1
 924 fi
 925 if test "x$ac_cv_func_vsnprintf" != "xyes" ; then
 926     AC_DEFINE(vsnprintf, trio_vsnprintf,
 927               [Define to trio_vsnprintf if your system lacks vsnprintf])
 928     needtrio=1
 929 fi
 930 AM_CONDITIONAL(NEED_TRIO, test "$needtrio" = 1)
 931
 932 dnl TRIO IEEE compiler option for Alpha
 933 dnl
 934 if test "$needtrio" = 1 ; then
 935     AC_MSG_CHECKING(for IEEE compilation options)
 936     AC_CACHE_VAL(ac_cv_ieee_option, [
 937     AC_TRY_COMPILE(,[
 938     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && (defined(VMS) || defined(__VMS)))
 939     # error "Option needed"
 940     #endif
 941     ],ac_cv_ieee_option="/IEEE_MODE=UNDERFLOW_TO_ZERO/FLOAT=IEEE",
 942     AC_TRY_COMPILE(,[
 943     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && !(defined(VMS) || defined(__VMS)) && !defined(_CFE))
 944     # error "Option needed"
 945     #endif
 946     ],ac_cv_ieee_option="-ieee",
 947     AC_TRY_COMPILE(,[
 948     #if !(defined(__alpha) && (defined(__GNUC__) && (defined(__osf__) || defined(__linux__))))
 949     # error "Option needed"
 950     #endif
 951     ],ac_cv_ieee_option="-mieee",
 952     ac_cv_ieee_option="none"
 953     )
 954     )
 955     )
 956     ])
 957     AC_MSG_RESULT($ac_cv_ieee_option)
 958     if test $ac_cv_ieee_option != none; then
 959       CFLAGS="${CFLAGS} ${ac_cv_ieee_option}"
 960     fi
 961 fi
 962 dnl ----------------------------------------------------------------'
 963
 964 AC_CONFIG_FILES([Makefile po/Makefile.in genlsm.sh])
 965 AC_OUTPUT
 966
 967 dnl Local Variables:
 968 dnl comment-start: "dnl "
 969 dnl comment-end: ""
 970 dnl comment-start-skip: "\\bdnl\\b\\s *"
 971 dnl compile-command: "make configure config.h.in"
 972 dnl End: