Pileus Git - ~andy/fetchmail/blob - configure.ac

   1 dnl Autoconfigure input file for fetchmail
   2 dnl Eric S. Raymond <esr@thyrsus.com>
   3 dnl Matthias Andree <matthias.andree@gmx.de>
   4 dnl
   5 dnl Process this file with autoconf to produce a configure script.
   6 dnl
   7
   8 AC_INIT([fetchmail],[6.3.6-rc2],[fetchmail-users@lists.berlios.de])
   9 AC_CONFIG_SRCDIR([fetchmail.h])
  10 AC_CONFIG_HEADERS([config.h])
  11 AC_CONFIG_LIBOBJ_DIR([.])
  12
  13 AC_CANONICAL_TARGET
  14
  15 dnl automake options are in Makefile.am
  16 AC_PREREQ(2.59)
  17 AM_INIT_AUTOMAKE
  18
  19 dnl autobuild support, see <http://josefsson.org/autobuild/>
  20 (
  21   TZ=GMT
  22   export TZ
  23   AB_INIT
  24 )
  25
  26 dnl python is optional
  27 AM_PATH_PYTHON(2.0,,AC_MSG_WARN([Disabling fetchmailconf: python 2.0 or greater not found]))
  28 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
  29
  30 AC_PROG_AWK
  31 AC_PROG_CC
  32 AC_PROG_INSTALL
  33 AC_PROG_CPP                     dnl Later checks need this.
  34 AC_PROG_RANLIB
  35 AM_PROG_CC_C_O
  36 AC_AIX
  37 AC_ISC_POSIX
  38 AC_MINIX
  39 AC_HEADER_STDC
  40 AC_HEADER_TIME
  41 AC_TYPE_SIZE_T
  42 AC_TYPE_PID_T
  43 AC_TYPE_SIGNAL
  44 AC_CHECK_TYPE(u_int32_t,unsigned int)
  45 AC_CHECK_HEADERS([unistd.h termios.h termio.h sgtty.h stdarg.h \
  46         sys/itimer.h fcntl.h sys/fcntl.h memory.h sys/wait.h \
  47         arpa/inet.h arpa/nameser.h netinet/in.h net/socket.h \
  48         sys/select.h sys/socket.h sys/time.h langinfo.h])
  49 AC_CHECK_HEADERS([resolv.h],,,[
  50 #include <sys/types.h>
  51 #ifdef HAVE_NETINET_IN_H
  52 #include <netinet/in.h>
  53 #endif
  54 #ifdef HAVE_ARPA_NAMESER_H
  55 #include <arpa/nameser.h>
  56 #endif
  57 ])
  58
  59 AC_C_CONST                      dnl getopt needs this.
  60
  61 AM_PROG_LEX
  62 AC_PROG_MAKE_SET
  63 AC_PROG_YACC
  64
  65 # Check for OS special cases
  66 case $target_os in
  67 darwin*)
  68     AC_MSG_NOTICE(found Darwin - Adding -DBIND_8_COMPAT to CFLAGS)
  69     CPFLAGS="-DBIND_8_COMPAT"
  70     ;;
  71 # Check for FreeBSD special case: more libs needed
  72 freebsd*)
  73     AC_MSG_NOTICE(found FreeBSD - Adding -lmd -lkvm -lcom_err to standard libraries)
  74     LIBS="$LIBS -lmd -lkvm -lcom_err"
  75     ;;
  76 # Check for LynxOS special case: -lbsd needed (at least on 2.3.0) and -s
  77 # not working.
  78 lynxos*)
  79     AC_MSG_NOTICE(found LynxOS - Adding -lbsd to standard libraries)
  80     LIBS="$LIBS -lbsd"
  81     LDFLAGS=`echo $LDFLAGS | sed "s/-s //"`
  82     AC_MSG_NOTICE(found LynxOS - Prepending standard include path to gcc flags)
  83     CPFLAGS="-I/usr/include"
  84     ;;
  85 # Check for Rhapsody special case: it doesn't like -s
  86 rhapsody*)
  87     AC_MSG_NOTICE(found Rhapsody - Removing -s load flag)
  88     LDFLAGS=`echo $LDFLAGS | sed "s/-s //"`
  89     ;;
  90 esac
  91
  92 dnl i18n
  93 AM_GNU_GETTEXT([external], [need-ngettext])
  94 AM_GNU_GETTEXT_VERSION(0.14.3)
  95 dnl end i18n
  96
  97 # Under sysV68, socket and friends are provided by the C library.
  98 # -linet does not provide socket, but causes multiple definition
  99 # errors at link-time.  It is thus better to only use the C library.
 100 # So don't add -linet to the link list unless it's necessary
 101 AC_CHECK_FUNC(socket,
 102     AC_MSG_RESULT(using libc's socket),
 103     AC_CHECK_LIB(socket,socket)
 104     AC_CHECK_LIB(inet,socket))
 105
 106 # The condition in this test copes with the presence of inet_addr in libc6.
 107 AC_CHECK_FUNC(inet_addr,
 108     AC_MSG_RESULT(using libc's inet_addr),
 109     AC_CHECK_LIB(nsl,inet_addr))
 110
 111 dnl Port hack for Interactive UNIX System V/386 Release 3.2
 112 AC_CHECK_LIB(cposix, strchr,
 113                 [DEFS="$DEFS -D_SYSV3"
 114                 LIBS="$LIBS -lcposix"])
 115
 116 dnl Port hack for Sparc/NetBSD-1.5
 117 dnl
 118 dnl NB: this has been disabled as it causes the unconditional
 119 dnl addition of libintl to the build, which is both undesired
 120 dnl and breaks on Solaris/Blastwave.org machines.
 121 dnl
 122 dnl AC_CHECK_LIB(intl, gettext,
 123 dnl             [LIBS="$LIBS -lintl"])
 124
 125 AC_REPLACE_FUNCS([strstr strcasecmp memmove stpcpy strlcpy strlcat])
 126
 127 AC_CHECK_FUNC(MD5Init, [],
 128               [AC_LIBSOURCE(md5c.c)
 129                EXTRAOBJ="$EXTRAOBJ md5c.\$(OBJEXT)"])
 130
 131 AC_CHECK_FUNC(getopt_long, [],
 132               [AC_LIBSOURCES([getopt.c, getopt1.c])
 133                EXTRAOBJ="$EXTRAOBJ getopt.\$(OBJEXT) getopt1.\$(OBJEXT)"])
 134
 135 AC_FUNC_VPRINTF
 136
 137 AC_SUBST(EXTRAOBJ)
 138
 139 AC_CHECK_FUNCS(tcsetattr stty setsid geteuid seteuid dnl
 140   strerror syslog snprintf vprintf vsnprintf vsyslog dnl
 141   atexit inet_aton strftime setrlimit socketpair dnl
 142   sigaction strdup setlocale)
 143
 144 AC_CHECK_DECLS(strerror)
 145 dnl INET6 is used by KAME/getnameinfo
 146 AC_CACHE_CHECK(for AF_INET6/PF_INET6,ac_cv_inet6,
 147 AC_COMPILE_IFELSE([
 148   AC_LANG_PROGRAM([[
 149     #ifdef HAVE_SYS_TYPES_H
 150     #include <sys/types.h>
 151     #endif
 152     #ifdef HAVE_SYS_SOCKET_H
 153     #include <sys/socket.h>
 154     #endif
 155   ]],[[
 156     int foo = AF_INET6;
 157     int bar = PF_INET6;
 158   ]])],
 159   ac_cv_inet6=yes , ac_cv_inet6=no
 160 ))
 161 if test "x$ac_cv_inet6" = xyes
 162 then
 163     AC_DEFINE(INET6,1,Define to 1 if your system defines AF_INET6 and PF_INET6.)
 164 fi
 165
 166 # Under Red Hat 4.0 (and many other Linuxes) -lresolv is seriously flaky
 167 # and breaks gethostbyname(2).  It's better to use the bind stuff in the C
 168 # library.  So don't add -lresolv to the link list unless it's necessary
 169 # (It will be necessary when using GNU libc6).
 170 old_LIBS="$LIBS"
 171 for lib in '' -lresolv; do
 172     if test -z "$lib"; then
 173        AC_MSG_CHECKING([for res_search in libc])
 174     else
 175        AC_MSG_CHECKING([for res_search in $lib])
 176     fi
 177     LIBS="$old_LIBS $lib"
 178     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 179 #include <sys/types.h>
 180 #ifdef HAVE_NETINET_IN_H
 181 #include <netinet/in.h>
 182 #endif
 183 #ifdef HAVE_ARPA_NAMESER_H
 184 #include <arpa/nameser.h>
 185 #endif
 186 #ifdef HAVE_RESOLV_H
 187 #include <resolv.h>
 188 #endif
 189 extern int res_search();
 190 ]], [[res_search(0, 0, 0, 0, 0);]])],
 191     [AC_MSG_RESULT([found])
 192      AC_DEFINE(HAVE_RES_SEARCH, [1],
 193                [Define to 1 if you have the 'res_search' function.])
 194      break], [AC_MSG_RESULT([not found])])
 195      LIBS=$old_LIBS
 196 done
 197
 198 dnl Check for libcrypt -- it may live in libc or libcrypt, as on IRIX
 199 AC_CHECK_FUNC(crypt, , AC_CHECK_LIB(crypt,crypt))
 200
 201 dnl Check for RSA refersence library in case we're using SSL
 202 AC_CHECK_LIB(rsaref, RSAPublicDecrypt)
 203
 204 dnl AC_FUNC_SETVBUF_REVERSED
 205
 206 dnl Check for usable void pointer type
 207 AC_MSG_CHECKING(use of void pointer type)
 208 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[char *p;
 209     void *xmalloc();
 210     p = (char *) xmalloc(1);
 211    ]])],[AC_DEFINE(HAVE_VOIDPOINTER,1,[Define if your C compiler allows void * as a function result]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 212
 213 dnl Check for ANSI volatile
 214 AC_C_VOLATILE
 215
 216 dnl Check out the wait reality.  We have to assume sys/wait.h is present.
 217 AC_CHECK_FUNCS(waitpid wait3)
 218 AC_MSG_CHECKING(for union wait);
 219 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 220 #include <sys/wait.h>]], [[union wait status; int pid; pid = wait (&status);
 221 #ifdef WEXITSTATUS
 222 /* Some POSIXoid systems have both the new-style macros and the old
 223    union wait type, and they do not work together.  If union wait
 224    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 225 if (WEXITSTATUS (status) != 0) pid = -1;
 226 #endif
 227 #ifdef HAVE_WAITPID
 228 /* Make sure union wait works with waitpid.  */
 229 pid = waitpid (-1, &status, 0);
 230 #endif
 231 ]])],[AC_DEFINE(HAVE_UNION_WAIT,1,Define if 'union wait' is the type of the first arg to wait functions.) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 232
 233 AC_MSG_CHECKING(sys_siglist declaration in signal.h or unistd.h)
 234 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>
 235 /* NetBSD declares sys_siglist in <unistd.h>.  */
 236 #ifdef HAVE_UNISTD_H
 237 #include <unistd.h>
 238 #endif]], [[char *msg = *(sys_siglist + 1);]])],[AC_DEFINE(SYS_SIGLIST_DECLARED,1,[Define if 'sys_siglist' is declared by <signal.h>.]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 239
 240 # Find the right directory to put the root-mode PID file in
 241 for dir in "/var/run" "/etc"
 242 do
 243         if test -d $dir
 244         then
 245                 break;
 246         fi
 247 done
 248 AC_MSG_RESULT(root-mode pid file will go in $dir)
 249 AC_DEFINE_UNQUOTED(PID_DIR, "$dir", directory for PID lock files)
 250
 251 # We may have a fallback MDA available in case the socket open to the
 252 # local SMTP listener fails.  Best to use procmail for this, as we know
 253 # it won't try delivering through local SMTP and cause a mail loop.
 254 # Sendmail without the -t option to use the message headers will work too,
 255 # not just for sendmail itself but for workalikes like exim.
 256 #
 257 # Note1: A disadvantage of using procmail is that local alias expansion
 258 # according to /etc/aliases won't get done if we fall back.  This doesn't
 259 # matter in single-drop mode.
 260 #
 261 # Note2: it would be a very bad idea to use any MDA that doesn't return
 262 # a refuse-to-deliver status on disk- or process-table-full
 263 # conditions; mail could get lost that way.  Sendmail and all of the MDAs
 264 # like exim that might be lurking under a sendmail alias) do the right
 265 # thing in this circumstance.  Matthias Andree warns that procmail does
 266 # not.
 267 #
 268 # Note3: Defalt value of fallback is now off.  Matthias writes:
 269 #
 270 # 1. there is no way to predict when the fallback is used. With some MTAs
 271 #    (such as those limiting load average), outer circumstances can cause
 272 #    the fallback to kick in.
 273 #
 274 # 2. the fallback changes fetchmail behaviour in unpredictable ways. It's
 275 #    not only about alias expansion, .forwards to special filters won't
 276 #    work, mail may end up in a different place (users claim "mail loss"
 277 #    for that).
 278 #
 279 # 3. The claim procmail did the right thing with its exit codes is plain
 280 #    wrong. I've seen procmail exit with code 1 when it should have exited
 281 #    with code 75, like, configuration errors. Procmail is a dangerous
 282 #    beast and is best replaced by maildrop.
 283 #
 284 # 4. if multiple choices exist (like procmail and maildrop), fetchmail
 285 #    cannot tell which one it should choose. Say, your MTA is configured
 286 #    to use maildrop to deliver to user's mailboxes, if fetchmail then
 287 #    chooses procmail, this is plain wrong.
 288 #
 289
 290 AC_PATH_PROG(procmail, procmail, "", $PATH:/usr/sbin)
 291 AC_PATH_PROG(sendmail, sendmail, "", $PATH:/usr/sbin:/usr/lib)
 292 AC_PATH_PROG(maildrop, maildrop, "", $PATH:/usr/local/bin)
 293
 294 ###     use option --disable-fallback to disable fallback MDA
 295 ###     use option --enable-fallback=procmail or
 296 ###                --enable-fallback=sendmail to select
 297 AC_ARG_ENABLE(fallback,
 298         [  --enable-fallback=procmail    enable procmail as fallback
 299   --enable-fallback=sendmail    enable /usr/sbin/sendmail as fallback
 300   --enable-fallback=maildrop    enable maildrop as fallback
 301   --enable-fallback=no          disable fallback],,[enable_fallback=no])
 302
 303 case "$enable_fallback" in
 304         sendmail)       if test -z "$sendmail" ; then
 305                                 AC_MSG_ERROR([Sendmail selected as fallback, but not found])
 306                                 #not reached
 307                         fi
 308                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$sendmail -i %T", Fallback MTA to use if defined)
 309                         AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 310                         ;;
 311         procmail)       if test -z "$procmail" ; then
 312                                 AC_MSG_ERROR([procmail selected as fallback, but not found])
 313                                 #not reached
 314                         fi
 315                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$procmail -d %T")
 316                         AC_MSG_NOTICE(Will use $procmail as fallback MDA.)
 317                         ;;
 318         maildrop)       if test -z "$maildrop" ; then
 319                                 AC_MSG_ERROR([maildrop selected as fallback, but not found])
 320                                 #not reached
 321                         fi
 322                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$maildrop -d %T")
 323                         AC_MSG_NOTICE(Will use $maildrop as fallback MDA.)
 324                         ;;
 325         no|unset)       AC_MSG_NOTICE(Will not use a fallback MDA.)
 326                         ;;
 327         auto|yes|set)   if test -n "$sendmail" ; then
 328                                 AC_DEFINE_UNQUOTED(FALLBACK_MDA,"$sendmail -i %T")
 329                                 AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 330                         else
 331                                 AC_MSG_WARN(No fallback MDA available.  procmail and maildrop are not eligible)
 332                                 AC_MSG_WARN(for automatic fallback MDA configuration for reliability reasons.)
 333                         fi
 334                         ;;
 335         *)              AC_MSG_ERROR([unkown value for --enable-fallback given: $enable_fallback])
 336                         #notreached
 337                         ;;
 338 esac
 339
 340 AC_CHECK_SIZEOF(short)
 341 AC_CHECK_SIZEOF(int)
 342 AC_CHECK_SIZEOF(long)
 343
 344 ###     use option --enable-POP2 to compile in the POP2 support
 345 AC_ARG_ENABLE(POP2,
 346         [  --enable-POP2           compile in POP2 protocol support (obsolete)],
 347         [with_POP2=$enableval],
 348         [with_POP2=no])
 349 test "$with_POP2" = "yes" && AC_DEFINE(POP2_ENABLE,1,Define if you want POP2 support compiled in)
 350 AM_CONDITIONAL(POP2_ENABLE, test "$with_POP2" = yes)
 351
 352 ###     use option --disable-POP3 to omit the POP3 support
 353 AC_ARG_ENABLE(POP3,
 354         [  --disable-POP3          don't compile in POP3 protocol support],
 355         [with_POP3=$enableval],
 356         [with_POP3=yes])
 357 test "$with_POP3" = "yes" && AC_DEFINE(POP3_ENABLE,1,Define if you want POP3 support compiled in)
 358 AM_CONDITIONAL(POP3_ENABLE, test "$with_POP3" = yes)
 359
 360 ###     use option --disable-IMAP to omit the IMAP support
 361 AC_ARG_ENABLE(IMAP,
 362         [  --disable-IMAP          don't compile in IMAP protocol support],
 363         [with_IMAP=$enableval],
 364         [with_IMAP=yes])
 365 test "$with_IMAP" = "yes" && AC_DEFINE(IMAP_ENABLE,1,Define if you want IMAP support compiled in)
 366 AM_CONDITIONAL(IMAP_ENABLE, test "$with_IMAP" = yes)
 367
 368 ###     use option --disable-ETRN to omit the ETRN support
 369 AC_ARG_ENABLE(ETRN,
 370         [  --disable-ETRN          don't compile in ETRN protocol support],
 371         [with_ETRN=$enableval],
 372         [with_ETRN=yes])
 373 test "$with_ETRN" = "yes" && AC_DEFINE(ETRN_ENABLE,1,Define if you want ETRN support compiled in.)
 374 AM_CONDITIONAL(ETRN_ENABLE, test "$with_ETRN" = yes)
 375
 376 ###     use option --disable-ODMR to omit the ODMR support
 377 AC_ARG_ENABLE(ODMR,
 378         [  --disable-ODMR          don't compile in ODMR protocol support],
 379         [with_ODMR=$enableval],
 380         [with_ODMR=yes])
 381 test "$with_ODMR" = "yes" && AC_DEFINE(ODMR_ENABLE,1,Define if you want ODMR support compiled in)
 382 AM_CONDITIONAL(ODMR_ENABLE, test "$with_ODMR" = yes)
 383
 384 ###     use option --enable-RPA to compile in the RPA support
 385 AC_ARG_ENABLE(RPA,
 386         [  --enable-RPA            compile in RPA protocol support],
 387         [with_RPA=$enableval],
 388         [with_RPA=no])
 389 test "$with_RPA" = "yes" && AC_DEFINE(RPA_ENABLE,1,Define if you want RPA support compiled in)
 390 AM_CONDITIONAL(RPA_ENABLE, test "$with_RPA" = yes)
 391
 392 ###     use option --enable-NTLM to compile in the NTLM support
 393 AC_ARG_ENABLE(NTLM,
 394         [  --enable-NTLM           compile in NTLM authentication support],
 395         [with_NTLM=$enableval],
 396         [with_NTLM=no])
 397 test "$with_NTLM" = "yes" && AC_DEFINE(NTLM_ENABLE,1,Define if you want NTLM authentication)
 398
 399 ###     use option --enable-SDPS to compile in the SDPS support
 400 AC_ARG_ENABLE(SDPS,
 401         [  --enable-SDPS           compile in SDPS protocol support],
 402         [with_SDPS=$enableval],
 403         [with_SDPS=no])
 404 if test "$with_SDPS" = yes ; then
 405    if test "$with_POP3" != yes ; then
 406        AC_MSG_WARN([SDPS cannot be enabled with POP3 disabled. Disabling SDPS.])
 407        with_SDPS=no
 408    else
 409        AC_DEFINE(SDPS_ENABLE,1,Define if you want SDPS support compiled in)
 410    fi
 411 fi
 412 if test "$with_POP3" != yes && test "$with_POP2" != yes \
 413     && test "$with_IMAP"  != yes ; then
 414     AC_MSG_ERROR([You must enable at least one of POP2, POP3 and IMAP.])
 415 fi
 416
 417 ###     use option --enable-opie to compile in the OPIE support
 418 AC_ARG_ENABLE(opie,
 419         [  --enable-opie           support OTP through the OPIE library],
 420         [ AC_CHECK_HEADER(opie.h,, [AC_MSG_ERROR(cannot find <opie.h>, which is required for OPIE support.)])
 421           AC_CHECK_LIB(opie,opiegenerator,, [AC_MSG_ERROR(cannot find libopie, which is required for OPIE support.)])
 422           with_opie=$enableval],
 423         [with_opie=no])
 424 test "$with_opie" = "yes" && AC_DEFINE(OPIE_ENABLE,1,Define if you want OPIE support compiled in)
 425
 426 AC_SEARCH_LIBS(getaddrinfo, inet6, [AC_DEFINE(HAVE_GETADDRINFO,1,[define to 1 if you have the getaddrinfo function])])
 427 AC_CHECK_FUNCS(getnameinfo inet_ntop)
 428 AM_CONDITIONAL(NEED_GETADDRINFO, test "$ac_cv_search_getaddrinfo" != "none required")
 429 AM_CONDITIONAL(NEED_GETNAMEINFO, test "$ac_cv_func_getnameinfo"   != yes)
 430
 431 dnl Check if getaddrinfo is async-signal-safe - most implementations aren't
 432 if test "$ac_cv_search_getaddrinfo" = "none required" ; then
 433     AC_MSG_CHECKING(if your getaddrinfo is async-signal-safe)
 434     gai_ts=no
 435     dnl we have getaddrinfo() - check if the OS is known to have a async-signal-safe implementation
 436     case $target_os in
 437         linux*)                                 gai_ts=yes ;;
 438         freebsd5.5|freebsd6*|freebsd7*)         gai_ts=yes ;;
 439         solaris2.8|solaris2.9|solaris2.10)      gai_ts=yes ;;
 440     esac
 441     AC_MSG_RESULT($gai_ts)
 442     if test $gai_ts = yes ; then
 443         AC_DEFINE(GETADDRINFO_ASYNCSAFE, 1, [define to 1 if you know your getaddrinfo function is async-signal-safe])
 444     fi
 445 fi
 446
 447 # This version of the Kerberos 4 and 5 options addresses the follwing issues:
 448 #
 449 # * Build correctly under Heimdal kerberos if it is compiled with db2 and
 450 #   OpenSSL support (Debian's is)
 451 # * Build the kerberos.c stuff (KPOP) only for kerberosIV, to avoid breakage.
 452 #   I don't know if this is 100% correct, but now at least IMAP and POP3
 453 #   behave the same way regarding kerberosV.
 454 # * Build without any fuss for both kerberosIV and V at the same time.
 455 # * Move all the kerberos header mess to kerberos.h, and #include that
 456 #   in driver.c and kerberos.c.
 457 #
 458 # Tested using the Heimdal Kerberos V libs, Kungliga Tekniska Högskolan (the
 459 # Royal Institute of Technology in Stockholm, Sweden)'s kerberos IV libs, and
 460 # the MIT reference implementation of KerberosV (all as packaged in Debian).
 461
 462 ###    use option --with-kerberos5=DIR to point at a Kerberos 5 directory
 463 ### make sure --with-ssl is run before --with-kerberos* !
 464 AC_ARG_WITH(kerberos5,
 465        [  --with-kerberos5=DIR    point fetchmail compilation at a Kerberos 5 directory],
 466 [
 467 if test "$with_kerberos5" != "no"
 468 then
 469 # Check for a OpenBSD special case
 470 if test "$with_kerberos5" = "yes" && ( test `uname` = "OpenBSD" )
 471 then
 472   AS_MESSAGE(checking kerberosV for OpenBSD...)
 473   AC_DEFINE(HEIMDAL,1,Define if you have HEIMDAL kerberos 5)
 474   AC_DEFINE(KERBEROS_V5,1,Define if you have Kerberos V5)
 475   CEFLAGS="$CEFLAGS -I/usr/include/kerberosV"
 476   LIBS="$LIBS -lasn1 -lkrb5 -lcom_err -lkafs"
 477 elif krb5-config 2> /dev/null >/dev/null ; then
 478   krb5_prefix=`krb5-config --prefix krb5`
 479   AC_MSG_RESULT([krb5-config points to kerberosV under $krb5_prefix])
 480   if test -f ${krb5_prefix}/include/et/com_err.h && \
 481    ! test -f ${krb5_prefix}/include/com_err.h  ; then
 482     CEFLAGS="$CEFLAGS -I${krb5_prefix}/include/et"
 483   fi
 484   unset krb5_prefix
 485   CEFLAGS="$CEFLAGS `krb5-config --cflags krb5`"
 486   LIBS="$LIBS `krb5-config --libs krb5`"
 487   AC_DEFINE(KERBEROS_V5)
 488 else
 489   if test "$with_kerberos5" != "yes"
 490   then
 491       LDEFLAGS="$LDEFLAGS -L${with_kerberos5}/lib"
 492       searchdirs="$with_kerberos5"
 493   else
 494       searchdirs="/usr/kerberos /usr/local/krb5 /usr/athena /usr"
 495   fi
 496   with_kerberos5=
 497   for dir in $searchdirs
 498   do AC_MSG_CHECKING([for Kerberos V in $dir])
 499      if test -f "$dir/include/krb5.h" || test -f "$dir/include/krb5/krb5.h"
 500      then
 501         if test -d "$dir/include/krb5" ; then CPFLAGS="$CPFLAGS -I$dir/include/krb5" ; fi
 502         ac_krblibs=
 503         if test -f "$dir/include/roken.h" || test -f "$dir/include/krb5/roken.h"
 504         then
 505            ac_krblibs="-lasn1 -lroken -lcom_err"
 506            AC_MSG_RESULT([Heimdal found])
 507           dnl Attempt to detect if we need to -ldb2 to link Heimdal
 508           dnl we assume we do if it is available
 509            AC_CHECK_LIB(db2, db_open, ac_krblibs="$ac_krblibs -ldb2", [],
 510                 ${LDEFLAGS})
 511            AC_CHECK_LIB(des, des_string_to_key, libk5crypto=-ldes,
 512               AC_CHECK_LIB(ssl, MD5_Init, [],
 513                 AC_MSG_ERROR([DES libraries not found. Try adding --with-ssl to enable OpenSSL support]),
 514                 ${LDEFLAGS} ${ac_krblibs}),
 515            ${LDEFLAGS} ${ac_krblibs})
 516            AC_DEFINE(HEIMDAL)
 517         else
 518           AC_MSG_RESULT([found])
 519           ac_krblibs="-lcom_err"
 520            AC_CHECK_LIB(crypto,
 521              krb5_des_string_to_key,
 522              libk5crypto=-lcrypto,
 523                 AC_CHECK_LIB(k5crypto,
 524                    krb5_des_string_to_key,
 525                    libk5crypto=-lk5crypto,
 526                       AC_MSG_ERROR([Kerberos 5 DES libraries not found]),
 527                    ${LDEFLAGS} ${ac_krblibs}),
 528                  ${LDEFLAGS} ${ac_krblibs})
 529         fi
 530         AC_CHECK_LIB(krb5, krb5_init_context,[],
 531            continue,
 532            ${LDEFLAGS} ${ac_krblibs})
 533         AC_DEFINE(KERBEROS_V5)
 534         test "$dir" != "/usr" && CEFLAGS="$CEFLAGS -I$dir/include"
 535         LDEFLAGS="$LDEFLAGS -L$dir/lib"
 536        LIBS="$LIBS $ac_krblibs $libk5crypto"
 537         with_kerberos5=$dir
 538         break
 539      else
 540         AC_MSG_RESULT([not found])
 541      fi
 542   done
 543   if test -z "$with_kerberos5" ; then
 544      AC_MSG_ERROR([Kerberos 5 libraries not found])
 545   fi
 546 fi
 547 fi
 548 ]) dnl --with-kerberos5=DIR
 549
 550 ###    use option --with-kerberos=DIR to point at a Kerberos 4 directory
 551 KERBEROS_V4=0
 552 AC_ARG_WITH(kerberos,
 553        [  --with-kerberos=DIR     point fetchmail compilation at a Kerberos 4 directory],
 554 [
 555 if test "$with_kerberos" != "no"
 556 then
 557     AC_MSG_WARN([Kerberos IV support is obsolete. Use --with-kerberos5 if possible.])
 558 # Check for a NetBSD/OpenBSD special case
 559 if test "$with_kerberos" = "yes" && ( test `uname` = "NetBSD" || test `uname` = "OpenBSD" )
 560 then
 561   AS_MESSAGE(checking kerberosIV for `uname`...)
 562   KERBEROS_V4=1
 563   CEFLAGS="$CEFLAGS -I/usr/include/kerberosIV"
 564   case `uname` in
 565       NetBSD)  LIBS="$LIBS -lkrb -ldes -lroken -lcom_err" ;;
 566       OpenBSD) LIBS="$LIBS -lkrb -ldes" ;;
 567   esac
 568 elif krb4-config 2> /dev/null >/dev/null ; then
 569   krb4_prefix=`krb4-config --prefix`
 570   AC_MSG_RESULT([krb4-config points to kerberosIV under $krb4_prefix])
 571   unset krb4_prefix
 572   CEFLAGS="$CEFLAGS `krb4-config --cflags`"
 573   LIBS="$LIBS `krb4-config --libs`"
 574   KERBEROS_V4=1
 575 elif krb5-config 2> /dev/null >/dev/null ; then
 576   krb4_prefix=`krb5-config --prefix krb4`
 577   AC_MSG_RESULT([krb5-config points to kerberosIV under $krb4_prefix])
 578   if test -f ${krb4_prefix}/include/kerberosIV/krb.h ; then
 579     AC_DEFINE(KERBEROS_V4_V5,1,Define if you have Kerberos V4 headers under a kerberosIV directory)
 580   fi
 581   unset krb4_prefix
 582   CEFLAGS="$CEFLAGS `krb5-config --cflags krb4`"
 583   LIBS="$LIBS `krb5-config --libs krb4`"
 584   KERBEROS_V4=1
 585 else
 586   #we need to detect when we're building under a kerberosV compatibility
 587   #layer, btw...
 588   if test "$with_kerberos" != "yes" ; then
 589      searchdirs="$with_kerberos"
 590   else
 591      searchdirs="$with_kerberos5 /usr/kerberos /usr/kerberosIV /usr/athena /usr"
 592   fi
 593   with_kerberos=
 594   ac_saveLDFLAGS="$LDFLAGS"
 595   for dir in $searchdirs
 596   do
 597      AC_MSG_CHECKING([for Kerberos IV in $dir])
 598      if test -f "$dir/include/krb.h" || test -f "$dir/include/krb4.h" \
 599             || test -f "$dir/include/kerberosIV/krb.h"
 600      then
 601         AC_MSG_RESULT([found])
 602      else
 603         AC_MSG_RESULT([not found])
 604        continue
 605      fi
 606      #Find libs
 607      if test -f "$with_kerberos5/roken.h" ; then
 608        AC_CHECK_LIB(45, krb_mk_req)
 609      fi
 610      LDFLAGS="-L$dir/lib $ac_saveLDFLAGS"
 611      if test `uname` = "FreeBSD"; then
 612         AC_SEARCH_LIBS(_ossl_old_des_string_to_key, [des425 des crypto], [], continue)
 613      else
 614         AC_SEARCH_LIBS(des_string_to_key, [crypto], [], continue)
 615      fi
 616      AC_SEARCH_LIBS(krb_realmofhost, [krb4 krb], [], continue)
 617      with_kerberos="$dir"
 618      if test -f "$dir/include/kerberosIV/krb.h" ; then
 619         dir="$dir/include/kerberosIV"
 620      else
 621        dir="$dir/include"
 622      fi
 623      KERBEROS_V4=1
 624      test -f "$with_kerberos5/roken.h" && AC_DEFINE(HEIMDAL)
 625      test "$dir" != "/usr/include" && CEFLAGS="$CEFLAGS -I$dir"
 626      LDEFLAGS="$LDEFLAGS -L$with_kerberos/lib"
 627      break
 628   done
 629   if test -z "$with_kerberos" ; then
 630      AC_MSG_ERROR([Kerberos 4 libraries not found])
 631   fi
 632   LDFLAGS="$ac_saveLDFLAGS"
 633 fi
 634 fi
 635 ]) dnl --with-kerberos=DIR
 636 if test "$KERBEROS_V4" = 1 ; then
 637     AC_DEFINE(KERBEROS_V4,1,Define if you have Kerberos V4)
 638 fi
 639 AM_CONDITIONAL(KERBEROS_V4_ENABLE, test "$KERBEROS_V4" = 1)
 640
 641 ###     use option --with-ssl to compile in the SSL support
 642 AC_ARG_WITH(ssl,
 643         [  --with-ssl=[DIR]        enable SSL support using libraries in DIR],
 644         [with_ssl=$withval],
 645         [with_ssl=no])
 646 test "$with_ssl" != "no" && AC_DEFINE(SSL_ENABLE,1,Define if you want SSL support compiled in)
 647
 648 if test "$with_ssl" = "yes"
 649 then
 650     #   User didn't specify an SSL location.  Let's look at some common
 651     #   directories where SSL has been found in the past and try and auto
 652     #   configure for SSL.  OpenSSL determination will be made later.
 653     #   This will screw up if an OpenSSL install is located in a later
 654     #   directory than an older SSLeay install, but the user should fix that
 655     #   anyways and he can override on the configure line.
 656     #   Just testing for directories is not sufficient, /usr exists on
 657     #   all systems!
 658     for ac_dir in \
 659       /usr/local/ssl \
 660       /usr/local \
 661       /usr/ssl \
 662       /usr \
 663       /local/ssl \
 664       /opt/ssl \
 665       /opt/csw \
 666       ; \
 667     do
 668         if test -r "$ac_dir/include/openssl/ssl.h" ; then
 669             with_ssl=$ac_dir
 670             break;
 671         fi
 672     done
 673 fi
 674
 675 if test -n "$with_ssl" -a "$with_ssl" != "no"
 676 then
 677   # With the autoconfigure above, the only time this is going to be
 678   # true is going to be when we could not find the headers.  If they
 679   # are not in system standard locations, we are going to be broken.
 680   if test "$with_ssl" = "yes"
 681   then
 682     # Let's just define the standard location for the SSLeay root
 683     with_ssl="/usr/local/ssl"
 684   fi
 685   if test -r $with_ssl/include/openssl/ssl.h
 686   then
 687     ### ssl.h found under openssl.  Use openssl configuration preferentially,
 688     AC_MSG_NOTICE(Enabling OpenSSL support in $with_ssl.)
 689     test "$with_ssl" != "/usr" && CEFLAGS="$CEFLAGS -I$with_ssl/include"
 690     ### In Red Hat 9, this file includes a reference to <krb5.h>, so we
 691     ### force the Kerberos direcory onto the include path so it will build.
 692     CEFLAGS="$CEFLAGS -I/usr/kerberos/include"
 693     ### OpenBSD comes with ssl headers
 694   else
 695     AC_MSG_ERROR([SSL support enabled, but OpenSSL not found])
 696   fi
 697   LDEFLAGS="$LDEFLAGS -L$with_ssl/lib"
 698   LIBS="$LIBS -lssl -lcrypto"
 699   dnl check if -ldl is needed
 700   AC_MSG_CHECKING([for additional library dependencies of SSL])
 701   found=0
 702   save_LIBS="$LIBS"
 703   for i in "" "-ldl" ; do
 704       LIBS="$LDEFLAGS $save_LIBS $i"
 705       AC_LINK_IFELSE([AC_LANG_PROGRAM(,[SSL_library_init()])],[found=1; break])
 706   done
 707   if test $found = 0 ; then
 708       AC_MSG_RESULT([error])
 709       AC_MSG_ERROR([cannot link with SSL - check config.log])
 710   fi
 711   LIBS="$save_LIBS $i"
 712   if test "$i" = "" ; then i="(none)" ; fi
 713   AC_MSG_RESULT($i)
 714   dnl XXX FIXME: use pkg-config if available!
 715   AC_DEFINE(SSL_ENABLE)
 716 else
 717   AC_MSG_NOTICE(Disabling SSL support.)
 718 fi
 719
 720 ###     use option --with-socks=DIR to point at SOCKS library
 721 AC_ARG_WITH(socks,
 722         [  --with-socks[=DIR]      add built-in SOCKS firewall access],
 723 [
 724 if test "$with_socks" != no
 725 then
 726     if test "$with_socks" != yes
 727     then
 728         LDEFLAGS="$LDEFLAGS -L$with_socks"
 729     else
 730         AC_CHECK_LIB(socks, Rconnect,,
 731                AC_MSG_ERROR([could not find libsocks which is needed for built-in SOCKS support]))
 732     fi
 733     AC_DEFINE(HAVE_SOCKS,1,Define if you want built-in SOCKS support)
 734     CEFLAGS="$CEFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 735     LIBS="-lsocks $LIBS"
 736 fi])
 737
 738 ###     use option --with-socks5=DIR to point at SOCKS library
 739 AC_ARG_WITH(socks5,
 740         [  --with-socks5[=DIR]     add built-in SOCKS5 firewall access],
 741 [
 742 if test "$with_socks5" != no
 743 then
 744   if test "$with_socks5" != yes
 745   then
 746     LDEFLAGS="$LDEFLAGS -L$with_socks5"
 747   fi
 748   ac_savedLDFLAGS="$LDFLAGS"
 749   LDFLAGS="$LDEFLAGS $LDFLAGS"
 750   AC_CHECK_LIB(socks5, SOCKSconnect,,
 751         AC_MSG_ERROR([could not find libsocks5 which is needed for built-in SOCKS5 support]))
 752   AC_DEFINE(HAVE_SOCKS)
 753   CEFLAGS="$CEFLAGS -Dconnect=SOCKSconnect -Dgetsockname=SOCKSgetsockname -Dbind=SOCKSbind -Daccept=SOCKSaccept -Dlisten=SOCKSlisten -Dselect=SOCKSselect -Drecvfrom=SOCKSrecvfrom -Dsendto=SOCKSsendto -Drecv=SOCKSrecv -Dsend=SOCKSsend -Dread=SOCKSread -Dwrite=SOCKSwrite -Drresvport=SOCKSrresvport -Dshutdown=SOCKSshutdown -Dlisten=SOCKSlisten -Dclose=SOCKSclose -Ddup=SOCKSdup -Ddup2=SOCKSdup2 -Dgethostbyname=SOCKSgethostbyname"
 754   AC_CHECK_FUNC(SOCKSfclose, [CFLAGS="$CFLAGS -Dfclose=SOCKSfclose"])
 755   LDFLAGS="$ac_savedLDFLAGS"
 756 fi])
 757
 758 ACX_WHICH_GETHOSTBYNAME_R
 759
 760 ###     use option --with-hesiod=DIR to point at a HESIOD directory
 761 AC_ma_SEARCH_PACKAGE(hesiod, hesiod_getmailhost, /usr/athena /usr /usr/local,hesiod, hesiod.h)
 762
 763 ###     use option --with-gssapi=DIR to compile in GSSAPI support
 764 AC_ARG_WITH(gssapi,
 765         [  --with-gssapi[=DIR]     compile in GSSAPI support using libraries in DIR],
 766 [
 767 if test "$with_gssapi" != "no"
 768 then
 769   if test "$with_gssapi" = "yes" -a -n "$with_kerberos5"
 770   then
 771     with_gssapi=$with_kerberos5
 772   fi
 773
 774   if test "$with_gssapi" != "yes" -a -n "$with_gssapi"
 775   then
 776     CFLAGS="$CFLAGS -I$with_gssapi/include"
 777     LDFLAGS="$LDFLAGS -L$with_gssapi/lib"
 778   fi
 779
 780   dnl obtain gssapi default libs
 781   if krb5-config --libs gssapi 2>/dev/null >/dev/null ; then
 782       LIBS="$LIBS `krb5-config --libs gssapi`"
 783   else
 784     AC_CHECK_LIB(gss, gss_check_version, LIBS="$LIBS -lgss", nogss=t)
 785     if test -n "$nogss"
 786     then
 787       # -lgss not found
 788       if test "$with_gssapi" = yes ; then
 789           with_gssapi=/usr
 790       fi
 791       if test -f "$with_gssapi/include/roken.h" -o -f "$with_gssapi/include/krb5/roken.h"
 792       then
 793          # have roken.h, assume Heimdal
 794          case `uname` in
 795              NetBSD) LIBS="$LIBS -lkrb5" ;;
 796              *)      LIBS="$LIBS -lkrb5 -lasn1 -ldes -lroken -ldb -ldl" ;;
 797          esac
 798          AC_CHECK_LIB(gssapi, gss_init_sec_context,LIBS="$LIBS -lgssapi",
 799                       AC_MSG_ERROR([could not find libgssapi which is needed for GSSAPI support]), )
 800          AC_DEFINE(HEIMDAL)
 801       else
 802          # no roken.h, assume MIT
 803          AC_CHECK_LIB(gssapi_krb5, gss_init_sec_context,LIBS="$LIBS -lgssapi_krb5",
 804                       AC_MSG_ERROR([could not find libgssapi_krb5 which is needed for GSSAPI support]), -lkrb5)
 805       fi
 806     fi
 807   fi
 808   AC_DEFINE(GSSAPI,1,Define if you want GSSAPI authentication)
 809   if test "$with_gssapi" != yes ; then
 810     CPPFLAGS="-I$with_gssapi/include"
 811   fi
 812   AC_CHECK_HEADERS(gss.h gssapi.h gssapi/gssapi.h gssapi/gssapi_generic.h)
 813   if test "$ac_cv_header_gssapi_h" = "yes"; then
 814     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE,1,Define if you have MIT kerberos))
 815   else
 816     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi/gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE))
 817   fi
 818 fi])
 819
 820 AC_SUBST(CPFLAGS)
 821 AC_SUBST(CEFLAGS)
 822 AC_SUBST(LDEFLAGS)
 823
 824 dnl ,------------------------------------------------------------------
 825 dnl Check if we need TRIO
 826 needtrio=0
 827 if test "$FORCE_TRIO" = "yes" ; then
 828     needtrio=1
 829     ac_cv_func_vsnprintf=no
 830     ac_cv_func_snprintf=no
 831 fi
 832 if test "x$ac_cv_func_snprintf" != "xyes" ; then
 833     AC_DEFINE(snprintf, trio_snprintf,
 834               [Define to trio_snprintf if your system lacks snprintf])
 835     needtrio=1
 836 fi
 837 if test "x$ac_cv_func_vsnprintf" != "xyes" ; then
 838     AC_DEFINE(vsnprintf, trio_vsnprintf,
 839               [Define to trio_vsnprintf if your system lacks vsnprintf])
 840     needtrio=1
 841 fi
 842 AM_CONDITIONAL(NEED_TRIO, test "$needtrio" = 1)
 843
 844 dnl TRIO IEEE compiler option for Alpha
 845 dnl
 846 if test "$needtrio" = 1 ; then
 847     AC_MSG_CHECKING(for IEEE compilation options)
 848     AC_CACHE_VAL(ac_cv_ieee_option, [
 849     AC_TRY_COMPILE(,[
 850     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && (defined(VMS) || defined(__VMS)))
 851     # error "Option needed"
 852     #endif
 853     ],ac_cv_ieee_option="/IEEE_MODE=UNDERFLOW_TO_ZERO/FLOAT=IEEE",
 854     AC_TRY_COMPILE(,[
 855     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && !(defined(VMS) || defined(__VMS)) && !defined(_CFE))
 856     # error "Option needed"
 857     #endif
 858     ],ac_cv_ieee_option="-ieee",
 859     AC_TRY_COMPILE(,[
 860     #if !(defined(__alpha) && (defined(__GNUC__) && (defined(__osf__) || defined(__linux__))))
 861     # error "Option needed"
 862     #endif
 863     ],ac_cv_ieee_option="-mieee",
 864     ac_cv_ieee_option="none"
 865     )
 866     )
 867     )
 868     ])
 869     AC_MSG_RESULT($ac_cv_ieee_option)
 870     if test $ac_cv_ieee_option != none; then
 871       CFLAGS="${CFLAGS} ${ac_cv_ieee_option}"
 872     fi
 873 fi
 874 dnl ----------------------------------------------------------------'
 875
 876 AC_CONFIG_FILES([Makefile m4/Makefile po/Makefile.in genlsm.sh])
 877 AC_OUTPUT
 878
 879 dnl Local Variables:
 880 dnl comment-start: "dnl "
 881 dnl comment-end: ""
 882 dnl comment-start-skip: "\\bdnl\\b\\s *"
 883 dnl compile-command: "make configure config.h.in"
 884 dnl End: