Pileus Git - ~andy/fetchmail/blob - configure.ac

   1 dnl Autoconfigure input file for fetchmail
   2 #
   3 # Fetchmail automatic configuration support
   4 #
   5 # Eric S. Raymond <esr@thyrsus.com>
   6 # 2004 - 2010 Matthias Andree <matthias.andree@gmx.de>
   7 #
   8 dnl Process this file with autoconf to produce a configure script.
   9 dnl
  10
  11 dnl XXX - if bumping version here, check fetchmail.man, too!
  12 AC_INIT([fetchmail],[6.3.15-beta3],[fetchmail-users@lists.berlios.de])
  13 AC_CONFIG_SRCDIR([fetchmail.h])
  14 AC_CONFIG_HEADERS([config.h])
  15 AC_CONFIG_LIBOBJ_DIR([.])
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl automake options are in Makefile.am
  20 AC_PREREQ(2.60)
  21 dnl 2.60 required for AC_USE_SYSTEM_EXTENSIONS
  22 AM_INIT_AUTOMAKE
  23
  24 dnl python is optional
  25 #
  26 # you can pass PYTHON=: in environment or on the command line
  27 # to disable python detection and continue without building/installing
  28 # fetchmail.conf -- be sure to check README.packaging, too!
  29 #
  30 AM_PATH_PYTHON(2.0,,AC_MSG_WARN([Disabling fetchmailconf: python 2.0 or greater not found]))
  31 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
  32
  33 AC_PROG_AWK
  34 AC_PROG_CC
  35 AC_PROG_INSTALL
  36 AC_PROG_CPP                     dnl Later checks need this.
  37 AC_PROG_RANLIB
  38 AM_PROG_CC_C_O
  39 AC_USE_SYSTEM_EXTENSIONS
  40
  41 AC_ISC_POSIX
  42 dnl AC_ISC_POSIX: - XXX FIXME: remove in fetchmail 6.4.
  43 dnl This macro adds `-lcposix' to output variable `LIBS' if necessary
  44 dnl for Posix facilities.  Sun dropped support for the obsolete
  45 dnl INTERACTIVE Systems Corporation Unix on 2006-07-23.  New programs
  46 dnl need not use this macro.  It is implemented as
  47 dnl `AC_SEARCH_LIBS([strerror], [cposix])'
  48
  49 dnl check for b0rked Solaris (and other shells) and find one that works
  50 AC_MSG_CHECKING(for a working shell...)
  51 for i in /usr/xpg6/bin/sh /usr/xpg4/bin/sh /usr/ccs/bin/sh /bin/sh /usr/bin/sh /bin/ksh /bin/bash /usr/local/bin/bash ; do
  52     $i -c 'if ! false ; then echo $(echo ok) ; fi' >config.$$ 2>/dev/null
  53     j=`cat config.$$`
  54     rm -f config.$$
  55     if test "x$j" = "xok" ; then
  56         SHELL=$i
  57         AC_SUBST(SHELL)
  58         break
  59     fi
  60 done
  61 AC_MSG_RESULT($SHELL)
  62 if test "x$SHELL" = "x" ; then
  63     AC_MSG_ERROR(no SUS compliant shell found - on Solaris, install SUNWxcu4)
  64 fi
  65
  66
  67 AC_HEADER_STDC
  68 AC_HEADER_TIME
  69 AC_TYPE_SIZE_T
  70 AC_TYPE_PID_T
  71 AC_TYPE_SIGNAL
  72 AC_CHECK_HEADERS([unistd.h termios.h termio.h sgtty.h stdarg.h \
  73         sys/itimer.h fcntl.h sys/fcntl.h memory.h sys/wait.h \
  74         arpa/inet.h arpa/nameser.h netinet/in.h net/socket.h netdb.h \
  75         sys/select.h sys/socket.h sys/time.h langinfo.h md5.h])
  76 if test _$ac_cv_header_stdarg_h != _yes ; then
  77 AC_MSG_WARN([stdarg.h is not defined. Unsupported configuration, proceed at your own risk.])
  78 fi
  79 AC_CHECK_TYPE(u_int32_t,,
  80         AC_DEFINE(u_int32_t,unsigned int,
  81                 [Define to unsigned int if <sys/types.h> does not define.]),
  82         [AC_INCLUDES_DEFAULT
  83 #ifdef HAVE_ARPA_NAMESER_H
  84 #include <arpa/nameser.h>
  85 #endif])
  86 AC_CHECK_HEADERS([resolv.h],,,[
  87 #include <sys/types.h>
  88 #ifdef HAVE_NETINET_IN_H
  89 #include <netinet/in.h>
  90 #endif
  91 #ifdef HAVE_ARPA_NAMESER_H
  92 #include <arpa/nameser.h>
  93 #endif
  94 ])
  95
  96 AC_CHECK_DECLS([h_errno],,,[
  97         AC_INCLUDES_DEFAULT
  98         #ifdef HAVE_NETDB_H
  99         #include <netdb.h>
 100         #endif
 101 ])
 102
 103 AC_C_CONST                      dnl getopt needs this.
 104
 105 AM_PROG_LEX
 106 AC_PROG_MAKE_SET
 107 AC_PROG_YACC
 108
 109 # Check for OS special cases
 110 case $host_os in
 111 darwin*)
 112     AC_MSG_NOTICE(found Darwin - Adding -DBIND_8_COMPAT to CFLAGS)
 113     CPPFLAGS="$CPPFLAGS -DBIND_8_COMPAT"
 114     ;;
 115 # Check for FreeBSD special case: more libs needed
 116 freebsd*)
 117     AC_MSG_NOTICE(found FreeBSD - Adding -lkvm -lcom_err to standard libraries)
 118     LIBS="$LIBS -lkvm -lcom_err"
 119     ;;
 120 # Check for LynxOS special case: -lbsd needed (at least on 2.3.0) and -s
 121 # not working.
 122 lynxos*)
 123     AC_MSG_NOTICE(found LynxOS - Adding -lbsd to standard libraries)
 124     LIBS="$LIBS -lbsd"
 125     LDFLAGS=`echo $LDFLAGS | sed "s/-s //"`
 126     AC_MSG_NOTICE(found LynxOS - Prepending standard include path to gcc flags)
 127     CPPFLAGS="$CPPFLAGS -I/usr/include"
 128     ;;
 129 # Check for Rhapsody special case: it doesn't like -s
 130 rhapsody*)
 131     AC_MSG_NOTICE(found Rhapsody - Removing -s load flag)
 132     LDFLAGS=`echo $LDFLAGS | sed "s/-s //"`
 133     ;;
 134 esac
 135
 136 AC_CACHE_SAVE
 137
 138 dnl i18n
 139 AM_GNU_GETTEXT([external], [need-ngettext])
 140 AM_GNU_GETTEXT_VERSION([0.14.6])
 141 dnl end i18n
 142
 143 # Under sysV68, socket and friends are provided by the C library.
 144 # -linet does not provide socket, but causes multiple definition
 145 # errors at link-time.  It is thus better to only use the C library.
 146 # So don't add -linet to the link list unless it's necessary
 147 AC_CHECK_FUNC(socket,
 148     AC_MSG_RESULT(using libc's socket),
 149     AC_CHECK_LIB(socket,socket)
 150     AC_CHECK_LIB(inet,socket))
 151
 152 # The condition in this test copes with the presence of inet_addr in libc6.
 153 AC_CHECK_FUNC(inet_addr,
 154     AC_MSG_RESULT(using libc's inet_addr),
 155     AC_CHECK_LIB(nsl,inet_addr))
 156
 157 dnl Port hack for Interactive UNIX System V/386 Release 3.2
 158 AC_CHECK_LIB(cposix, strchr,
 159                 [DEFS="$DEFS -D_SYSV3"
 160                 LIBS="$LIBS -lcposix"])
 161
 162 dnl Port hack for Sparc/NetBSD-1.5
 163 dnl
 164 dnl NB: this has been disabled as it causes the unconditional
 165 dnl addition of libintl to the build, which is both undesired
 166 dnl and breaks on Solaris/Blastwave.org machines.
 167 dnl
 168 dnl AC_CHECK_LIB(intl, gettext,
 169 dnl             [LIBS="$LIBS -lintl"])
 170
 171 AC_REPLACE_FUNCS([strstr strcasecmp memmove stpcpy strlcpy strlcat])
 172
 173 AC_SEARCH_LIBS(MD5Init, [md5 md], [],
 174               [AC_LIBSOURCE(md5c.c)
 175                EXTRAOBJ="$EXTRAOBJ md5c.\$(OBJEXT)"])
 176
 177 AC_CHECK_FUNC(getopt_long, [],
 178               [AC_LIBSOURCES([getopt.c, getopt1.c])
 179                EXTRAOBJ="$EXTRAOBJ getopt.\$(OBJEXT) getopt1.\$(OBJEXT)"])
 180
 181 AC_FUNC_VPRINTF
 182
 183 AC_SUBST(EXTRAOBJ)
 184
 185 AC_CHECK_FUNCS(tcsetattr stty setsid geteuid seteuid dnl
 186   strerror syslog snprintf vprintf vsnprintf vsyslog dnl
 187   atexit inet_aton strftime setrlimit socketpair dnl
 188   sigaction strdup setlocale)
 189
 190 AC_CHECK_DECLS([strerror,getenv])
 191 dnl INET6 is used by KAME/getnameinfo
 192 AC_CACHE_CHECK(for AF_INET6/PF_INET6,ac_cv_inet6,
 193 AC_COMPILE_IFELSE([
 194   AC_LANG_PROGRAM([[
 195     #ifdef HAVE_SYS_TYPES_H
 196     #include <sys/types.h>
 197     #endif
 198     #ifdef HAVE_SYS_SOCKET_H
 199     #include <sys/socket.h>
 200     #endif
 201   ]],[[
 202     int foo = AF_INET6;
 203     int bar = PF_INET6;
 204   ]])],
 205   ac_cv_inet6=yes , ac_cv_inet6=no
 206 ))
 207 if test "x$ac_cv_inet6" = xyes
 208 then
 209     AC_DEFINE(INET6,1,Define to 1 if your system defines AF_INET6 and PF_INET6.)
 210 fi
 211
 212 # Under Red Hat 4.0 (and many other Linuxes) -lresolv is seriously flaky
 213 # and breaks gethostbyname(2).  It's better to use the bind stuff in the C
 214 # library.  So don't add -lresolv to the link list unless it's necessary
 215 # (It will be necessary when using GNU libc6).
 216 old_LIBS="$LIBS"
 217 for lib in '' -lresolv; do
 218     if test -z "$lib"; then
 219        AC_MSG_CHECKING([for res_search in libc])
 220     else
 221        AC_MSG_CHECKING([for res_search in $lib])
 222     fi
 223     LIBS="$old_LIBS $lib"
 224     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 225 #include <sys/types.h>
 226 #ifdef HAVE_NETINET_IN_H
 227 #include <netinet/in.h>
 228 #endif
 229 #ifdef HAVE_ARPA_NAMESER_H
 230 #include <arpa/nameser.h>
 231 #endif
 232 #ifdef HAVE_RESOLV_H
 233 #include <resolv.h>
 234 #endif
 235 extern int res_search();
 236 ]], [[res_search(0, 0, 0, 0, 0); dn_skipname(0,0);]])],
 237     [AC_MSG_RESULT([found])
 238      AC_DEFINE(HAVE_RES_SEARCH, [1],
 239                [Define to 1 if you have the 'res_search' and 'dn_skipname' functions.])
 240      break], [AC_MSG_RESULT([not found])])
 241      LIBS=$old_LIBS
 242 done
 243
 244 dnl Check for libcrypt -- it may live in libc or libcrypt, as on IRIX
 245 AC_CHECK_FUNC(crypt, , AC_CHECK_LIB(crypt,crypt))
 246
 247 dnl Check for RSA refersence library in case we're using SSL
 248 AC_CHECK_LIB(rsaref, RSAPublicDecrypt)
 249
 250 dnl AC_FUNC_SETVBUF_REVERSED
 251
 252 dnl Check for usable void pointer type
 253 AC_MSG_CHECKING(use of void pointer type)
 254 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[char *p;
 255     void *xmalloc();
 256     p = (char *) xmalloc(1);
 257    ]])],[AC_DEFINE(HAVE_VOIDPOINTER,1,[Define if your C compiler allows void * as a function result]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 258
 259 dnl Check for ANSI volatile
 260 AC_C_VOLATILE
 261
 262 dnl Check out the wait reality.  We have to assume sys/wait.h is present.
 263 AC_CHECK_FUNCS(waitpid wait3)
 264 AC_MSG_CHECKING(for union wait);
 265 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 266 #include <sys/wait.h>]], [[union wait status; int pid; pid = wait (&status);
 267 #ifdef WEXITSTATUS
 268 /* Some POSIXoid systems have both the new-style macros and the old
 269    union wait type, and they do not work together.  If union wait
 270    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 271 if (WEXITSTATUS (status) != 0) pid = -1;
 272 #endif
 273 #ifdef HAVE_WAITPID
 274 /* Make sure union wait works with waitpid.  */
 275 pid = waitpid (-1, &status, 0);
 276 #endif
 277 ]])],[AC_DEFINE(HAVE_UNION_WAIT,1,Define if 'union wait' is the type of the first arg to wait functions.) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 278
 279 AC_MSG_CHECKING(sys_siglist declaration in signal.h or unistd.h)
 280 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>
 281 /* NetBSD declares sys_siglist in <unistd.h>.  */
 282 #ifdef HAVE_UNISTD_H
 283 #include <unistd.h>
 284 #endif]], [[char *msg = *(sys_siglist + 1);]])],[AC_DEFINE(SYS_SIGLIST_DECLARED,1,[Define if 'sys_siglist' is declared by <signal.h>.]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 285
 286 # Find the right directory to put the root-mode PID file in
 287 for dir in "/var/run" "/etc"
 288 do
 289         if test -d $dir
 290         then
 291                 break;
 292         fi
 293 done
 294 AC_MSG_RESULT(root-mode pid file will go in $dir)
 295 AC_DEFINE_UNQUOTED(PID_DIR, "$dir", directory for PID lock files)
 296
 297 # We may have a fallback MDA available in case the socket open to the
 298 # local SMTP listener fails.  Best to use procmail for this, as we know
 299 # it won't try delivering through local SMTP and cause a mail loop.
 300 # Sendmail without the -t option to use the message headers will work too,
 301 # not just for sendmail itself but for workalikes like exim.
 302 #
 303 # Note1: A disadvantage of using procmail is that local alias expansion
 304 # according to /etc/aliases won't get done if we fall back.  This doesn't
 305 # matter in single-drop mode.
 306 #
 307 # Note2: it would be a very bad idea to use any MDA that doesn't return
 308 # a refuse-to-deliver status on disk- or process-table-full
 309 # conditions; mail could get lost that way.  Sendmail and all of the MDAs
 310 # like exim that might be lurking under a sendmail alias) do the right
 311 # thing in this circumstance.  Matthias Andree warns that procmail does
 312 # not.
 313 #
 314 # Note3: Defalt value of fallback is now off.  Matthias writes:
 315 #
 316 # 1. there is no way to predict when the fallback is used. With some MTAs
 317 #    (such as those limiting load average), outer circumstances can cause
 318 #    the fallback to kick in.
 319 #
 320 # 2. the fallback changes fetchmail behaviour in unpredictable ways. It's
 321 #    not only about alias expansion, .forwards to special filters won't
 322 #    work, mail may end up in a different place (users claim "mail loss"
 323 #    for that).
 324 #
 325 # 3. The claim procmail did the right thing with its exit codes is plain
 326 #    wrong. I've seen procmail exit with code 1 when it should have exited
 327 #    with code 75, like, configuration errors. Procmail is a dangerous
 328 #    beast and is best replaced by maildrop.
 329 #
 330 # 4. if multiple choices exist (like procmail and maildrop), fetchmail
 331 #    cannot tell which one it should choose. Say, your MTA is configured
 332 #    to use maildrop to deliver to user's mailboxes, if fetchmail then
 333 #    chooses procmail, this is plain wrong.
 334 #
 335
 336 AC_PATH_PROG(procmail, procmail, "", $PATH:/usr/sbin)
 337 AC_PATH_PROG(sendmail, sendmail, "", $PATH:/usr/sbin:/usr/lib)
 338 AC_PATH_PROG(maildrop, maildrop, "", $PATH:/usr/local/bin)
 339
 340 ###     use option --disable-fallback to disable fallback MDA
 341 ###     use option --enable-fallback=procmail or
 342 ###                --enable-fallback=sendmail to select
 343 AC_ARG_ENABLE(fallback,
 344         [  --enable-fallback=procmail    enable procmail as fallback
 345   --enable-fallback=sendmail    enable /usr/sbin/sendmail as fallback
 346   --enable-fallback=maildrop    enable maildrop as fallback
 347   --enable-fallback=no          disable fallback],,[enable_fallback=no])
 348
 349 case "$enable_fallback" in
 350         sendmail)       if test -z "$sendmail" ; then
 351                                 AC_MSG_ERROR([Sendmail selected as fallback, but not found])
 352                                 #not reached
 353                         fi
 354                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$sendmail -i %T", Fallback MTA to use if defined)
 355                         AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 356                         ;;
 357         procmail)       if test -z "$procmail" ; then
 358                                 AC_MSG_ERROR([procmail selected as fallback, but not found])
 359                                 #not reached
 360                         fi
 361                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$procmail -d %T")
 362                         AC_MSG_NOTICE(Will use $procmail as fallback MDA.)
 363                         ;;
 364         maildrop)       if test -z "$maildrop" ; then
 365                                 AC_MSG_ERROR([maildrop selected as fallback, but not found])
 366                                 #not reached
 367                         fi
 368                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$maildrop -d %T")
 369                         AC_MSG_NOTICE(Will use $maildrop as fallback MDA.)
 370                         ;;
 371         no|unset)       AC_MSG_NOTICE(Will not use a fallback MDA.)
 372                         ;;
 373         auto|yes|set)   if test -n "$sendmail" ; then
 374                                 AC_DEFINE_UNQUOTED(FALLBACK_MDA,"$sendmail -i %T")
 375                                 AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 376                         else
 377                                 AC_MSG_WARN(No fallback MDA available.  procmail and maildrop are not eligible)
 378                                 AC_MSG_WARN(for automatic fallback MDA configuration for reliability reasons.)
 379                         fi
 380                         ;;
 381         *)              AC_MSG_ERROR([unkown value for --enable-fallback given: $enable_fallback])
 382                         #notreached
 383                         ;;
 384 esac
 385
 386 AC_CHECK_SIZEOF(short)
 387 AC_CHECK_SIZEOF(int)
 388 AC_CHECK_SIZEOF(long)
 389
 390 ###     use option --enable-POP2 to compile in the POP2 support
 391 AC_ARG_ENABLE(POP2,
 392         [  --enable-POP2           compile in POP2 protocol support (obsolete)],
 393         [with_POP2=$enableval],
 394         [with_POP2=no])
 395 test "$with_POP2" = "yes" && AC_DEFINE(POP2_ENABLE,1,Define if you want POP2 support compiled in)
 396 AM_CONDITIONAL(POP2_ENABLE, test "$with_POP2" = yes)
 397
 398 ###     use option --disable-POP3 to omit the POP3 support
 399 AC_ARG_ENABLE(POP3,
 400         [  --disable-POP3          don't compile in POP3 protocol support],
 401         [with_POP3=$enableval],
 402         [with_POP3=yes])
 403 test "$with_POP3" = "yes" && AC_DEFINE(POP3_ENABLE,1,Define if you want POP3 support compiled in)
 404 AM_CONDITIONAL(POP3_ENABLE, test "$with_POP3" = yes)
 405
 406 ###     use option --disable-IMAP to omit the IMAP support
 407 AC_ARG_ENABLE(IMAP,
 408         [  --disable-IMAP          don't compile in IMAP protocol support],
 409         [with_IMAP=$enableval],
 410         [with_IMAP=yes])
 411 test "$with_IMAP" = "yes" && AC_DEFINE(IMAP_ENABLE,1,Define if you want IMAP support compiled in)
 412 AM_CONDITIONAL(IMAP_ENABLE, test "$with_IMAP" = yes)
 413
 414 ###     use option --disable-ETRN to omit the ETRN support
 415 AC_ARG_ENABLE(ETRN,
 416         [  --disable-ETRN          don't compile in ETRN protocol support],
 417         [with_ETRN=$enableval],
 418         [with_ETRN=yes])
 419 test "$with_ETRN" = "yes" && AC_DEFINE(ETRN_ENABLE,1,Define if you want ETRN support compiled in.)
 420 AM_CONDITIONAL(ETRN_ENABLE, test "$with_ETRN" = yes)
 421
 422 ###     use option --disable-ODMR to omit the ODMR support
 423 AC_ARG_ENABLE(ODMR,
 424         [  --disable-ODMR          don't compile in ODMR protocol support],
 425         [with_ODMR=$enableval],
 426         [with_ODMR=yes])
 427 test "$with_ODMR" = "yes" && AC_DEFINE(ODMR_ENABLE,1,Define if you want ODMR support compiled in)
 428 AM_CONDITIONAL(ODMR_ENABLE, test "$with_ODMR" = yes)
 429
 430 ###     use option --enable-RPA to compile in the RPA support
 431 AC_ARG_ENABLE(RPA,
 432         [  --enable-RPA            compile in RPA protocol support],
 433         [with_RPA=$enableval],
 434         [with_RPA=no])
 435 test "$with_RPA" = "yes" && AC_DEFINE(RPA_ENABLE,1,Define if you want RPA support compiled in)
 436 AM_CONDITIONAL(RPA_ENABLE, test "$with_RPA" = yes)
 437
 438 ###     use option --enable-NTLM to compile in the NTLM support
 439 AC_ARG_ENABLE(NTLM,
 440         [  --enable-NTLM           compile in NTLM authentication support],
 441         [with_NTLM=$enableval],
 442         [with_NTLM=no])
 443 test "$with_NTLM" = "yes" && AC_DEFINE(NTLM_ENABLE,1,Define if you want NTLM authentication)
 444
 445 ###     use option --enable-SDPS to compile in the SDPS support
 446 AC_ARG_ENABLE(SDPS,
 447         [  --enable-SDPS           compile in SDPS protocol support],
 448         [with_SDPS=$enableval],
 449         [with_SDPS=no])
 450 if test "$with_SDPS" = yes ; then
 451    if test "$with_POP3" != yes ; then
 452        AC_MSG_WARN([SDPS cannot be enabled with POP3 disabled. Disabling SDPS.])
 453        with_SDPS=no
 454    else
 455        AC_DEFINE(SDPS_ENABLE,1,Define if you want SDPS support compiled in)
 456    fi
 457 fi
 458 if test "$with_POP3" != yes && test "$with_POP2" != yes \
 459     && test "$with_IMAP"  != yes ; then
 460     AC_MSG_ERROR([You must enable at least one of POP2, POP3 and IMAP.])
 461 fi
 462
 463 AC_CACHE_SAVE
 464
 465 ###     use option --enable-opie to compile in the OPIE support
 466 AC_ARG_ENABLE(opie,
 467         [  --enable-opie           support OTP through the OPIE library],
 468         [ AC_CHECK_HEADER(opie.h,, [AC_MSG_ERROR(cannot find <opie.h>, which is required for OPIE support.)])
 469           AC_CHECK_LIB(opie,opiegenerator,, [AC_MSG_ERROR(cannot find libopie, which is required for OPIE support.)])
 470           with_opie=$enableval],
 471         [with_opie=no])
 472 test "$with_opie" = "yes" && AC_DEFINE(OPIE_ENABLE,1,Define if you want OPIE support compiled in)
 473
 474 dnl Mostly stolen from gnulib's getaddrinfo.m4
 475 AC_SEARCH_LIBS(getaddrinfo, [nsl socket])
 476 AC_CACHE_CHECK([for getaddrinfo],[fm_cv_getaddrinfo],[
 477   AC_TRY_LINK([
 478 #include <sys/types.h>
 479 #ifdef HAVE_SYS_SOCKET_H
 480 #include <sys/socket.h>
 481 #endif
 482 #ifdef HAVE_NETDB_H
 483 #include <netdb.h>
 484 #endif
 485   ], [getaddrinfo(0, 0, 0, 0);],
 486     [ fm_cv_getaddrinfo=yes],
 487     [ fm_cv_getaddrinfo=no ])
 488 ])
 489
 490 if test x"$fm_cv_getaddrinfo" = "xyes"; then
 491      AC_DEFINE(HAVE_GETADDRINFO, 1,
 492       [Define to 1 if you have the getaddrinfo function.])
 493 fi
 494
 495 AC_CACHE_CHECK([for getnameinfo],[fm_cv_getnameinfo],[
 496   AC_TRY_LINK([
 497 #include <sys/types.h>
 498 #ifdef HAVE_SYS_SOCKET_H
 499 #include <sys/socket.h>
 500 #endif
 501 #ifdef HAVE_NETDB_H
 502 #include <netdb.h>
 503 #endif
 504 #ifndef NULL
 505 #define NULL 0
 506 #endif
 507   ], [getnameinfo(NULL,0, NULL,0, NULL, 0, 0);],
 508     [ fm_cv_getnameinfo=yes],
 509     [ fm_cv_getnameinfo=no ])
 510 ])
 511 if test $fm_cv_getnameinfo = yes ; then
 512     AC_DEFINE(HAVE_GETNAMEINFO,1,[Define to 1 if your system has getnameinfo()])
 513 fi
 514
 515 AM_CONDITIONAL(NEED_GETADDRINFO, test "$fm_cv_getaddrinfo" != yes)
 516 AM_CONDITIONAL(NEED_GETNAMEINFO, test "$fm_cv_getnameinfo"   != yes)
 517
 518 AC_CHECK_FUNCS(inet_ntop)
 519 dnl Check if getaddrinfo is async-signal-safe - most implementations aren't
 520 if test "$fm_cv_getaddrinfo" = yes ; then
 521     AC_MSG_CHECKING(if your getaddrinfo is async-signal-safe)
 522     gai_ts=no
 523     dnl we have getaddrinfo() - check if the OS is known to have a async-signal-safe implementation
 524     case $host_os in
 525         darwin9*)                               gai_ts=yes ;;
 526         linux*)                                 gai_ts=yes ;;
 527         freebsd5.5|freebsd6*|freebsd7*)         gai_ts=yes ;;
 528         solaris2.8|solaris2.9|solaris2.10)      gai_ts=yes ;;
 529     esac
 530     AC_MSG_RESULT($gai_ts)
 531     if test $gai_ts = yes ; then
 532         AC_DEFINE(GETADDRINFO_ASYNCSAFE, 1, [define to 1 if you know your getaddrinfo function is async-signal-safe])
 533     fi
 534 fi
 535
 536 # This version of the Kerberos 4 and 5 options addresses the follwing issues:
 537 #
 538 # * Build correctly under Heimdal kerberos if it is compiled with db2 and
 539 #   OpenSSL support (Debian's is)
 540 # * Build the kerberos.c stuff (KPOP) only for kerberosIV, to avoid breakage.
 541 #   I don't know if this is 100% correct, but now at least IMAP and POP3
 542 #   behave the same way regarding kerberosV.
 543 # * Build without any fuss for both kerberosIV and V at the same time.
 544 # * Move all the kerberos header mess to kerberos.h, and #include that
 545 #   in driver.c and kerberos.c.
 546 #
 547 # Tested using the Heimdal Kerberos V libs, Kungliga Tekniska Högskolan (the
 548 # Royal Institute of Technology in Stockholm, Sweden)'s kerberos IV libs, and
 549 # the MIT reference implementation of KerberosV (all as packaged in Debian).
 550
 551 ###    use option --with-kerberos5=DIR to point at a Kerberos 5 directory
 552 ### make sure --with-ssl is run before --with-kerberos* !
 553 AC_ARG_WITH(kerberos5,
 554        [  --with-kerberos5=DIR    point fetchmail compilation at a Kerberos 5 directory],
 555 [
 556 if test "$with_kerberos5" != "no"
 557 then
 558 # Check for a OpenBSD special case
 559 if test "$with_kerberos5" = "yes" && ( test `uname` = "OpenBSD" )
 560 then
 561   AS_MESSAGE(checking kerberosV for OpenBSD...)
 562   AC_DEFINE(HEIMDAL,1,Define if you have HEIMDAL kerberos 5)
 563   AC_DEFINE(KERBEROS_V5,1,Define if you have Kerberos V5)
 564   CFLAGS="$CFLAGS -I/usr/include/kerberosV"
 565   LIBS="$LIBS -lasn1 -lkrb5 -lcom_err -lkafs"
 566 elif krb5-config 2> /dev/null >/dev/null ; then
 567   krb5_prefix=`krb5-config --prefix krb5`
 568   AC_MSG_RESULT([krb5-config points to kerberosV under $krb5_prefix])
 569   if test -f ${krb5_prefix}/include/et/com_err.h && \
 570    ! test -f ${krb5_prefix}/include/com_err.h  ; then
 571     CFLAGS="$CFLAGS -I${krb5_prefix}/include/et"
 572   fi
 573   unset krb5_prefix
 574   CFLAGS="$CFLAGS `krb5-config --cflags krb5`"
 575   LIBS="$LIBS `krb5-config --libs krb5`"
 576   AC_DEFINE(KERBEROS_V5)
 577 else
 578   if test "$with_kerberos5" != "yes"
 579   then
 580       LDFLAGS="$LDFLAGS -L${with_kerberos5}/lib"
 581       searchdirs="$with_kerberos5"
 582   else
 583       searchdirs="/usr/kerberos /usr/local/krb5 /usr/athena /usr"
 584   fi
 585   with_kerberos5=
 586   for dir in $searchdirs
 587   do AC_MSG_CHECKING([for Kerberos V in $dir])
 588      if test -f "$dir/include/krb5.h" || test -f "$dir/include/krb5/krb5.h"
 589      then
 590         if test -d "$dir/include/krb5" ; then CPPFLAGS="$CPPFLAGS -I$dir/include/krb5" ; fi
 591         ac_krblibs=
 592         if test -f "$dir/include/roken.h" || test -f "$dir/include/krb5/roken.h"
 593         then
 594            ac_krblibs="-lasn1 -lroken -lcom_err"
 595            AC_MSG_RESULT([Heimdal found])
 596           dnl Attempt to detect if we need to -ldb2 to link Heimdal
 597           dnl we assume we do if it is available
 598            AC_CHECK_LIB(db2, db_open, ac_krblibs="$ac_krblibs -ldb2", [],
 599                 ${LDFLAGS})
 600            AC_CHECK_LIB(des, des_string_to_key, libk5crypto=-ldes,
 601               AC_CHECK_LIB(crypto, MD5_Init, [],
 602                 AC_MSG_ERROR([DES libraries not found. Try adding --with-ssl to enable OpenSSL support]),
 603                 ${LDFLAGS} ${ac_krblibs}),
 604            ${LDFLAGS} ${ac_krblibs})
 605            AC_DEFINE(HEIMDAL)
 606         else
 607           AC_MSG_RESULT([found])
 608           ac_krblibs="-lcom_err"
 609            AC_CHECK_LIB(crypto,
 610              krb5_des_string_to_key,
 611              libk5crypto=-lcrypto,
 612                 AC_CHECK_LIB(k5crypto,
 613                    krb5_des_string_to_key,
 614                    libk5crypto=-lk5crypto,
 615                       AC_MSG_ERROR([Kerberos 5 DES libraries not found]),
 616                    ${LDFLAGS} ${ac_krblibs}),
 617                  ${LDFLAGS} ${ac_krblibs})
 618         fi
 619         AC_CHECK_LIB(krb5, krb5_init_context,[],
 620            continue,
 621            ${LDFLAGS} ${ac_krblibs})
 622         AC_DEFINE(KERBEROS_V5)
 623         test "$dir" != "/usr" && CFLAGS="$CFLAGS -I$dir/include"
 624         LDFLAGS="$LDFLAGS -L$dir/lib"
 625        LIBS="$LIBS $ac_krblibs $libk5crypto"
 626         with_kerberos5=$dir
 627         break
 628      else
 629         AC_MSG_RESULT([not found])
 630      fi
 631   done
 632   if test -z "$with_kerberos5" ; then
 633      AC_MSG_ERROR([Kerberos 5 libraries not found])
 634   fi
 635 fi
 636 fi
 637 ]) dnl --with-kerberos5=DIR
 638
 639 ###    use option --with-kerberos=DIR to point at a Kerberos 4 directory
 640 KERBEROS_V4=0
 641 AC_ARG_WITH(kerberos,
 642        [  --with-kerberos=DIR     point fetchmail compilation at a Kerberos 4 directory],
 643 [
 644 if test "$with_kerberos" != "no"
 645 then
 646     AC_MSG_WARN([Kerberos IV support is obsolete. Use --with-kerberos5 if possible.])
 647 # Check for a NetBSD/OpenBSD special case
 648 if test "$with_kerberos" = "yes" && ( test `uname` = "NetBSD" || test `uname` = "OpenBSD" )
 649 then
 650   AS_MESSAGE(checking kerberosIV for `uname`...)
 651   KERBEROS_V4=1
 652   CFLAGS="$CFLAGS -I/usr/include/kerberosIV"
 653   case `uname` in
 654       NetBSD)  LIBS="$LIBS -lkrb -ldes -lroken -lcom_err" ;;
 655       OpenBSD) LIBS="$LIBS -lkrb -ldes" ;;
 656   esac
 657 elif krb4-config 2> /dev/null >/dev/null ; then
 658   krb4_prefix=`krb4-config --prefix`
 659   AC_MSG_RESULT([krb4-config points to kerberosIV under $krb4_prefix])
 660   unset krb4_prefix
 661   CFLAGS="$CFLAGS `krb4-config --cflags`"
 662   LIBS="$LIBS `krb4-config --libs`"
 663   KERBEROS_V4=1
 664 elif krb5-config 2> /dev/null >/dev/null ; then
 665   krb4_prefix=`krb5-config --prefix krb4`
 666   AC_MSG_RESULT([krb5-config points to kerberosIV under $krb4_prefix])
 667   if test -f ${krb4_prefix}/include/kerberosIV/krb.h ; then
 668     AC_DEFINE(KERBEROS_V4_V5,1,Define if you have Kerberos V4 headers under a kerberosIV directory)
 669   fi
 670   unset krb4_prefix
 671   CFLAGS="$CFLAGS `krb5-config --cflags krb4`"
 672   LIBS="$LIBS `krb5-config --libs krb4`"
 673   KERBEROS_V4=1
 674 else
 675   #we need to detect when we're building under a kerberosV compatibility
 676   #layer, btw...
 677   if test "$with_kerberos" != "yes" ; then
 678      searchdirs="$with_kerberos"
 679   else
 680      searchdirs="$with_kerberos5 /usr/kerberos /usr/kerberosIV /usr/athena /usr"
 681   fi
 682   with_kerberos=
 683   ac_saveLDFLAGS="$LDFLAGS"
 684   for dir in $searchdirs
 685   do
 686      AC_MSG_CHECKING([for Kerberos IV in $dir])
 687      if test -f "$dir/include/krb.h" || test -f "$dir/include/krb4.h" \
 688             || test -f "$dir/include/kerberosIV/krb.h"
 689      then
 690         AC_MSG_RESULT([found])
 691      else
 692         AC_MSG_RESULT([not found])
 693        continue
 694      fi
 695      #Find libs
 696      if test -f "$with_kerberos5/roken.h" ; then
 697        AC_CHECK_LIB(45, krb_mk_req)
 698      fi
 699      LDFLAGS="-L$dir/lib $ac_saveLDFLAGS"
 700      if test `uname` = "FreeBSD"; then
 701         AC_SEARCH_LIBS(_ossl_old_des_string_to_key, [des425 des crypto], [], continue)
 702      else
 703         AC_SEARCH_LIBS(des_string_to_key, [crypto], [], continue)
 704      fi
 705      AC_SEARCH_LIBS(krb_realmofhost, [krb4 krb], [], continue)
 706      with_kerberos="$dir"
 707      if test -f "$dir/include/kerberosIV/krb.h" ; then
 708         dir="$dir/include/kerberosIV"
 709      else
 710        dir="$dir/include"
 711      fi
 712      KERBEROS_V4=1
 713      test -f "$with_kerberos5/roken.h" && AC_DEFINE(HEIMDAL)
 714      test "$dir" != "/usr/include" && CFLAGS="$CFLAGS -I$dir"
 715      LDFLAGS="$LDFLAGS -L$with_kerberos/lib"
 716      break
 717   done
 718   if test -z "$with_kerberos" ; then
 719      AC_MSG_ERROR([Kerberos 4 libraries not found])
 720   fi
 721   LDFLAGS="$ac_saveLDFLAGS"
 722 fi
 723 fi
 724 ]) dnl --with-kerberos=DIR
 725 if test "$KERBEROS_V4" = 1 ; then
 726     AC_DEFINE(KERBEROS_V4,1,Define if you have Kerberos V4)
 727 fi
 728 AM_CONDITIONAL(KERBEROS_V4_ENABLE, test "$KERBEROS_V4" = 1)
 729
 730 ###     use option --with-ssl to compile in the SSL support
 731 AC_ARG_WITH(ssl,
 732         [  --with-ssl=[DIR]        enable SSL support using libraries in DIR],
 733         [with_ssl=$withval],
 734         [with_ssl=no])
 735 test "$with_ssl" != "no" && AC_DEFINE(SSL_ENABLE,1,Define if you want SSL support compiled in)
 736
 737 if test "$with_ssl" = "yes"
 738 then
 739     #   User didn't specify an SSL location.  Let's look at some common
 740     #   directories where SSL has been found in the past and try and auto
 741     #   configure for SSL.  OpenSSL determination will be made later.
 742     #   This will screw up if an OpenSSL install is located in a later
 743     #   directory than an older SSLeay install, but the user should fix that
 744     #   anyways and he can override on the configure line.
 745     #   Just testing for directories is not sufficient, /usr exists on
 746     #   all systems!
 747     for ac_dir in \
 748       /usr/local/ssl \
 749       /usr/local \
 750       /usr/ssl \
 751       /usr \
 752       /local/ssl \
 753       /opt/ssl \
 754       /opt/csw \
 755       ; \
 756     do
 757         if test -r "$ac_dir/include/openssl/ssl.h" ; then
 758             with_ssl=$ac_dir
 759             break;
 760         fi
 761     done
 762 fi
 763
 764 if test -n "$with_ssl" -a "$with_ssl" != "no"
 765 then
 766   # With the autoconfigure above, the only time this is going to be
 767   # true is going to be when we could not find the headers.  If they
 768   # are not in system standard locations, we are going to be broken.
 769   if test "$with_ssl" = "yes"
 770   then
 771     # Let's just define the standard location for the SSLeay root
 772     with_ssl="/usr/local/ssl"
 773   fi
 774   if test -r $with_ssl/include/openssl/ssl.h
 775   then
 776     ### ssl.h found under openssl.  Use openssl configuration preferentially,
 777     AC_MSG_NOTICE(Enabling OpenSSL support in $with_ssl.)
 778     test "$with_ssl" != "/usr" && CFLAGS="$CFLAGS -I$with_ssl/include"
 779     ### In Red Hat 9, this file includes a reference to <krb5.h>, so we
 780     ### force the Kerberos direcory onto the include path so it will build.
 781     CFLAGS="$CFLAGS -I/usr/kerberos/include"
 782     ### OpenBSD comes with ssl headers
 783   else
 784     AC_MSG_ERROR([SSL support enabled, but OpenSSL not found])
 785   fi
 786   LDFLAGS="$LDFLAGS -L$with_ssl/lib"
 787   LIBS="$LIBS -lssl -lcrypto"
 788   dnl check if -ldl is needed
 789   AC_MSG_CHECKING([for additional library dependencies of SSL])
 790   found=0
 791   save_LIBS="$LIBS"
 792   for i in "" "-ldl" ; do
 793       LIBS="$LDFLAGS $save_LIBS $i"
 794       AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <openssl/ssl.h>],[SSL_library_init()])],[found=1; break])
 795   done
 796   if test $found = 0 ; then
 797       AC_MSG_RESULT([error])
 798       AC_MSG_ERROR([cannot link with SSL - check config.log])
 799   fi
 800   LIBS="$save_LIBS $i"
 801   if test "$i" = "" ; then i="(none)" ; fi
 802   AC_MSG_RESULT($i)
 803   dnl XXX FIXME: use pkg-config if available!
 804   AC_DEFINE(SSL_ENABLE)
 805 else
 806   AC_MSG_NOTICE(Disabling SSL support.)
 807 fi
 808
 809 ###     use option --with-socks=DIR to point at SOCKS library
 810 AC_ARG_WITH(socks,
 811         [  --with-socks[=DIR]      add built-in SOCKS firewall access],
 812 [
 813 if test "$with_socks" != no
 814 then
 815     if test "$with_socks" != yes
 816     then
 817         LDFLAGS="$LDFLAGS -L$with_socks"
 818     else
 819         AC_CHECK_LIB(socks, Rconnect,,
 820                AC_MSG_ERROR([could not find libsocks which is needed for built-in SOCKS support]))
 821     fi
 822     AC_DEFINE(HAVE_SOCKS,1,Define if you want built-in SOCKS support)
 823     CFLAGS="$CFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 824     LIBS="-lsocks $LIBS"
 825 fi])
 826
 827 ###     use option --with-socks5=DIR to point at SOCKS library
 828 AC_ARG_WITH(socks5,
 829         [  --with-socks5[=DIR]     add built-in SOCKS5 firewall access],
 830 [
 831 if test "$with_socks5" != no
 832 then
 833   if test "$with_socks5" != yes
 834   then
 835     LDFLAGS="$LDFLAGS -L$with_socks5"
 836   fi
 837   ac_savedLDFLAGS="$LDFLAGS"
 838   LDFLAGS="$LDFLAGS $LDFLAGS"
 839   AC_CHECK_LIB(socks5, SOCKSconnect,,
 840         AC_MSG_ERROR([could not find libsocks5 which is needed for built-in SOCKS5 support]))
 841   AC_DEFINE(HAVE_SOCKS)
 842   CFLAGS="$CFLAGS -Dconnect=SOCKSconnect -Dgetsockname=SOCKSgetsockname -Dbind=SOCKSbind -Daccept=SOCKSaccept -Dlisten=SOCKSlisten -Dselect=SOCKSselect -Drecvfrom=SOCKSrecvfrom -Dsendto=SOCKSsendto -Drecv=SOCKSrecv -Dsend=SOCKSsend -Dread=SOCKSread -Dwrite=SOCKSwrite -Drresvport=SOCKSrresvport -Dshutdown=SOCKSshutdown -Dlisten=SOCKSlisten -Dclose=SOCKSclose -Ddup=SOCKSdup -Ddup2=SOCKSdup2 -Dgethostbyname=SOCKSgethostbyname"
 843   AC_CHECK_FUNC(SOCKSfclose, [CFLAGS="$CFLAGS -Dfclose=SOCKSfclose"])
 844   LDFLAGS="$ac_savedLDFLAGS"
 845 fi])
 846
 847 dnl for libesmtp/ modules:
 848 ACX_WHICH_GETHOSTBYNAME_R
 849
 850 ###     use option --with-hesiod=DIR to point at a HESIOD directory
 851 AC_ma_SEARCH_PACKAGE(hesiod, hesiod_getmailhost, /usr/athena /usr /usr/local,hesiod, hesiod.h)
 852
 853 ###     use option --with-gssapi=DIR to compile in GSSAPI support
 854 AC_ARG_WITH(gssapi,
 855         [  --with-gssapi[=DIR]     compile in GSSAPI support using libraries in DIR],
 856 [
 857 if test "$with_gssapi" != "no"
 858 then
 859   if test "$with_gssapi" = "yes" -a -n "$with_kerberos5"
 860   then
 861     with_gssapi=$with_kerberos5
 862   fi
 863
 864   if test "$with_gssapi" != "yes" -a -n "$with_gssapi"
 865   then
 866     CFLAGS="$CFLAGS -I$with_gssapi/include"
 867     LDFLAGS="$LDFLAGS -L$with_gssapi/lib"
 868   fi
 869
 870   dnl obtain gssapi default libs
 871   if krb5-config --libs gssapi 2>/dev/null >/dev/null ; then
 872       LIBS="$LIBS `krb5-config --libs gssapi`"
 873   else
 874     AC_CHECK_LIB(gss, gss_check_version, LIBS="$LIBS -lgss", nogss=t)
 875     if test -n "$nogss"
 876     then
 877       # -lgss not found
 878       if test "$with_gssapi" = yes ; then
 879           with_gssapi=/usr
 880       fi
 881       if test -f "$with_gssapi/include/roken.h" -o -f "$with_gssapi/include/krb5/roken.h"
 882       then
 883          # have roken.h, assume Heimdal
 884          case `uname` in
 885              NetBSD) LIBS="$LIBS -lkrb5" ;;
 886              *)      LIBS="$LIBS -lkrb5 -lasn1 -ldes -lroken -ldb -ldl" ;;
 887          esac
 888          AC_CHECK_LIB(gssapi, gss_init_sec_context,LIBS="$LIBS -lgssapi",
 889                       AC_MSG_ERROR([could not find libgssapi which is needed for GSSAPI support]), )
 890          AC_DEFINE(HEIMDAL)
 891       else
 892          # no roken.h, assume MIT
 893          AC_CHECK_LIB(gssapi_krb5, gss_init_sec_context,LIBS="$LIBS -lgssapi_krb5",
 894                       AC_MSG_ERROR([could not find libgssapi_krb5 which is needed for GSSAPI support]), -lkrb5)
 895       fi
 896     fi
 897   fi
 898   AC_DEFINE(GSSAPI,1,Define if you want GSSAPI authentication)
 899   if test "$with_gssapi" != yes ; then
 900     CPPFLAGS="$CPPFLAGS -I$with_gssapi/include"
 901   fi
 902   AC_CHECK_HEADERS(gss.h gssapi.h gssapi/gssapi.h gssapi/gssapi_generic.h)
 903   if test "$ac_cv_header_gssapi_h" = "yes"; then
 904     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE,1,Define if you have MIT kerberos))
 905   else
 906     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi/gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE))
 907   fi
 908 fi])
 909
 910 dnl ,------------------------------------------------------------------
 911 dnl Check if we need TRIO
 912 needtrio=0
 913 if test "$FORCE_TRIO" = "yes" ; then
 914     needtrio=1
 915     ac_cv_func_vsnprintf=no
 916     ac_cv_func_snprintf=no
 917 fi
 918 if test "x$ac_cv_func_snprintf" != "xyes" ; then
 919     AC_DEFINE(snprintf, trio_snprintf,
 920               [Define to trio_snprintf if your system lacks snprintf])
 921     needtrio=1
 922 fi
 923 if test "x$ac_cv_func_vsnprintf" != "xyes" ; then
 924     AC_DEFINE(vsnprintf, trio_vsnprintf,
 925               [Define to trio_vsnprintf if your system lacks vsnprintf])
 926     needtrio=1
 927 fi
 928 AM_CONDITIONAL(NEED_TRIO, test "$needtrio" = 1)
 929
 930 dnl TRIO IEEE compiler option for Alpha
 931 dnl
 932 if test "$needtrio" = 1 ; then
 933     AC_MSG_CHECKING(for IEEE compilation options)
 934     AC_CACHE_VAL(ac_cv_ieee_option, [
 935     AC_TRY_COMPILE(,[
 936     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && (defined(VMS) || defined(__VMS)))
 937     # error "Option needed"
 938     #endif
 939     ],ac_cv_ieee_option="/IEEE_MODE=UNDERFLOW_TO_ZERO/FLOAT=IEEE",
 940     AC_TRY_COMPILE(,[
 941     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && !(defined(VMS) || defined(__VMS)) && !defined(_CFE))
 942     # error "Option needed"
 943     #endif
 944     ],ac_cv_ieee_option="-ieee",
 945     AC_TRY_COMPILE(,[
 946     #if !(defined(__alpha) && (defined(__GNUC__) && (defined(__osf__) || defined(__linux__))))
 947     # error "Option needed"
 948     #endif
 949     ],ac_cv_ieee_option="-mieee",
 950     ac_cv_ieee_option="none"
 951     )
 952     )
 953     )
 954     ])
 955     AC_MSG_RESULT($ac_cv_ieee_option)
 956     if test $ac_cv_ieee_option != none; then
 957       CFLAGS="${CFLAGS} ${ac_cv_ieee_option}"
 958     fi
 959 fi
 960 dnl ----------------------------------------------------------------'
 961
 962 AC_CONFIG_FILES([Makefile po/Makefile.in genlsm.sh])
 963 AC_OUTPUT
 964
 965 dnl Local Variables:
 966 dnl comment-start: "dnl "
 967 dnl comment-end: ""
 968 dnl comment-start-skip: "\\bdnl\\b\\s *"
 969 dnl compile-command: "make configure config.h.in"
 970 dnl End: