Pileus Git - ~andy/fetchmail/blob - configure.ac

   1 dnl Autoconfigure input file for fetchmail
   2 #
   3 # Fetchmail automatic configuration support
   4 #
   5 # Eric S. Raymond <esr@thyrsus.com>
   6 # 2004 - 2012 Matthias Andree <matthias.andree@gmx.de>
   7 #
   8 dnl Process this file with autoconf to produce a configure script.
   9 dnl
  10
  11 dnl XXX - if bumping version here, check fetchmail.man, too!
  12 AC_INIT([fetchmail],[6.3.25],[fetchmail-users@lists.berlios.de])
  13 AC_CONFIG_SRCDIR([fetchmail.h])
  14 AC_CONFIG_HEADERS([config.h])
  15 AC_CONFIG_LIBOBJ_DIR([.])
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl automake options are in Makefile.am
  20 AC_PREREQ(2.60)
  21 dnl 2.60 required for AC_USE_SYSTEM_EXTENSIONS
  22 AM_INIT_AUTOMAKE([silent-rules -Wall])
  23 AM_SILENT_RULES
  24
  25 dnl python is optional
  26 #
  27 # you can pass PYTHON=: in environment or on the command line
  28 # to disable python detection and continue without building/installing
  29 # fetchmail.conf -- be sure to check README.packaging, too!
  30 #
  31 AM_PATH_PYTHON(2.0,,AC_MSG_WARN([Disabling fetchmailconf: python 2.0 or greater not found]))
  32 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
  33
  34 AC_PROG_AWK
  35 AC_PROG_CC
  36 AM_PROG_CC_C_O
  37 AC_PROG_INSTALL
  38 AC_PROG_CPP                     dnl Later checks need this.
  39 AC_PROG_RANLIB
  40 AM_PROG_CC_C_O
  41 AC_USE_SYSTEM_EXTENSIONS
  42
  43 AC_ISC_POSIX
  44 dnl AC_ISC_POSIX: - XXX FIXME: remove in fetchmail 6.4.
  45 dnl This macro adds `-lcposix' to output variable `LIBS' if necessary
  46 dnl for Posix facilities.  Sun dropped support for the obsolete
  47 dnl INTERACTIVE Systems Corporation Unix on 2006-07-23.  New programs
  48 dnl need not use this macro.  It is implemented as
  49 dnl `AC_SEARCH_LIBS([strerror], [cposix])'
  50
  51 dnl check for b0rked Solaris (and other shells) and find one that works
  52 AC_MSG_CHECKING(for a working shell...)
  53 for i in /usr/xpg6/bin/sh /usr/xpg4/bin/sh /usr/ccs/bin/sh /bin/sh /usr/bin/sh /bin/ksh /bin/bash /usr/local/bin/bash ; do
  54     $i -c 'if ! false ; then echo $(echo ok) ; fi' >config.$$ 2>/dev/null
  55     j=`cat config.$$`
  56     rm -f config.$$
  57     if test "x$j" = "xok" ; then
  58         SHELL=$i
  59         AC_SUBST(SHELL)
  60         break
  61     fi
  62 done
  63 AC_MSG_RESULT($SHELL)
  64 if test "x$SHELL" = "x" ; then
  65     AC_MSG_ERROR(no SUS compliant shell found - on Solaris, install SUNWxcu4)
  66 fi
  67
  68
  69 AC_HEADER_STDC
  70 AC_HEADER_TIME
  71 AC_TYPE_SIZE_T
  72 AC_TYPE_PID_T
  73 AC_TYPE_SIGNAL
  74 AC_CHECK_HEADERS([unistd.h termios.h termio.h sgtty.h stdarg.h \
  75         sys/itimer.h fcntl.h sys/fcntl.h memory.h sys/wait.h \
  76         arpa/inet.h arpa/nameser.h netinet/in.h net/socket.h netdb.h \
  77         sys/select.h sys/socket.h sys/time.h langinfo.h])
  78 if test _$ac_cv_header_stdarg_h != _yes ; then
  79 AC_MSG_WARN([stdarg.h is not defined. Unsupported configuration, proceed at your own risk.])
  80 fi
  81 AC_CHECK_TYPE(u_int32_t,,
  82         AC_DEFINE(u_int32_t,unsigned int,
  83                 [Define to unsigned int if <sys/types.h> does not define.]),
  84         [AC_INCLUDES_DEFAULT
  85 #ifdef HAVE_ARPA_NAMESER_H
  86 #include <arpa/nameser.h>
  87 #endif])
  88 AC_CHECK_HEADERS([resolv.h],,,[
  89 #include <sys/types.h>
  90 #ifdef HAVE_NETINET_IN_H
  91 #include <netinet/in.h>
  92 #endif
  93 #ifdef HAVE_ARPA_NAMESER_H
  94 #include <arpa/nameser.h>
  95 #endif
  96 ])
  97
  98 AC_CHECK_DECLS([h_errno],,,[
  99         AC_INCLUDES_DEFAULT
 100         #ifdef HAVE_NETDB_H
 101         #include <netdb.h>
 102         #endif
 103 ])
 104
 105 AC_C_CONST                      dnl getopt needs this.
 106
 107 AM_PROG_LEX
 108 AC_PROG_MAKE_SET
 109 AC_PROG_YACC
 110
 111 # Check for OS special cases
 112 case $host_os in
 113 darwin*)
 114     AC_MSG_NOTICE(found Darwin - Adding -DBIND_8_COMPAT to CFLAGS)
 115     CPPFLAGS="$CPPFLAGS -DBIND_8_COMPAT"
 116     ;;
 117 # Check for FreeBSD special case: more libs needed
 118 freebsd*)
 119     AC_MSG_NOTICE(found FreeBSD - Adding -lkvm -lcom_err to standard libraries)
 120     LIBS="$LIBS -lkvm -lcom_err"
 121     ;;
 122 # Check for LynxOS special case: -lbsd needed (at least on 2.3.0) and -s
 123 # not working.
 124 lynxos*)
 125     AC_MSG_NOTICE(found LynxOS - Adding -lbsd to standard libraries)
 126     LIBS="$LIBS -lbsd"
 127     LDFLAGS=`echo $LDFLAGS | sed "s/-s //"`
 128     AC_MSG_NOTICE(found LynxOS - Prepending standard include path to gcc flags)
 129     CPPFLAGS="$CPPFLAGS -I/usr/include"
 130     ;;
 131 # Check for Rhapsody special case: it doesn't like -s
 132 rhapsody*)
 133     AC_MSG_NOTICE(found Rhapsody - Removing -s load flag)
 134     LDFLAGS=`echo $LDFLAGS | sed "s/-s //"`
 135     ;;
 136 esac
 137
 138 AC_CACHE_SAVE
 139
 140 dnl i18n
 141 AM_GNU_GETTEXT([external], [need-ngettext])
 142 AM_GNU_GETTEXT_VERSION([0.17])
 143 dnl end i18n
 144
 145 # Under sysV68, socket and friends are provided by the C library.
 146 # -linet does not provide socket, but causes multiple definition
 147 # errors at link-time.  It is thus better to only use the C library.
 148 # So don't add -linet to the link list unless it's necessary
 149 AC_CHECK_FUNC(socket,
 150     AC_MSG_RESULT(using libc's socket),
 151     AC_CHECK_LIB(socket,socket)
 152     AC_CHECK_LIB(inet,socket))
 153
 154 # The condition in this test copes with the presence of inet_addr in libc6.
 155 AC_CHECK_FUNC(inet_addr,
 156     AC_MSG_RESULT(using libc's inet_addr),
 157     AC_CHECK_LIB(nsl,inet_addr))
 158
 159 dnl Port hack for Interactive UNIX System V/386 Release 3.2
 160 AC_CHECK_LIB(cposix, strchr,
 161                 [DEFS="$DEFS -D_SYSV3"
 162                 LIBS="$LIBS -lcposix"])
 163
 164 dnl Port hack for Sparc/NetBSD-1.5
 165 dnl
 166 dnl NB: this has been disabled as it causes the unconditional
 167 dnl addition of libintl to the build, which is both undesired
 168 dnl and breaks on Solaris/Blastwave.org machines.
 169 dnl
 170 dnl AC_CHECK_LIB(intl, gettext,
 171 dnl             [LIBS="$LIBS -lintl"])
 172
 173 AC_REPLACE_FUNCS([strstr strcasecmp memmove stpcpy strlcpy strlcat])
 174
 175 AC_CHECK_FUNC(getopt_long, [],
 176               [AC_LIBSOURCES([getopt.c, getopt1.c])
 177                EXTRAOBJ="$EXTRAOBJ getopt.\$(OBJEXT) getopt1.\$(OBJEXT)"])
 178
 179 AC_FUNC_VPRINTF
 180
 181 AC_SUBST(EXTRAOBJ)
 182
 183 AC_CHECK_FUNCS(tcsetattr stty setsid geteuid seteuid dnl
 184   strerror syslog snprintf vprintf vsnprintf vsyslog dnl
 185   atexit inet_aton strftime setrlimit socketpair dnl
 186   sigaction strdup setlocale)
 187
 188 AC_CHECK_DECLS([strerror,getenv])
 189 dnl INET6 is used by KAME/getnameinfo
 190 AC_CACHE_CHECK(for AF_INET6/PF_INET6,ac_cv_inet6,
 191 AC_COMPILE_IFELSE([
 192   AC_LANG_PROGRAM([[
 193     #ifdef HAVE_SYS_TYPES_H
 194     #include <sys/types.h>
 195     #endif
 196     #ifdef HAVE_SYS_SOCKET_H
 197     #include <sys/socket.h>
 198     #endif
 199   ]],[[
 200     int foo = AF_INET6;
 201     int bar = PF_INET6;
 202   ]])],
 203   ac_cv_inet6=yes , ac_cv_inet6=no
 204 ))
 205 if test "x$ac_cv_inet6" = xyes
 206 then
 207     AC_DEFINE(INET6,1,Define to 1 if your system defines AF_INET6 and PF_INET6.)
 208 fi
 209
 210 # Under Red Hat 4.0 (and many other Linuxes) -lresolv is seriously flaky
 211 # and breaks gethostbyname(2).  It's better to use the bind stuff in the C
 212 # library.  So don't add -lresolv to the link list unless it's necessary
 213 # (It will be necessary when using GNU libc6).
 214 old_LIBS="$LIBS"
 215 for lib in '' -lresolv; do
 216     if test -z "$lib"; then
 217        AC_MSG_CHECKING([for res_search in libc])
 218     else
 219        AC_MSG_CHECKING([for res_search in $lib])
 220     fi
 221     LIBS="$old_LIBS $lib"
 222     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 223 #include <sys/types.h>
 224 #ifdef HAVE_NETINET_IN_H
 225 #include <netinet/in.h>
 226 #endif
 227 #ifdef HAVE_ARPA_NAMESER_H
 228 #include <arpa/nameser.h>
 229 #endif
 230 #ifdef HAVE_RESOLV_H
 231 #include <resolv.h>
 232 #endif
 233 extern int res_search();
 234 ]], [[res_search(0, 0, 0, 0, 0); dn_skipname(0,0);]])],
 235     [AC_MSG_RESULT([found])
 236      AC_DEFINE(HAVE_RES_SEARCH, [1],
 237                [Define to 1 if you have the 'res_search' and 'dn_skipname' functions.])
 238      break], [AC_MSG_RESULT([not found])])
 239      LIBS=$old_LIBS
 240 done
 241
 242 dnl Check for libcrypt -- it may live in libc or libcrypt, as on IRIX
 243 AC_CHECK_FUNC(crypt, , AC_CHECK_LIB(crypt,crypt))
 244
 245 dnl Check for usable void pointer type
 246 AC_MSG_CHECKING(use of void pointer type)
 247 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[char *p;
 248     void *xmalloc();
 249     p = (char *) xmalloc(1);
 250    ]])],[AC_DEFINE(HAVE_VOIDPOINTER,1,[Define if your C compiler allows void * as a function result]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 251
 252 dnl Check for ANSI volatile
 253 AC_C_VOLATILE
 254
 255 dnl Check out the wait reality.  We have to assume sys/wait.h is present.
 256 AC_CHECK_FUNCS(waitpid wait3)
 257 AC_MSG_CHECKING(for union wait);
 258 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 259 #include <sys/wait.h>]], [[union wait status; int pid; pid = wait (&status);
 260 #ifdef WEXITSTATUS
 261 /* Some POSIXoid systems have both the new-style macros and the old
 262    union wait type, and they do not work together.  If union wait
 263    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 264 if (WEXITSTATUS (status) != 0) pid = -1;
 265 #endif
 266 #ifdef HAVE_WAITPID
 267 /* Make sure union wait works with waitpid.  */
 268 pid = waitpid (-1, &status, 0);
 269 #endif
 270 ]])],[AC_DEFINE(HAVE_UNION_WAIT,1,Define if 'union wait' is the type of the first arg to wait functions.) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 271
 272 AC_MSG_CHECKING(sys_siglist declaration in signal.h or unistd.h)
 273 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>
 274 /* NetBSD declares sys_siglist in <unistd.h>.  */
 275 #ifdef HAVE_UNISTD_H
 276 #include <unistd.h>
 277 #endif]], [[char *msg = *(sys_siglist + 1);]])],[AC_DEFINE(SYS_SIGLIST_DECLARED,1,[Define if 'sys_siglist' is declared by <signal.h>.]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 278
 279 # Find the right directory to put the root-mode PID file in
 280 for dir in "/var/run" "/etc"
 281 do
 282         if test -d $dir
 283         then
 284                 break;
 285         fi
 286 done
 287 AC_MSG_RESULT(root-mode pid file will go in $dir)
 288 AC_DEFINE_UNQUOTED(PID_DIR, "$dir", directory for PID lock files)
 289
 290 # We may have a fallback MDA available in case the socket open to the
 291 # local SMTP listener fails.  Best to use procmail for this, as we know
 292 # it won't try delivering through local SMTP and cause a mail loop.
 293 # Sendmail without the -t option to use the message headers will work too,
 294 # not just for sendmail itself but for workalikes like exim.
 295 #
 296 # Note1: A disadvantage of using procmail is that local alias expansion
 297 # according to /etc/aliases won't get done if we fall back.  This doesn't
 298 # matter in single-drop mode.
 299 #
 300 # Note2: it would be a very bad idea to use any MDA that doesn't return
 301 # a refuse-to-deliver status on disk- or process-table-full
 302 # conditions; mail could get lost that way.  Sendmail and all of the MDAs
 303 # like exim that might be lurking under a sendmail alias) do the right
 304 # thing in this circumstance.  Matthias Andree warns that procmail does
 305 # not.
 306 #
 307 # Note3: Defalt value of fallback is now off.  Matthias writes:
 308 #
 309 # 1. there is no way to predict when the fallback is used. With some MTAs
 310 #    (such as those limiting load average), outer circumstances can cause
 311 #    the fallback to kick in.
 312 #
 313 # 2. the fallback changes fetchmail behaviour in unpredictable ways. It's
 314 #    not only about alias expansion, .forwards to special filters won't
 315 #    work, mail may end up in a different place (users claim "mail loss"
 316 #    for that).
 317 #
 318 # 3. The claim procmail did the right thing with its exit codes is plain
 319 #    wrong. I've seen procmail exit with code 1 when it should have exited
 320 #    with code 75, like, configuration errors. Procmail is a dangerous
 321 #    beast and is best replaced by maildrop.
 322 #
 323 # 4. if multiple choices exist (like procmail and maildrop), fetchmail
 324 #    cannot tell which one it should choose. Say, your MTA is configured
 325 #    to use maildrop to deliver to user's mailboxes, if fetchmail then
 326 #    chooses procmail, this is plain wrong.
 327 #
 328
 329 AC_PATH_PROG(procmail, procmail, "", $PATH:/usr/sbin)
 330 AC_PATH_PROG(sendmail, sendmail, "", $PATH:/usr/sbin:/usr/lib)
 331 AC_PATH_PROG(maildrop, maildrop, "", $PATH:/usr/local/bin)
 332
 333 ###     use option --disable-fallback to disable fallback MDA
 334 ###     use option --enable-fallback=procmail or
 335 ###                --enable-fallback=sendmail to select
 336 AC_ARG_ENABLE(fallback,
 337         [  --enable-fallback=procmail    enable procmail as fallback
 338   --enable-fallback=sendmail    enable /usr/sbin/sendmail as fallback
 339   --enable-fallback=maildrop    enable maildrop as fallback
 340   --enable-fallback=no          disable fallback],,[enable_fallback=no])
 341
 342 case "$enable_fallback" in
 343         sendmail)       if test -z "$sendmail" ; then
 344                                 AC_MSG_ERROR([Sendmail selected as fallback, but not found])
 345                                 #not reached
 346                         fi
 347                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$sendmail -i %T", Fallback MTA to use if defined)
 348                         AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 349                         ;;
 350         procmail)       if test -z "$procmail" ; then
 351                                 AC_MSG_ERROR([procmail selected as fallback, but not found])
 352                                 #not reached
 353                         fi
 354                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$procmail -d %T")
 355                         AC_MSG_NOTICE(Will use $procmail as fallback MDA.)
 356                         ;;
 357         maildrop)       if test -z "$maildrop" ; then
 358                                 AC_MSG_ERROR([maildrop selected as fallback, but not found])
 359                                 #not reached
 360                         fi
 361                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$maildrop -d %T")
 362                         AC_MSG_NOTICE(Will use $maildrop as fallback MDA.)
 363                         ;;
 364         no|unset)       AC_MSG_NOTICE(Will not use a fallback MDA.)
 365                         ;;
 366         auto|yes|set)   if test -n "$sendmail" ; then
 367                                 AC_DEFINE_UNQUOTED(FALLBACK_MDA,"$sendmail -i %T")
 368                                 AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 369                         else
 370                                 AC_MSG_WARN(No fallback MDA available.  procmail and maildrop are not eligible)
 371                                 AC_MSG_WARN(for automatic fallback MDA configuration for reliability reasons.)
 372                         fi
 373                         ;;
 374         *)              AC_MSG_ERROR([unkown value for --enable-fallback given: $enable_fallback])
 375                         #notreached
 376                         ;;
 377 esac
 378
 379 AC_CHECK_SIZEOF(short)
 380 AC_CHECK_SIZEOF(int)
 381 AC_CHECK_SIZEOF(long)
 382
 383 ###     use option --enable-POP2 to compile in the POP2 support
 384 AC_ARG_ENABLE(POP2,
 385         [  --enable-POP2           compile in POP2 protocol support (obsolete)],
 386         [with_POP2=$enableval],
 387         [with_POP2=no])
 388 test "$with_POP2" = "yes" && AC_DEFINE(POP2_ENABLE,1,Define if you want POP2 support compiled in)
 389 AM_CONDITIONAL(POP2_ENABLE, test "$with_POP2" = yes)
 390
 391 ###     use option --disable-POP3 to omit the POP3 support
 392 AC_ARG_ENABLE(POP3,
 393         [  --disable-POP3          don't compile in POP3 protocol support],
 394         [with_POP3=$enableval],
 395         [with_POP3=yes])
 396 test "$with_POP3" = "yes" && AC_DEFINE(POP3_ENABLE,1,Define if you want POP3 support compiled in)
 397 AM_CONDITIONAL(POP3_ENABLE, test "$with_POP3" = yes)
 398
 399 ###     use option --disable-IMAP to omit the IMAP support
 400 AC_ARG_ENABLE(IMAP,
 401         [  --disable-IMAP          don't compile in IMAP protocol support],
 402         [with_IMAP=$enableval],
 403         [with_IMAP=yes])
 404 test "$with_IMAP" = "yes" && AC_DEFINE(IMAP_ENABLE,1,Define if you want IMAP support compiled in)
 405 AM_CONDITIONAL(IMAP_ENABLE, test "$with_IMAP" = yes)
 406
 407 ###     use option --disable-ETRN to omit the ETRN support
 408 AC_ARG_ENABLE(ETRN,
 409         [  --disable-ETRN          don't compile in ETRN protocol support],
 410         [with_ETRN=$enableval],
 411         [with_ETRN=yes])
 412 test "$with_ETRN" = "yes" && AC_DEFINE(ETRN_ENABLE,1,Define if you want ETRN support compiled in.)
 413 AM_CONDITIONAL(ETRN_ENABLE, test "$with_ETRN" = yes)
 414
 415 ###     use option --disable-ODMR to omit the ODMR support
 416 AC_ARG_ENABLE(ODMR,
 417         [  --disable-ODMR          don't compile in ODMR protocol support],
 418         [with_ODMR=$enableval],
 419         [with_ODMR=yes])
 420 test "$with_ODMR" = "yes" && AC_DEFINE(ODMR_ENABLE,1,Define if you want ODMR support compiled in)
 421 AM_CONDITIONAL(ODMR_ENABLE, test "$with_ODMR" = yes)
 422
 423 ###     use option --enable-RPA to compile in the RPA support
 424 AC_ARG_ENABLE(RPA,
 425         [  --enable-RPA            compile in RPA protocol support],
 426         [with_RPA=$enableval],
 427         [with_RPA=no])
 428 test "$with_RPA" = "yes" && AC_DEFINE(RPA_ENABLE,1,Define if you want RPA support compiled in)
 429 AM_CONDITIONAL(RPA_ENABLE, test "$with_RPA" = yes)
 430
 431 ###     use option --enable-NTLM to compile in the NTLM support
 432 AC_ARG_ENABLE(NTLM,
 433         [  --enable-NTLM           compile in NTLM authentication support],
 434         [with_NTLM=$enableval],
 435         [with_NTLM=no])
 436 test "$with_NTLM" = "yes" && AC_DEFINE(NTLM_ENABLE,1,Define if you want NTLM authentication)
 437 AM_CONDITIONAL(NTLM_ENABLE, test "$with_NTLM" = yes)
 438
 439 ###     use option --enable-SDPS to compile in the SDPS support
 440 AC_ARG_ENABLE(SDPS,
 441         [  --enable-SDPS           compile in SDPS protocol support],
 442         [with_SDPS=$enableval],
 443         [with_SDPS=no])
 444 if test "$with_SDPS" = yes ; then
 445    if test "$with_POP3" != yes ; then
 446        AC_MSG_WARN([SDPS cannot be enabled with POP3 disabled. Disabling SDPS.])
 447        with_SDPS=no
 448    else
 449        AC_DEFINE(SDPS_ENABLE,1,Define if you want SDPS support compiled in)
 450    fi
 451 fi
 452 if test "$with_POP3" != yes && test "$with_POP2" != yes \
 453     && test "$with_IMAP"  != yes ; then
 454     AC_MSG_ERROR([You must enable at least one of POP2, POP3 and IMAP.])
 455 fi
 456
 457 AC_CACHE_SAVE
 458
 459 ###     use option --enable-opie to compile in the OPIE support
 460 AC_ARG_ENABLE(opie,
 461         [  --enable-opie           support OTP through the OPIE library],
 462         [ AC_CHECK_HEADER(opie.h,, [AC_MSG_ERROR([cannot find <opie.h>, which is required for OPIE support.])])
 463           AC_CHECK_LIB(opie,opiegenerator,, [AC_MSG_ERROR([cannot find libopie, which is required for OPIE support.])])
 464           with_opie=$enableval],
 465         [with_opie=no])
 466 test "$with_opie" = "yes" && AC_DEFINE(OPIE_ENABLE,1,Define if you want OPIE support compiled in)
 467
 468 dnl Mostly stolen from gnulib's getaddrinfo.m4
 469 AC_SEARCH_LIBS(getaddrinfo, [nsl socket])
 470 AC_CACHE_CHECK([for getaddrinfo],[fm_cv_getaddrinfo],[
 471   AC_TRY_LINK([
 472 #include <sys/types.h>
 473 #ifdef HAVE_SYS_SOCKET_H
 474 #include <sys/socket.h>
 475 #endif
 476 #ifdef HAVE_NETDB_H
 477 #include <netdb.h>
 478 #endif
 479   ], [getaddrinfo(0, 0, 0, 0);],
 480     [ fm_cv_getaddrinfo=yes],
 481     [ fm_cv_getaddrinfo=no ])
 482 ])
 483
 484 if test x"$fm_cv_getaddrinfo" = "xyes"; then
 485      AC_DEFINE(HAVE_GETADDRINFO, 1,
 486       [Define to 1 if you have the getaddrinfo function.])
 487 fi
 488
 489 AC_CACHE_CHECK([for getnameinfo],[fm_cv_getnameinfo],[
 490   AC_TRY_LINK([
 491 #include <sys/types.h>
 492 #ifdef HAVE_SYS_SOCKET_H
 493 #include <sys/socket.h>
 494 #endif
 495 #ifdef HAVE_NETDB_H
 496 #include <netdb.h>
 497 #endif
 498 #ifndef NULL
 499 #define NULL 0
 500 #endif
 501   ], [getnameinfo(NULL,0, NULL,0, NULL, 0, 0);],
 502     [ fm_cv_getnameinfo=yes],
 503     [ fm_cv_getnameinfo=no ])
 504 ])
 505 if test $fm_cv_getnameinfo = yes ; then
 506     AC_DEFINE(HAVE_GETNAMEINFO,1,[Define to 1 if your system has getnameinfo()])
 507 fi
 508
 509 AM_CONDITIONAL(NEED_GETADDRINFO, test "$fm_cv_getaddrinfo" != yes)
 510 AM_CONDITIONAL(NEED_GETNAMEINFO, test "$fm_cv_getnameinfo"   != yes)
 511
 512 AC_CHECK_FUNCS(inet_ntop)
 513 dnl Check if getaddrinfo is async-signal-safe - most implementations aren't
 514 if test "$fm_cv_getaddrinfo" = yes ; then
 515     AC_MSG_CHECKING(if your getaddrinfo is async-signal-safe)
 516     gai_ts=no
 517     dnl we have getaddrinfo() - check if the OS is known to have a async-signal-safe implementation
 518     case $host_os in
 519         darwin9*)                               gai_ts=yes ;;
 520         linux*)                                 gai_ts=yes ;;
 521         freebsd5.5|freebsd6*|freebsd7*)         gai_ts=yes ;;
 522         solaris2.8|solaris2.9|solaris2.10)      gai_ts=yes ;;
 523     esac
 524     AC_MSG_RESULT($gai_ts)
 525     if test $gai_ts = yes ; then
 526         AC_DEFINE(GETADDRINFO_ASYNCSAFE, 1, [define to 1 if you know your getaddrinfo function is async-signal-safe])
 527     fi
 528 fi
 529
 530 # This version of the Kerberos 4 and 5 options addresses the follwing issues:
 531 #
 532 # * Build correctly under Heimdal kerberos if it is compiled with db2 and
 533 #   OpenSSL support (Debian's is)
 534 # * Build the kerberos.c stuff (KPOP) only for kerberosIV, to avoid breakage.
 535 #   I don't know if this is 100% correct, but now at least IMAP and POP3
 536 #   behave the same way regarding kerberosV.
 537 # * Build without any fuss for both kerberosIV and V at the same time.
 538 # * Move all the kerberos header mess to kerberos.h, and #include that
 539 #   in driver.c and kerberos.c.
 540 #
 541 # Tested using the Heimdal Kerberos V libs, Kungliga Tekniska Högskolan (the
 542 # Royal Institute of Technology in Stockholm, Sweden)'s kerberos IV libs, and
 543 # the MIT reference implementation of KerberosV (all as packaged in Debian).
 544
 545 ###    use option --with-kerberos5=DIR to point at a Kerberos 5 directory
 546 ### make sure --with-ssl is run before --with-kerberos* !
 547 AC_ARG_WITH(kerberos5,
 548        [  --with-kerberos5=DIR    point fetchmail compilation at a Kerberos 5 directory],
 549 [
 550 if test "$with_kerberos5" != "no"
 551 then
 552 # Check for a OpenBSD special case
 553 if test "$with_kerberos5" = "yes" && ( test `uname` = "OpenBSD" )
 554 then
 555   AS_MESSAGE(checking kerberosV for OpenBSD...)
 556   AC_DEFINE(HEIMDAL,1,Define if you have HEIMDAL kerberos 5)
 557   AC_DEFINE(KERBEROS_V5,1,Define if you have Kerberos V5)
 558   CFLAGS="$CFLAGS -I/usr/include/kerberosV"
 559   LIBS="$LIBS -lasn1 -lkrb5 -lcom_err -lkafs"
 560 elif krb5-config 2> /dev/null >/dev/null ; then
 561   krb5_prefix=`krb5-config --prefix krb5`
 562   AC_MSG_RESULT([krb5-config points to kerberosV under $krb5_prefix])
 563   if test -f ${krb5_prefix}/include/et/com_err.h && \
 564    ! test -f ${krb5_prefix}/include/com_err.h  ; then
 565     CFLAGS="$CFLAGS -I${krb5_prefix}/include/et"
 566   fi
 567   unset krb5_prefix
 568   CFLAGS="$CFLAGS `krb5-config --cflags krb5`"
 569   LIBS="$LIBS `krb5-config --libs krb5`"
 570   AC_DEFINE(KERBEROS_V5)
 571 else
 572   if test "$with_kerberos5" != "yes"
 573   then
 574       LDFLAGS="$LDFLAGS -L${with_kerberos5}/lib"
 575       searchdirs="$with_kerberos5"
 576   else
 577       searchdirs="/usr/kerberos /usr/local/krb5 /usr/athena /usr"
 578   fi
 579   with_kerberos5=
 580   for dir in $searchdirs
 581   do AC_MSG_CHECKING([for Kerberos V in $dir])
 582      if test -f "$dir/include/krb5.h" || test -f "$dir/include/krb5/krb5.h"
 583      then
 584         if test -d "$dir/include/krb5" ; then CPPFLAGS="$CPPFLAGS -I$dir/include/krb5" ; fi
 585         ac_krblibs=
 586         if test -f "$dir/include/roken.h" || test -f "$dir/include/krb5/roken.h"
 587         then
 588            ac_krblibs="-lasn1 -lroken -lcom_err"
 589            AC_MSG_RESULT([Heimdal found])
 590           dnl Attempt to detect if we need to -ldb2 to link Heimdal
 591           dnl we assume we do if it is available
 592            AC_CHECK_LIB(db2, db_open, ac_krblibs="$ac_krblibs -ldb2", [],
 593                 ${LDFLAGS})
 594            AC_CHECK_LIB(des, des_string_to_key, libk5crypto=-ldes,
 595               AC_CHECK_LIB(crypto, MD5_Init, [],
 596                 AC_MSG_ERROR([DES libraries not found. Try adding --with-ssl to enable OpenSSL support]),
 597                 ${LDFLAGS} ${ac_krblibs}),
 598            ${LDFLAGS} ${ac_krblibs})
 599            AC_DEFINE(HEIMDAL)
 600         else
 601           AC_MSG_RESULT([found])
 602           ac_krblibs="-lcom_err"
 603            AC_CHECK_LIB(crypto,
 604              krb5_des_string_to_key,
 605              libk5crypto=-lcrypto,
 606                 AC_CHECK_LIB(k5crypto,
 607                    krb5_des_string_to_key,
 608                    libk5crypto=-lk5crypto,
 609                       AC_MSG_ERROR([Kerberos 5 DES libraries not found]),
 610                    ${LDFLAGS} ${ac_krblibs}),
 611                  ${LDFLAGS} ${ac_krblibs})
 612         fi
 613         AC_CHECK_LIB(krb5, krb5_init_context,[],
 614            continue,
 615            ${LDFLAGS} ${ac_krblibs})
 616         AC_DEFINE(KERBEROS_V5)
 617         test "$dir" != "/usr" && CFLAGS="$CFLAGS -I$dir/include"
 618         LDFLAGS="$LDFLAGS -L$dir/lib"
 619        LIBS="$LIBS $ac_krblibs $libk5crypto"
 620         with_kerberos5=$dir
 621         break
 622      else
 623         AC_MSG_RESULT([not found])
 624      fi
 625   done
 626   if test -z "$with_kerberos5" ; then
 627      AC_MSG_ERROR([Kerberos 5 libraries not found])
 628   fi
 629 fi
 630 fi
 631 ]) dnl --with-kerberos5=DIR
 632
 633 ###    use option --with-kerberos=DIR to point at a Kerberos 4 directory
 634 KERBEROS_V4=0
 635 AC_ARG_WITH(kerberos,
 636        [  --with-kerberos=DIR     point fetchmail compilation at a Kerberos 4 directory],
 637 [
 638 if test "$with_kerberos" != "no"
 639 then
 640     AC_MSG_WARN([Kerberos IV support is obsolete. Use --with-kerberos5 if possible.])
 641 # Check for a NetBSD/OpenBSD special case
 642 if test "$with_kerberos" = "yes" && ( test `uname` = "NetBSD" || test `uname` = "OpenBSD" )
 643 then
 644   AS_MESSAGE(checking kerberosIV for `uname`...)
 645   KERBEROS_V4=1
 646   CFLAGS="$CFLAGS -I/usr/include/kerberosIV"
 647   case `uname` in
 648       NetBSD)  LIBS="$LIBS -lkrb -ldes -lroken -lcom_err" ;;
 649       OpenBSD) LIBS="$LIBS -lkrb -ldes" ;;
 650   esac
 651 elif krb4-config 2> /dev/null >/dev/null ; then
 652   krb4_prefix=`krb4-config --prefix`
 653   AC_MSG_RESULT([krb4-config points to kerberosIV under $krb4_prefix])
 654   unset krb4_prefix
 655   CFLAGS="$CFLAGS `krb4-config --cflags`"
 656   LIBS="$LIBS `krb4-config --libs`"
 657   KERBEROS_V4=1
 658 elif krb5-config 2> /dev/null >/dev/null ; then
 659   krb4_prefix=`krb5-config --prefix krb4`
 660   AC_MSG_RESULT([krb5-config points to kerberosIV under $krb4_prefix])
 661   if test -f ${krb4_prefix}/include/kerberosIV/krb.h ; then
 662     AC_DEFINE(KERBEROS_V4_V5,1,Define if you have Kerberos V4 headers under a kerberosIV directory)
 663   fi
 664   unset krb4_prefix
 665   CFLAGS="$CFLAGS `krb5-config --cflags krb4`"
 666   LIBS="$LIBS `krb5-config --libs krb4`"
 667   KERBEROS_V4=1
 668 else
 669   #we need to detect when we're building under a kerberosV compatibility
 670   #layer, btw...
 671   if test "$with_kerberos" != "yes" ; then
 672      searchdirs="$with_kerberos"
 673   else
 674      searchdirs="$with_kerberos5 /usr/kerberos /usr/kerberosIV /usr/athena /usr"
 675   fi
 676   with_kerberos=
 677   ac_saveLDFLAGS="$LDFLAGS"
 678   for dir in $searchdirs
 679   do
 680      AC_MSG_CHECKING([for Kerberos IV in $dir])
 681      if test -f "$dir/include/krb.h" || test -f "$dir/include/krb4.h" \
 682             || test -f "$dir/include/kerberosIV/krb.h"
 683      then
 684         AC_MSG_RESULT([found])
 685      else
 686         AC_MSG_RESULT([not found])
 687        continue
 688      fi
 689      #Find libs
 690      if test -f "$with_kerberos5/roken.h" ; then
 691        AC_CHECK_LIB(45, krb_mk_req)
 692      fi
 693      LDFLAGS="-L$dir/lib $ac_saveLDFLAGS"
 694      if test `uname` = "FreeBSD"; then
 695         AC_SEARCH_LIBS(_ossl_old_des_string_to_key, [des425 des crypto], [], continue)
 696      else
 697         AC_SEARCH_LIBS(des_string_to_key, [crypto], [], continue)
 698      fi
 699      AC_SEARCH_LIBS(krb_realmofhost, [krb4 krb], [], continue)
 700      with_kerberos="$dir"
 701      if test -f "$dir/include/kerberosIV/krb.h" ; then
 702         dir="$dir/include/kerberosIV"
 703      else
 704        dir="$dir/include"
 705      fi
 706      KERBEROS_V4=1
 707      test -f "$with_kerberos5/roken.h" && AC_DEFINE(HEIMDAL)
 708      test "$dir" != "/usr/include" && CFLAGS="$CFLAGS -I$dir"
 709      LDFLAGS="$LDFLAGS -L$with_kerberos/lib"
 710      break
 711   done
 712   if test -z "$with_kerberos" ; then
 713      AC_MSG_ERROR([Kerberos 4 libraries not found])
 714   fi
 715   LDFLAGS="$ac_saveLDFLAGS"
 716 fi
 717 fi
 718 ]) dnl --with-kerberos=DIR
 719 if test "$KERBEROS_V4" = 1 ; then
 720     AC_DEFINE(KERBEROS_V4,1,Define if you have Kerberos V4)
 721 fi
 722 AM_CONDITIONAL(KERBEROS_V4_ENABLE, test "$KERBEROS_V4" = 1)
 723
 724 ###     use option --with-ssl to compile in the SSL support
 725 AC_ARG_WITH(ssl,
 726         [  --with-ssl=[DIR]        enable SSL support using libraries in DIR],
 727         [with_ssl=$withval],
 728         [with_ssl=no])
 729 test "$with_ssl" != "no" && AC_DEFINE(SSL_ENABLE,1,Define if you want SSL support compiled in)
 730
 731 if test "$with_ssl" = "yes"
 732 then
 733     #   User didn't specify an SSL location.  Let's look at some common
 734     #   directories where SSL has been found in the past and try and auto
 735     #   configure for SSL.  OpenSSL determination will be made later.
 736     #   This will screw up if an OpenSSL install is located in a later
 737     #   directory than an older SSLeay install, but the user should fix that
 738     #   anyways and he can override on the configure line.
 739     #   Just testing for directories is not sufficient, /usr exists on
 740     #   all systems!
 741     for ac_dir in \
 742       /usr/local/ssl \
 743       /usr/local \
 744       /usr/ssl \
 745       /usr \
 746       /local/ssl \
 747       /opt/ssl \
 748       /opt/csw \
 749       ; \
 750     do
 751         if test -r "$ac_dir/include/openssl/ssl.h" ; then
 752             with_ssl=$ac_dir
 753             break;
 754         fi
 755     done
 756 fi
 757
 758 if test -n "$with_ssl" -a "$with_ssl" != "no"
 759 then
 760   # With the autoconfigure above, the only time this is going to be
 761   # true is going to be when we could not find the headers.  If they
 762   # are not in system standard locations, we are going to be broken.
 763   if test "$with_ssl" = "yes"
 764   then
 765     # Let's just define the standard location for the SSLeay root
 766     with_ssl="/usr/local/ssl"
 767   fi
 768   if test -r $with_ssl/include/openssl/ssl.h
 769   then
 770     ### ssl.h found under openssl.  Use openssl configuration preferentially,
 771     AC_MSG_NOTICE(Enabling OpenSSL support in $with_ssl.)
 772     test "$with_ssl" != "/usr" && CFLAGS="$CFLAGS -I$with_ssl/include"
 773     ### In Red Hat 9, this file includes a reference to <krb5.h>, so we
 774     ### force the Kerberos direcory onto the include path so it will build.
 775     CFLAGS="$CFLAGS -I/usr/kerberos/include"
 776     ### OpenBSD comes with ssl headers
 777   else
 778     AC_MSG_ERROR([SSL support enabled, but OpenSSL not found])
 779   fi
 780   LDFLAGS="$LDFLAGS -L$with_ssl/lib"
 781   LIBS="$LIBS -lssl -lcrypto"
 782   dnl check if -ldl is needed
 783   AC_MSG_CHECKING([for additional library dependencies of SSL])
 784   found=0
 785   save_LIBS="$LIBS"
 786   for i in "" "-ldl" ; do
 787       LIBS="$LDFLAGS $save_LIBS $i"
 788       AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <openssl/ssl.h>],[SSL_library_init()])],[found=1; break])
 789   done
 790   if test $found = 0 ; then
 791       AC_MSG_RESULT([error])
 792       AC_MSG_ERROR([cannot link with SSL - check config.log])
 793   fi
 794   LIBS="$save_LIBS $i"
 795   if test "$i" = "" ; then i="(none)" ; fi
 796   AC_MSG_RESULT($i)
 797   dnl XXX FIXME: use pkg-config if available!
 798   AC_DEFINE(SSL_ENABLE)
 799 else
 800   AC_MSG_WARN(Disabling SSL support.)
 801   AC_MSG_WARN(Consider re-running configure --with-ssl.)
 802 fi
 803
 804 case "$LIBS" in *-lssl*)
 805         AC_CHECK_DECLS([SSLv2_client_method],,,[#include <openssl/ssl.h>])
 806         ;;
 807 esac
 808
 809 ###     use option --with-socks=DIR to point at SOCKS library
 810 AC_ARG_WITH(socks,
 811         [  --with-socks[=DIR]      add built-in SOCKS firewall access],
 812 [
 813 if test "$with_socks" != no
 814 then
 815     if test "$with_socks" != yes
 816     then
 817         LDFLAGS="$LDFLAGS -L$with_socks"
 818     else
 819         AC_CHECK_LIB(socks, Rconnect,,
 820                AC_MSG_ERROR([could not find libsocks which is needed for built-in SOCKS support]))
 821     fi
 822     AC_DEFINE(HAVE_SOCKS,1,Define if you want built-in SOCKS support)
 823     CFLAGS="$CFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 824     LIBS="-lsocks $LIBS"
 825 fi])
 826
 827 ###     use option --with-socks5=DIR to point at SOCKS library
 828 AC_ARG_WITH(socks5,
 829         [  --with-socks5[=DIR]     add built-in SOCKS5 firewall access],
 830 [
 831 if test "$with_socks5" != no
 832 then
 833   if test "$with_socks5" != yes
 834   then
 835     LDFLAGS="$LDFLAGS -L$with_socks5"
 836   fi
 837   ac_savedLDFLAGS="$LDFLAGS"
 838   LDFLAGS="$LDFLAGS $LDFLAGS"
 839   AC_CHECK_LIB(socks5, SOCKSconnect,,
 840         AC_MSG_ERROR([could not find libsocks5 which is needed for built-in SOCKS5 support]))
 841   AC_DEFINE(HAVE_SOCKS)
 842   CFLAGS="$CFLAGS -Dconnect=SOCKSconnect -Dgetsockname=SOCKSgetsockname -Dbind=SOCKSbind -Daccept=SOCKSaccept -Dlisten=SOCKSlisten -Dselect=SOCKSselect -Drecvfrom=SOCKSrecvfrom -Dsendto=SOCKSsendto -Drecv=SOCKSrecv -Dsend=SOCKSsend -Dread=SOCKSread -Dwrite=SOCKSwrite -Drresvport=SOCKSrresvport -Dshutdown=SOCKSshutdown -Dlisten=SOCKSlisten -Dclose=SOCKSclose -Ddup=SOCKSdup -Ddup2=SOCKSdup2 -Dgethostbyname=SOCKSgethostbyname"
 843   AC_CHECK_FUNC(SOCKSfclose, [CFLAGS="$CFLAGS -Dfclose=SOCKSfclose"])
 844   LDFLAGS="$ac_savedLDFLAGS"
 845 fi])
 846
 847 dnl for libesmtp/ modules:
 848 ACX_WHICH_GETHOSTBYNAME_R
 849
 850 ###     use option --with-hesiod=DIR to point at a HESIOD directory
 851 AC_ma_SEARCH_PACKAGE(hesiod, hesiod_getmailhost, /usr/athena /usr /usr/local,hesiod, hesiod.h)
 852
 853 ###     use option --with-gssapi=DIR to compile in GSSAPI support
 854 AC_ARG_WITH(gssapi,
 855         [  --with-gssapi[=DIR]     compile in GSSAPI support using libraries in DIR],
 856 [
 857 if test "$with_gssapi" != "no"
 858 then
 859   if test "$with_gssapi" = "yes" -a -n "$with_kerberos5"
 860   then
 861     with_gssapi=$with_kerberos5
 862   fi
 863
 864   if test "$with_gssapi" != "yes" -a -n "$with_gssapi"
 865   then
 866     CFLAGS="$CFLAGS -I$with_gssapi/include"
 867     LDFLAGS="$LDFLAGS -L$with_gssapi/lib"
 868   fi
 869
 870   dnl obtain gssapi default libs
 871   if krb5-config --libs gssapi 2>/dev/null >/dev/null ; then
 872       LIBS="$LIBS `krb5-config --libs gssapi`"
 873   else
 874     AC_CHECK_LIB(gss, gss_check_version, LIBS="$LIBS -lgss", nogss=t)
 875     if test -n "$nogss"
 876     then
 877       # -lgss not found
 878       if test "$with_gssapi" = yes ; then
 879           with_gssapi=/usr
 880       fi
 881       if test -f "$with_gssapi/include/roken.h" -o -f "$with_gssapi/include/krb5/roken.h"
 882       then
 883          # have roken.h, assume Heimdal
 884          case `uname` in
 885              NetBSD) LIBS="$LIBS -lkrb5" ;;
 886              *)      LIBS="$LIBS -lkrb5 -lasn1 -ldes -lroken -ldb -ldl" ;;
 887          esac
 888          AC_CHECK_LIB(gssapi, gss_init_sec_context,LIBS="$LIBS -lgssapi",
 889                       AC_MSG_ERROR([could not find libgssapi which is needed for GSSAPI support]), )
 890          AC_DEFINE(HEIMDAL)
 891       else
 892          # no roken.h, assume MIT
 893          AC_CHECK_LIB(gssapi_krb5, gss_init_sec_context,LIBS="$LIBS -lgssapi_krb5",
 894                       AC_MSG_ERROR([could not find libgssapi_krb5 which is needed for GSSAPI support]), -lkrb5)
 895       fi
 896     fi
 897   fi
 898   AC_DEFINE(GSSAPI,1,Define if you want GSSAPI authentication)
 899   if test "$with_gssapi" != yes ; then
 900     CPPFLAGS="$CPPFLAGS -I$with_gssapi/include"
 901   fi
 902   AC_CHECK_HEADERS(gss.h gssapi.h gssapi/gssapi.h gssapi/gssapi_generic.h)
 903   AC_CHECK_DECLS(GSS_C_NT_HOSTBASED_SERVICE,,,[
 904     AC_INCLUDES_DEFAULT
 905     #if HAVE_GSS_H
 906     #include <gss.h>
 907     #endif
 908     #if HAVE_GSSAPI_GSSAPI_H
 909     #include <gssapi/gssapi.h>
 910     #elif HAVE_GSSAPI_H
 911     #include <gssapi.h>
 912     #endif
 913     #if HAVE_GSSAPI_GSSAPI_GENERIC_H
 914     #include <gssapi/gssapi_generic.h>
 915     #endif
 916     ])
 917 fi])
 918
 919 dnl ,------------------------------------------------------------------
 920 dnl Check if we need TRIO
 921 needtrio=0
 922 if test "$FORCE_TRIO" = "yes" ; then
 923     needtrio=1
 924     ac_cv_func_vsnprintf=no
 925     ac_cv_func_snprintf=no
 926 fi
 927 if test "x$ac_cv_func_snprintf" != "xyes" ; then
 928     AC_DEFINE(snprintf, trio_snprintf,
 929               [Define to trio_snprintf if your system lacks snprintf])
 930     needtrio=1
 931 fi
 932 if test "x$ac_cv_func_vsnprintf" != "xyes" ; then
 933     AC_DEFINE(vsnprintf, trio_vsnprintf,
 934               [Define to trio_vsnprintf if your system lacks vsnprintf])
 935     needtrio=1
 936 fi
 937 AM_CONDITIONAL(NEED_TRIO, test "$needtrio" = 1)
 938
 939 dnl TRIO IEEE compiler option for Alpha
 940 dnl
 941 if test "$needtrio" = 1 ; then
 942     AC_MSG_CHECKING(for IEEE compilation options)
 943     AC_CACHE_VAL(ac_cv_ieee_option, [
 944     AC_TRY_COMPILE(,[
 945     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && (defined(VMS) || defined(__VMS)))
 946     # error "Option needed"
 947     #endif
 948     ],ac_cv_ieee_option="/IEEE_MODE=UNDERFLOW_TO_ZERO/FLOAT=IEEE",
 949     AC_TRY_COMPILE(,[
 950     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && !(defined(VMS) || defined(__VMS)) && !defined(_CFE))
 951     # error "Option needed"
 952     #endif
 953     ],ac_cv_ieee_option="-ieee",
 954     AC_TRY_COMPILE(,[
 955     #if !(defined(__alpha) && (defined(__GNUC__) && (defined(__osf__) || defined(__linux__))))
 956     # error "Option needed"
 957     #endif
 958     ],ac_cv_ieee_option="-mieee",
 959     ac_cv_ieee_option="none"
 960     )
 961     )
 962     )
 963     ])
 964     AC_MSG_RESULT($ac_cv_ieee_option)
 965     if test $ac_cv_ieee_option != none; then
 966       CFLAGS="${CFLAGS} ${ac_cv_ieee_option}"
 967     fi
 968 fi
 969 dnl ----------------------------------------------------------------'
 970
 971 AC_CONFIG_FILES([Makefile po/Makefile.in])
 972 AC_OUTPUT
 973
 974 dnl Local Variables:
 975 dnl comment-start: "dnl "
 976 dnl comment-end: ""
 977 dnl comment-start-skip: "\\bdnl\\b\\s *"
 978 dnl compile-command: "make configure config.h.in"
 979 dnl End: