Pileus Git - ~andy/fetchmail/blob - configure.ac

   1 dnl Autoconfigure input file for fetchmail
   2 #
   3 # Fetchmail automatic configuration support
   4 #
   5 # Eric S. Raymond <esr@thyrsus.com>
   6 # 2004 - 2012 Matthias Andree <matthias.andree@gmx.de>
   7 #
   8 dnl Process this file with autoconf to produce a configure script.
   9 dnl
  10
  11 dnl XXX - if bumping version here, check fetchmail.man, too!
  12 AC_INIT([fetchmail],[7.0.0-alpha5],[fetchmail-devel@lists.berlios.de])
  13 AC_CONFIG_SRCDIR([fetchmail.h])
  14 AC_CONFIG_HEADERS([config.h])
  15 AC_CONFIG_LIBOBJ_DIR([.])
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl keep this before stuff that runs the compiler!
  20 AC_USE_SYSTEM_EXTENSIONS
  21
  22 dnl automake options are in Makefile.am
  23 AC_PREREQ(2.64)
  24 dnl 2.60 required for AC_USE_SYSTEM_EXTENSIONS
  25 AM_INIT_AUTOMAKE([silent-rules -Wall])
  26 AM_SILENT_RULES
  27
  28 dnl python is optional
  29 #
  30 # you can pass PYTHON=: in environment or on the command line
  31 # to disable python detection and continue without building/installing
  32 # fetchmail.conf -- be sure to check README.packaging, too!
  33 #
  34 AM_PATH_PYTHON(2.0,,AC_MSG_WARN([Disabling fetchmailconf: python 2.0 or greater not found]))
  35 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
  36
  37 AC_PROG_AWK
  38 AC_PROG_CC_C99
  39 AC_PROG_INSTALL
  40 AM_PROG_LEX
  41 AC_PROG_MAKE_SET
  42 AC_PROG_RANLIB
  43 AC_PROG_YACC
  44
  45 dnl check for b0rked Solaris (and other shells) and find one that works
  46 AC_MSG_CHECKING(for a working shell...)
  47 for i in /usr/xpg6/bin/sh /usr/xpg4/bin/sh /usr/ccs/bin/sh /bin/sh /usr/bin/sh /bin/ksh /bin/bash /usr/local/bin/bash ; do
  48     $i -c 'if ! false ; then echo $(echo ok) ; fi' >config.$$ 2>/dev/null
  49     j=`cat config.$$`
  50     rm -f config.$$
  51     if test "x$j" = "xok" ; then
  52         SHELL=$i
  53         AC_SUBST(SHELL)
  54         break
  55     fi
  56 done
  57 AC_MSG_RESULT($SHELL)
  58 if test "x$SHELL" = "x" ; then
  59     AC_MSG_ERROR(no SUS compliant shell found - on Solaris, install SUNWxcu4)
  60 fi
  61
  62 AC_CHECK_HEADERS([arpa/nameser.h])
  63
  64 AC_CHECK_HEADERS([resolv.h],,,[
  65 #include <sys/types.h>
  66 #include <netinet/in.h>
  67 #ifdef HAVE_ARPA_NAMESER_H
  68 #include <arpa/nameser.h>
  69 #endif
  70 ])
  71
  72 AC_CHECK_DECLS([h_errno],,,[
  73         AC_INCLUDES_DEFAULT
  74         #include <netdb.h>
  75 ])
  76
  77 # Check for OS special cases
  78 case $host_os in
  79 darwin*)
  80     AC_MSG_NOTICE(found Darwin - Adding -DBIND_8_COMPAT to CFLAGS)
  81     CPPFLAGS="$CPPFLAGS -DBIND_8_COMPAT"
  82     ;;
  83 # Check for FreeBSD special case: more libs needed
  84 freebsd*)
  85     AC_MSG_NOTICE(found FreeBSD - Adding -lkvm -lcom_err to standard libraries)
  86     LIBS="$LIBS -lkvm -lcom_err"
  87     ;;
  88 esac
  89
  90 AC_CACHE_SAVE
  91
  92 dnl i18n
  93 AM_GNU_GETTEXT([external], [need-ngettext])
  94 AM_GNU_GETTEXT_VERSION([0.17])
  95 dnl end i18n
  96
  97 # Under sysV68, socket and friends are provided by the C library.
  98 # -linet does not provide socket, but causes multiple definition
  99 # errors at link-time.  It is thus better to only use the C library.
 100 # So don't add -linet to the link list unless it's necessary
 101 AC_CHECK_FUNC(socket,
 102     AC_MSG_RESULT(using libc's socket),
 103     AC_CHECK_LIB(socket,socket)
 104     AC_CHECK_LIB(inet,socket))
 105
 106 # The condition in this test copes with the presence of inet_addr in libc6.
 107 AC_CHECK_FUNC(inet_addr,
 108     AC_MSG_RESULT(using libc's inet_addr),
 109     AC_CHECK_LIB(nsl,inet_addr))
 110
 111 AC_REPLACE_FUNCS([stpcpy strlcpy strlcat])
 112
 113 AC_CHECK_FUNC(getopt_long, [],
 114               [AC_LIBSOURCES([getopt.c, getopt1.c])
 115                EXTRAOBJ="$EXTRAOBJ getopt.\$(OBJEXT) getopt1.\$(OBJEXT)"])
 116
 117 AC_SUBST(EXTRAOBJ)
 118
 119 AC_CHECK_FUNCS(vsyslog inet_aton)
 120
 121 dnl INET6 is used by KAME/getnameinfo
 122 AC_CACHE_CHECK(for AF_INET6/PF_INET6,ac_cv_inet6,
 123 AC_COMPILE_IFELSE([
 124   AC_LANG_PROGRAM([[
 125     #include <sys/types.h>
 126     #include <sys/socket.h>
 127   ]],[[
 128     int foo = AF_INET6;
 129     int bar = PF_INET6;
 130   ]])],
 131   ac_cv_inet6=yes , ac_cv_inet6=no
 132 ))
 133 if test "x$ac_cv_inet6" = xyes
 134 then
 135     AC_DEFINE(INET6,1,Define to 1 if your system defines AF_INET6 and PF_INET6.)
 136 fi
 137
 138 # Under Red Hat 4.0 (and many other Linuxes) -lresolv is seriously flaky
 139 # and breaks gethostbyname(2).  It's better to use the bind stuff in the C
 140 # library.  So don't add -lresolv to the link list unless it's necessary
 141 # (It will be necessary when using GNU libc6).
 142 old_LIBS="$LIBS"
 143 for lib in '' -lresolv; do
 144     if test -z "$lib"; then
 145        AC_MSG_CHECKING([for res_search in libc])
 146     else
 147        AC_MSG_CHECKING([for res_search in $lib])
 148     fi
 149     LIBS="$old_LIBS $lib"
 150     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 151 #include <sys/types.h>
 152 #include <netinet/in.h>
 153 #ifdef HAVE_ARPA_NAMESER_H
 154 #include <arpa/nameser.h>
 155 #endif
 156 #ifdef HAVE_RESOLV_H
 157 #include <resolv.h>
 158 #endif
 159 extern int res_search();
 160 ]], [[res_search(0, 0, 0, 0, 0); dn_skipname(0,0);]])],
 161     [AC_MSG_RESULT([found])
 162      AC_DEFINE(HAVE_RES_SEARCH, [1],
 163                [Define to 1 if you have the 'res_search' and 'dn_skipname' functions.])
 164      break], [AC_MSG_RESULT([not found])])
 165      LIBS=$old_LIBS
 166 done
 167
 168 dnl Check for libcrypt -- it may live in libc or libcrypt, as on IRIX
 169 AC_CHECK_FUNC(crypt, , AC_CHECK_LIB(crypt,crypt))
 170
 171 AC_MSG_CHECKING(sys_siglist declaration in signal.h or unistd.h)
 172 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>
 173 /* NetBSD declares sys_siglist in <unistd.h>.  */
 174 #include <unistd.h>
 175 ]], [[char *msg = *(sys_siglist + 1);]])],[AC_DEFINE(SYS_SIGLIST_DECLARED,1,[Define if 'sys_siglist' is declared by <signal.h>.]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 176
 177 AC_DEFINE_UNQUOTED(PID_DIR, "/var/run", directory for PID lock files)
 178
 179 AC_ARG_ENABLE(pwmd,
 180         [  --enable-pwmd           enable Password Manager Daemon support],
 181         , [enable_pwmd=no])
 182
 183 if test "$enable_pwmd" = "yes"; then
 184     PKG_CHECK_EXISTS([libpwmd], have_libpwmd=1,
 185                      AC_MSG_ERROR([Could not find libpwmd pkg-config module.]))
 186
 187
 188     PKG_CHECK_MODULES([libpwmd], [libpwmd >= 6.0.0])
 189     AM_CONDITIONAL(HAVE_LIBPWMD, true)
 190     AC_DEFINE(HAVE_LIBPWMD, 1, [Define if you have libPWMD installed.])
 191 else
 192     AM_CONDITIONAL(HAVE_LIBPWMD, false)
 193 fi
 194
 195 # We may have a fallback MDA available in case the socket open to the
 196 # local SMTP listener fails.  Best to use procmail for this, as we know
 197 # it won't try delivering through local SMTP and cause a mail loop.
 198 # Sendmail without the -t option to use the message headers will work too,
 199 # not just for sendmail itself but for workalikes like exim.
 200 #
 201 # Note1: A disadvantage of using procmail is that local alias expansion
 202 # according to /etc/aliases won't get done if we fall back.  This doesn't
 203 # matter in single-drop mode.
 204 #
 205 # Note2: it would be a very bad idea to use any MDA that doesn't return
 206 # a refuse-to-deliver status on disk- or process-table-full
 207 # conditions; mail could get lost that way.  Sendmail and all of the MDAs
 208 # like exim that might be lurking under a sendmail alias) do the right
 209 # thing in this circumstance.  Matthias Andree warns that procmail does
 210 # not.
 211 #
 212 # Note3: Defalt value of fallback is now off.  Matthias writes:
 213 #
 214 # 1. there is no way to predict when the fallback is used. With some MTAs
 215 #    (such as those limiting load average), outer circumstances can cause
 216 #    the fallback to kick in.
 217 #
 218 # 2. the fallback changes fetchmail behaviour in unpredictable ways. It's
 219 #    not only about alias expansion, .forwards to special filters won't
 220 #    work, mail may end up in a different place (users claim "mail loss"
 221 #    for that).
 222 #
 223 # 3. The claim procmail did the right thing with its exit codes is plain
 224 #    wrong. I've seen procmail exit with code 1 when it should have exited
 225 #    with code 75, like, configuration errors. Procmail is a dangerous
 226 #    beast and is best replaced by maildrop.
 227 #
 228 # 4. if multiple choices exist (like procmail and maildrop), fetchmail
 229 #    cannot tell which one it should choose. Say, your MTA is configured
 230 #    to use maildrop to deliver to user's mailboxes, if fetchmail then
 231 #    chooses procmail, this is plain wrong.
 232 #
 233
 234 AC_PATH_PROG(procmail, procmail, "", $PATH:/usr/sbin)
 235 AC_PATH_PROG(sendmail, sendmail, "", $PATH:/usr/sbin:/usr/lib)
 236 AC_PATH_PROG(maildrop, maildrop, "", $PATH:/usr/local/bin)
 237
 238 ###     use option --disable-fallback to disable fallback MDA
 239 ###     use option --enable-fallback=procmail or
 240 ###                --enable-fallback=sendmail to select
 241 AC_ARG_ENABLE(fallback,
 242         [  --enable-fallback=procmail    enable procmail as fallback
 243   --enable-fallback=sendmail    enable /usr/sbin/sendmail as fallback
 244   --enable-fallback=maildrop    enable maildrop as fallback
 245   --enable-fallback=no          disable fallback],,[enable_fallback=no])
 246
 247 case "$enable_fallback" in
 248         sendmail)       if test -z "$sendmail" ; then
 249                                 AC_MSG_ERROR([Sendmail selected as fallback, but not found])
 250                                 #not reached
 251                         fi
 252                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$sendmail -i %T", Fallback MTA to use if defined)
 253                         AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 254                         ;;
 255         procmail)       if test -z "$procmail" ; then
 256                                 AC_MSG_ERROR([procmail selected as fallback, but not found])
 257                                 #not reached
 258                         fi
 259                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$procmail -d %T")
 260                         AC_MSG_NOTICE(Will use $procmail as fallback MDA.)
 261                         ;;
 262         maildrop)       if test -z "$maildrop" ; then
 263                                 AC_MSG_ERROR([maildrop selected as fallback, but not found])
 264                                 #not reached
 265                         fi
 266                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$maildrop -d %T")
 267                         AC_MSG_NOTICE(Will use $maildrop as fallback MDA.)
 268                         ;;
 269         no|unset)       AC_MSG_NOTICE(Will not use a fallback MDA.)
 270                         ;;
 271         auto|yes|set)   if test -n "$sendmail" ; then
 272                                 AC_DEFINE_UNQUOTED(FALLBACK_MDA,"$sendmail -i %T")
 273                                 AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 274                         else
 275                                 AC_MSG_WARN(No fallback MDA available.  procmail and maildrop are not eligible)
 276                                 AC_MSG_WARN(for automatic fallback MDA configuration for reliability reasons.)
 277                         fi
 278                         ;;
 279         *)              AC_MSG_ERROR([unkown value for --enable-fallback given: $enable_fallback])
 280                         #notreached
 281                         ;;
 282 esac
 283
 284 ###     use option --disable-POP3 to omit the POP3 support
 285 AC_ARG_ENABLE(POP3,
 286         [  --disable-POP3          don't compile in POP3 protocol support],
 287         [with_POP3=$enableval],
 288         [with_POP3=yes])
 289 test "$with_POP3" = "yes" && AC_DEFINE(POP3_ENABLE,1,Define if you want POP3 support compiled in)
 290 AM_CONDITIONAL(POP3_ENABLE, test "$with_POP3" = yes)
 291
 292 ###     use option --disable-IMAP to omit the IMAP support
 293 AC_ARG_ENABLE(IMAP,
 294         [  --disable-IMAP          don't compile in IMAP protocol support],
 295         [with_IMAP=$enableval],
 296         [with_IMAP=yes])
 297 test "$with_IMAP" = "yes" && AC_DEFINE(IMAP_ENABLE,1,Define if you want IMAP support compiled in)
 298 AM_CONDITIONAL(IMAP_ENABLE, test "$with_IMAP" = yes)
 299
 300 ###     use option --disable-ETRN to omit the ETRN support
 301 AC_ARG_ENABLE(ETRN,
 302         [  --disable-ETRN          don't compile in ETRN protocol support],
 303         [with_ETRN=$enableval],
 304         [with_ETRN=yes])
 305 test "$with_ETRN" = "yes" && AC_DEFINE(ETRN_ENABLE,1,Define if you want ETRN support compiled in.)
 306 AM_CONDITIONAL(ETRN_ENABLE, test "$with_ETRN" = yes)
 307
 308 ###     use option --disable-ODMR to omit the ODMR support
 309 AC_ARG_ENABLE(ODMR,
 310         [  --disable-ODMR          don't compile in ODMR protocol support],
 311         [with_ODMR=$enableval],
 312         [with_ODMR=yes])
 313 test "$with_ODMR" = "yes" && AC_DEFINE(ODMR_ENABLE,1,Define if you want ODMR support compiled in)
 314 AM_CONDITIONAL(ODMR_ENABLE, test "$with_ODMR" = yes)
 315
 316 ###     use option --enable-RPA to compile in the RPA support
 317 AC_ARG_ENABLE(RPA,
 318         [  --enable-RPA            compile in RPA protocol support],
 319         [with_RPA=$enableval],
 320         [with_RPA=no])
 321 test "$with_RPA" = "yes" && AC_DEFINE(RPA_ENABLE,1,Define if you want RPA support compiled in)
 322 AM_CONDITIONAL(RPA_ENABLE, test "$with_RPA" = yes)
 323
 324 ###     use option --enable-NTLM to compile in the NTLM support
 325 AC_ARG_ENABLE(NTLM,
 326         [  --enable-NTLM           compile in NTLM authentication support],
 327         [with_NTLM=$enableval],
 328         [with_NTLM=no])
 329 test "$with_NTLM" = "yes" && AC_DEFINE(NTLM_ENABLE,1,Define if you want NTLM authentication)
 330 AM_CONDITIONAL(NTLM_ENABLE, test "$with_NTLM" = yes)
 331
 332 ###     use option --enable-SDPS to compile in the SDPS support
 333 AC_ARG_ENABLE(SDPS,
 334         [  --enable-SDPS           compile in SDPS protocol support],
 335         [with_SDPS=$enableval],
 336         [with_SDPS=no])
 337 if test "$with_SDPS" = yes ; then
 338    if test "$with_POP3" != yes ; then
 339        AC_MSG_WARN([SDPS cannot be enabled with POP3 disabled. Disabling SDPS.])
 340        with_SDPS=no
 341    else
 342        AC_DEFINE(SDPS_ENABLE,1,Define if you want SDPS support compiled in)
 343    fi
 344 fi
 345 if test "$with_POP3" != yes && test "$with_IMAP"  != yes ; then
 346     AC_MSG_ERROR([You must enable at least one of POP3 and IMAP.])
 347 fi
 348
 349 AC_CACHE_SAVE
 350
 351 ###     use option --enable-opie to compile in the OPIE support
 352 AC_ARG_ENABLE(opie,
 353         [  --enable-opie           support OTP through the OPIE library],
 354         [ AC_CHECK_HEADER(opie.h,, [AC_MSG_ERROR([cannot find <opie.h>, which is required for OPIE support.])])
 355           AC_CHECK_LIB(opie,opiegenerator,, [AC_MSG_ERROR([cannot find libopie, which is required for OPIE support.])])
 356           with_opie=$enableval],
 357         [with_opie=no])
 358 test "$with_opie" = "yes" && AC_DEFINE(OPIE_ENABLE,1,Define if you want OPIE support compiled in)
 359
 360 dnl Mostly stolen from gnulib's getaddrinfo.m4
 361 AC_SEARCH_LIBS(getaddrinfo, [nsl socket])
 362 AC_CACHE_CHECK([for getaddrinfo],[fm_cv_getaddrinfo],[
 363   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 364 #include <sys/types.h>
 365 #include <sys/socket.h>
 366 #include <netdb.h>
 367   ]], [[getaddrinfo(0, 0, 0, 0);]])],[ fm_cv_getaddrinfo=yes],[ fm_cv_getaddrinfo=no ])
 368 ])
 369
 370 if test x"$fm_cv_getaddrinfo" = "xyes"; then
 371      AC_DEFINE(HAVE_GETADDRINFO, 1,
 372       [Define to 1 if you have the getaddrinfo function.])
 373 fi
 374
 375 AC_CACHE_CHECK([for getnameinfo],[fm_cv_getnameinfo],[
 376   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 377 #include <sys/types.h>
 378 #include <sys/socket.h>
 379 #include <netdb.h>
 380 #ifndef NULL
 381 #define NULL 0
 382 #endif
 383   ]], [[getnameinfo(NULL,0, NULL,0, NULL, 0, 0);]])],[ fm_cv_getnameinfo=yes],[ fm_cv_getnameinfo=no ])
 384 ])
 385 if test $fm_cv_getnameinfo = yes ; then
 386     AC_DEFINE(HAVE_GETNAMEINFO,1,[Define to 1 if your system has getnameinfo()])
 387 fi
 388
 389 AM_CONDITIONAL(NEED_GETADDRINFO, test "$fm_cv_getaddrinfo" != yes)
 390 AM_CONDITIONAL(NEED_GETNAMEINFO, test "$fm_cv_getnameinfo"   != yes)
 391
 392 AC_CHECK_FUNCS(inet_ntop)
 393 dnl Check if getaddrinfo is async-signal-safe - most implementations aren't
 394 if test "$fm_cv_getaddrinfo" = yes ; then
 395     AC_MSG_CHECKING(if your getaddrinfo is async-signal-safe)
 396     gai_ts=no
 397     dnl we have getaddrinfo() - check if the OS is known to have a async-signal-safe implementation
 398     case $host_os in
 399         darwin9*)                               gai_ts=yes ;;
 400         linux*)                                 gai_ts=yes ;;
 401         freebsd5.5|freebsd6*|freebsd7*)         gai_ts=yes ;;
 402         solaris2.8|solaris2.9|solaris2.10)      gai_ts=yes ;;
 403     esac
 404     AC_MSG_RESULT($gai_ts)
 405     if test $gai_ts = yes ; then
 406         AC_DEFINE(GETADDRINFO_ASYNCSAFE, 1, [define to 1 if you know your getaddrinfo function is async-signal-safe])
 407     fi
 408 fi
 409
 410 # This version of the Kerberos 5 options addresses the follwing issues:
 411 #
 412 # * Build correctly under Heimdal kerberos if it is compiled with db2 and
 413 #   OpenSSL support (Debian's is)
 414
 415 ###    use option --with-kerberos5=DIR to point at a Kerberos 5 directory
 416 ### make sure --with-ssl is run before --with-kerberos* !
 417 AC_ARG_WITH(kerberos5,
 418        [  --with-kerberos5=DIR    point fetchmail compilation at a Kerberos 5 directory],
 419 [
 420 if test "$with_kerberos5" != "no"
 421 then
 422 # Check for a OpenBSD special case
 423 if test "$with_kerberos5" = "yes" && ( test `uname` = "OpenBSD" )
 424 then
 425   AS_MESSAGE(checking kerberosV for OpenBSD...)
 426   AC_DEFINE(HEIMDAL,1,Define if you have HEIMDAL kerberos 5)
 427   AC_DEFINE(KERBEROS_V5,1,Define if you have Kerberos V5)
 428   CFLAGS="$CFLAGS -I/usr/include/kerberosV"
 429   LIBS="$LIBS -lasn1 -lkrb5 -lcom_err -lkafs"
 430 elif krb5-config 2> /dev/null >/dev/null ; then
 431   krb5_prefix=`krb5-config --prefix krb5`
 432   AC_MSG_RESULT([krb5-config points to kerberosV under $krb5_prefix])
 433   if test -f ${krb5_prefix}/include/et/com_err.h && \
 434    ! test -f ${krb5_prefix}/include/com_err.h  ; then
 435     CFLAGS="$CFLAGS -I${krb5_prefix}/include/et"
 436   fi
 437   unset krb5_prefix
 438   CFLAGS="$CFLAGS `krb5-config --cflags krb5`"
 439   LIBS="$LIBS `krb5-config --libs krb5`"
 440   AC_DEFINE(KERBEROS_V5)
 441 else
 442   if test "$with_kerberos5" != "yes"
 443   then
 444       LDFLAGS="$LDFLAGS -L${with_kerberos5}/lib"
 445       searchdirs="$with_kerberos5"
 446   else
 447       searchdirs="/usr/kerberos /usr/local/krb5 /usr/athena /usr"
 448   fi
 449   with_kerberos5=
 450   for dir in $searchdirs
 451   do AC_MSG_CHECKING([for Kerberos V in $dir])
 452      if test -f "$dir/include/krb5.h" || test -f "$dir/include/krb5/krb5.h"
 453      then
 454         if test -d "$dir/include/krb5" ; then CPPFLAGS="$CPPFLAGS -I$dir/include/krb5" ; fi
 455         ac_krblibs=
 456         if test -f "$dir/include/roken.h" || test -f "$dir/include/krb5/roken.h"
 457         then
 458            ac_krblibs="-lasn1 -lroken -lcom_err"
 459            AC_MSG_RESULT([Heimdal found])
 460           dnl Attempt to detect if we need to -ldb2 to link Heimdal
 461           dnl we assume we do if it is available
 462            AC_CHECK_LIB(db2, db_open, ac_krblibs="$ac_krblibs -ldb2", [],
 463                 ${LDFLAGS})
 464            AC_CHECK_LIB(des, des_string_to_key, libk5crypto=-ldes,
 465               AC_CHECK_LIB(crypto, MD5_Init, [],
 466                 AC_MSG_ERROR([DES libraries not found. Try adding --with-ssl to enable OpenSSL support]),
 467                 ${LDFLAGS} ${ac_krblibs}),
 468            ${LDFLAGS} ${ac_krblibs})
 469            AC_DEFINE(HEIMDAL)
 470         else
 471           AC_MSG_RESULT([found])
 472           ac_krblibs="-lcom_err"
 473            AC_CHECK_LIB(crypto,
 474              krb5_des_string_to_key,
 475              libk5crypto=-lcrypto,
 476                 AC_CHECK_LIB(k5crypto,
 477                    krb5_des_string_to_key,
 478                    libk5crypto=-lk5crypto,
 479                       AC_MSG_ERROR([Kerberos 5 DES libraries not found]),
 480                    ${LDFLAGS} ${ac_krblibs}),
 481                  ${LDFLAGS} ${ac_krblibs})
 482         fi
 483         AC_CHECK_LIB(krb5, krb5_init_context,[],
 484            continue,
 485            ${LDFLAGS} ${ac_krblibs})
 486         AC_DEFINE(KERBEROS_V5)
 487         test "$dir" != "/usr" && CFLAGS="$CFLAGS -I$dir/include"
 488         LDFLAGS="$LDFLAGS -L$dir/lib"
 489        LIBS="$LIBS $ac_krblibs $libk5crypto"
 490         with_kerberos5=$dir
 491         break
 492      else
 493         AC_MSG_RESULT([not found])
 494      fi
 495   done
 496   if test -z "$with_kerberos5" ; then
 497      AC_MSG_ERROR([Kerberos 5 libraries not found])
 498   fi
 499 fi
 500 fi
 501 ]) dnl --with-kerberos5=DIR
 502
 503 ###     use option --with-ssl to compile in the SSL support
 504 AC_ARG_WITH(ssl,
 505         [  --with-ssl=[DIR]        enable SSL support using libraries in DIR],
 506         [with_ssl=$withval],
 507         [with_ssl=yes])
 508 test "$with_ssl" != "no" && AC_DEFINE(SSL_ENABLE,1,Define if you want SSL support compiled in)
 509
 510 if test "$with_ssl" = "yes"
 511 then
 512     #   User didn't specify an SSL location.  Let's look at some common
 513     #   directories where SSL has been found in the past and try and auto
 514     #   configure for SSL.  OpenSSL determination will be made later.
 515     #   This will screw up if an OpenSSL install is located in a later
 516     #   directory than an older SSLeay install, but the user should fix that
 517     #   anyways and he can override on the configure line.
 518     #   Just testing for directories is not sufficient, /usr exists on
 519     #   all systems!
 520     for ac_dir in \
 521       /usr/local/ssl \
 522       /usr/local \
 523       /usr/ssl \
 524       /usr \
 525       /local/ssl \
 526       /opt/ssl \
 527       /opt/csw \
 528       ; \
 529     do
 530         if test -r "$ac_dir/include/openssl/ssl.h" ; then
 531             with_ssl=$ac_dir
 532             break;
 533         fi
 534     done
 535 fi
 536
 537 if test -n "$with_ssl" -a "$with_ssl" != "no"
 538 then
 539   # With the autoconfigure above, the only time this is going to be
 540   # true is going to be when we could not find the headers.  If they
 541   # are not in system standard locations, we are going to be broken.
 542   if test "$with_ssl" = "yes"
 543   then
 544     # Let's just define the standard location for the SSLeay root
 545     with_ssl="/usr/local/ssl"
 546   fi
 547   if test -r $with_ssl/include/openssl/ssl.h
 548   then
 549     ### ssl.h found under openssl.  Use openssl configuration preferentially,
 550     AC_MSG_NOTICE(Enabling OpenSSL support in $with_ssl.)
 551     test "$with_ssl" != "/usr" && CFLAGS="$CFLAGS -I$with_ssl/include"
 552     ### In Red Hat 9, this file includes a reference to <krb5.h>, so we
 553     ### force the Kerberos direcory onto the include path so it will build.
 554     CFLAGS="$CFLAGS -I/usr/kerberos/include"
 555     ### OpenBSD comes with ssl headers
 556   else
 557     AC_MSG_ERROR([SSL support enabled, but OpenSSL not found])
 558   fi
 559   LDFLAGS="$LDFLAGS -L$with_ssl/lib"
 560   LIBS="$LIBS -lssl -lcrypto"
 561   dnl check if -ldl is needed
 562   AC_MSG_CHECKING([for additional library dependencies of SSL])
 563   found=0
 564   save_LIBS="$LIBS"
 565   for i in "" "-ldl" ; do
 566       LIBS="$LDFLAGS $save_LIBS $i"
 567       AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <openssl/ssl.h>],[SSL_library_init()])],[found=1; break])
 568   done
 569   if test $found = 0 ; then
 570       AC_MSG_RESULT([error])
 571       AC_MSG_ERROR([cannot link with SSL - check config.log])
 572   fi
 573   LIBS="$save_LIBS $i"
 574   if test "$i" = "" ; then i="(none)" ; fi
 575   AC_MSG_RESULT($i)
 576   dnl XXX FIXME: use pkg-config if available!
 577   AC_DEFINE(SSL_ENABLE)
 578 else
 579   AC_MSG_WARN(Disabling SSL support.)
 580   AC_MSG_WARN(Consider re-running configure --with-ssl.)
 581 fi
 582
 583 case "$LIBS" in *-lssl*)
 584         AC_CHECK_DECLS([SSLv2_client_method],,,[#include <openssl/ssl.h>])
 585         ;;
 586 esac
 587
 588 ###     use option --with-socks=DIR to point at SOCKS library
 589 AC_ARG_WITH(socks,
 590         [  --with-socks[=DIR]      add built-in SOCKS firewall access],
 591 [
 592 if test "$with_socks" != no
 593 then
 594     if test "$with_socks" != yes
 595     then
 596         LDFLAGS="$LDFLAGS -L$with_socks"
 597     else
 598         AC_CHECK_LIB(socks, Rconnect,,
 599                AC_MSG_ERROR([could not find libsocks which is needed for built-in SOCKS support]))
 600     fi
 601     AC_DEFINE(HAVE_SOCKS,1,Define if you want built-in SOCKS support)
 602     CFLAGS="$CFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 603     LIBS="-lsocks $LIBS"
 604 fi])
 605
 606 ###     use option --with-socks5=DIR to point at SOCKS library
 607 AC_ARG_WITH(socks5,
 608         [  --with-socks5[=DIR]     add built-in SOCKS5 firewall access],
 609 [
 610 if test "$with_socks5" != no
 611 then
 612   if test "$with_socks5" != yes
 613   then
 614     LDFLAGS="$LDFLAGS -L$with_socks5"
 615   fi
 616   ac_savedLDFLAGS="$LDFLAGS"
 617   LDFLAGS="$LDFLAGS $LDFLAGS"
 618   AC_CHECK_LIB(socks5, SOCKSconnect,,
 619         AC_MSG_ERROR([could not find libsocks5 which is needed for built-in SOCKS5 support]))
 620   AC_DEFINE(HAVE_SOCKS)
 621   CFLAGS="$CFLAGS -Dconnect=SOCKSconnect -Dgetsockname=SOCKSgetsockname -Dbind=SOCKSbind -Daccept=SOCKSaccept -Dlisten=SOCKSlisten -Dselect=SOCKSselect -Drecvfrom=SOCKSrecvfrom -Dsendto=SOCKSsendto -Drecv=SOCKSrecv -Dsend=SOCKSsend -Dread=SOCKSread -Dwrite=SOCKSwrite -Drresvport=SOCKSrresvport -Dshutdown=SOCKSshutdown -Dlisten=SOCKSlisten -Dclose=SOCKSclose -Ddup=SOCKSdup -Ddup2=SOCKSdup2 -Dgethostbyname=SOCKSgethostbyname"
 622   AC_CHECK_FUNC(SOCKSfclose, [CFLAGS="$CFLAGS -Dfclose=SOCKSfclose"])
 623   LDFLAGS="$ac_savedLDFLAGS"
 624 fi])
 625
 626 dnl for libesmtp/ modules:
 627 ACX_WHICH_GETHOSTBYNAME_R
 628
 629 ###     use option --with-hesiod=DIR to point at a HESIOD directory
 630 AC_ma_SEARCH_PACKAGE(hesiod, hesiod_getmailhost, /usr/athena /usr /usr/local,hesiod, hesiod.h)
 631
 632 ###     use option --with-gssapi=DIR to compile in GSSAPI support
 633 AC_ARG_WITH(gssapi,
 634         [  --with-gssapi[=DIR]     compile in GSSAPI support using libraries in DIR],
 635 [
 636 if test "$with_gssapi" != "no"
 637 then
 638   if test "$with_gssapi" = "yes" -a -n "$with_kerberos5"
 639   then
 640     with_gssapi=$with_kerberos5
 641   fi
 642
 643   if test "$with_gssapi" != "yes" -a -n "$with_gssapi"
 644   then
 645     CFLAGS="$CFLAGS -I$with_gssapi/include"
 646     LDFLAGS="$LDFLAGS -L$with_gssapi/lib"
 647   fi
 648
 649   dnl obtain gssapi default libs
 650   if krb5-config --libs gssapi 2>/dev/null >/dev/null ; then
 651       LIBS="$LIBS `krb5-config --libs gssapi`"
 652   else
 653     AC_CHECK_LIB(gss, gss_check_version, LIBS="$LIBS -lgss", nogss=t)
 654     if test -n "$nogss"
 655     then
 656       # -lgss not found
 657       if test "$with_gssapi" = yes ; then
 658           with_gssapi=/usr
 659       fi
 660       if test -f "$with_gssapi/include/roken.h" -o -f "$with_gssapi/include/krb5/roken.h"
 661       then
 662          # have roken.h, assume Heimdal
 663          case `uname` in
 664              NetBSD) LIBS="$LIBS -lkrb5" ;;
 665              *)      LIBS="$LIBS -lkrb5 -lasn1 -ldes -lroken -ldb -ldl" ;;
 666          esac
 667          AC_CHECK_LIB(gssapi, gss_init_sec_context,LIBS="$LIBS -lgssapi",
 668                       AC_MSG_ERROR([could not find libgssapi which is needed for GSSAPI support]), )
 669          AC_DEFINE(HEIMDAL)
 670       else
 671          # no roken.h, assume MIT
 672          AC_CHECK_LIB(gssapi_krb5, gss_init_sec_context,LIBS="$LIBS -lgssapi_krb5",
 673                       AC_MSG_ERROR([could not find libgssapi_krb5 which is needed for GSSAPI support]), -lkrb5)
 674       fi
 675     fi
 676   fi
 677   AC_DEFINE(GSSAPI,1,Define if you want GSSAPI authentication)
 678   if test "$with_gssapi" != yes ; then
 679     CPPFLAGS="$CPPFLAGS -I$with_gssapi/include"
 680   fi
 681   AC_CHECK_HEADERS(gss.h gssapi.h gssapi/gssapi.h gssapi/gssapi_generic.h)
 682   AC_CHECK_DECLS(GSS_C_NT_HOSTBASED_SERVICE,,,[
 683     AC_INCLUDES_DEFAULT
 684     #if HAVE_GSS_H
 685     #include <gss.h>
 686     #endif
 687     #if HAVE_GSSAPI_GSSAPI_H
 688     #include <gssapi/gssapi.h>
 689     #elif HAVE_GSSAPI_H
 690     #include <gssapi.h>
 691     #endif
 692     #if HAVE_GSSAPI_GSSAPI_GENERIC_H
 693     #include <gssapi/gssapi_generic.h>
 694     #endif
 695     ])
 696 fi])
 697
 698 AC_CONFIG_FILES([Makefile po/Makefile.in])
 699 AC_OUTPUT
 700
 701 dnl Local Variables:
 702 dnl comment-start: "dnl "
 703 dnl comment-end: ""
 704 dnl comment-start-skip: "\\bdnl\\b\\s *"
 705 dnl compile-command: "make configure config.h.in"
 706 dnl End: