Pileus Git - ~andy/fetchmail/blob - configure.ac

   1 dnl Autoconfigure input file for fetchmail
   2 #
   3 # Fetchmail automatic configuration support
   4 #
   5 # Eric S. Raymond <esr@thyrsus.com>
   6 # 2004 - 2012 Matthias Andree <matthias.andree@gmx.de>
   7 #
   8 dnl Process this file with autoconf to produce a configure script.
   9 dnl
  10
  11 dnl XXX - if bumping version here, check fetchmail.man, too!
  12 AC_INIT([fetchmail],[7.0.0-alpha3],[fetchmail-devel@lists.berlios.de])
  13 AC_CONFIG_SRCDIR([fetchmail.h])
  14 AC_CONFIG_HEADERS([config.h])
  15 AC_CONFIG_LIBOBJ_DIR([.])
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl keep this before stuff that runs the compiler!
  20 AC_USE_SYSTEM_EXTENSIONS
  21
  22 dnl automake options are in Makefile.am
  23 AC_PREREQ(2.64)
  24 dnl 2.60 required for AC_USE_SYSTEM_EXTENSIONS
  25 AM_INIT_AUTOMAKE(silent-rules)
  26
  27 dnl python is optional
  28 #
  29 # you can pass PYTHON=: in environment or on the command line
  30 # to disable python detection and continue without building/installing
  31 # fetchmail.conf -- be sure to check README.packaging, too!
  32 #
  33 AM_PATH_PYTHON(2.0,,AC_MSG_WARN([Disabling fetchmailconf: python 2.0 or greater not found]))
  34 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
  35
  36 AC_PROG_AWK
  37 AC_PROG_CC_C99
  38 AC_PROG_INSTALL
  39 AM_PROG_LEX
  40 AC_PROG_MAKE_SET
  41 AC_PROG_RANLIB
  42 AC_PROG_YACC
  43
  44 dnl check for b0rked Solaris (and other shells) and find one that works
  45 AC_MSG_CHECKING(for a working shell...)
  46 for i in /usr/xpg6/bin/sh /usr/xpg4/bin/sh /usr/ccs/bin/sh /bin/sh /usr/bin/sh /bin/ksh /bin/bash /usr/local/bin/bash ; do
  47     $i -c 'if ! false ; then echo $(echo ok) ; fi' >config.$$ 2>/dev/null
  48     j=`cat config.$$`
  49     rm -f config.$$
  50     if test "x$j" = "xok" ; then
  51         SHELL=$i
  52         AC_SUBST(SHELL)
  53         break
  54     fi
  55 done
  56 AC_MSG_RESULT($SHELL)
  57 if test "x$SHELL" = "x" ; then
  58     AC_MSG_ERROR(no SUS compliant shell found - on Solaris, install SUNWxcu4)
  59 fi
  60
  61 AC_CHECK_HEADERS([arpa/nameser.h])
  62
  63 AC_CHECK_HEADERS([resolv.h],,,[
  64 #include <sys/types.h>
  65 #include <netinet/in.h>
  66 #ifdef HAVE_ARPA_NAMESER_H
  67 #include <arpa/nameser.h>
  68 #endif
  69 ])
  70
  71 AC_CHECK_DECLS([h_errno],,,[
  72         AC_INCLUDES_DEFAULT
  73         #include <netdb.h>
  74 ])
  75
  76 # Check for OS special cases
  77 case $host_os in
  78 darwin*)
  79     AC_MSG_NOTICE(found Darwin - Adding -DBIND_8_COMPAT to CFLAGS)
  80     CPPFLAGS="$CPPFLAGS -DBIND_8_COMPAT"
  81     ;;
  82 # Check for FreeBSD special case: more libs needed
  83 freebsd*)
  84     AC_MSG_NOTICE(found FreeBSD - Adding -lkvm -lcom_err to standard libraries)
  85     LIBS="$LIBS -lkvm -lcom_err"
  86     ;;
  87 esac
  88
  89 AC_CACHE_SAVE
  90
  91 dnl i18n
  92 AM_GNU_GETTEXT([external], [need-ngettext])
  93 AM_GNU_GETTEXT_VERSION([0.17])
  94 dnl end i18n
  95
  96 # Under sysV68, socket and friends are provided by the C library.
  97 # -linet does not provide socket, but causes multiple definition
  98 # errors at link-time.  It is thus better to only use the C library.
  99 # So don't add -linet to the link list unless it's necessary
 100 AC_CHECK_FUNC(socket,
 101     AC_MSG_RESULT(using libc's socket),
 102     AC_CHECK_LIB(socket,socket)
 103     AC_CHECK_LIB(inet,socket))
 104
 105 # The condition in this test copes with the presence of inet_addr in libc6.
 106 AC_CHECK_FUNC(inet_addr,
 107     AC_MSG_RESULT(using libc's inet_addr),
 108     AC_CHECK_LIB(nsl,inet_addr))
 109
 110 AC_REPLACE_FUNCS([stpcpy strlcpy strlcat])
 111
 112 AC_CHECK_FUNC(getopt_long, [],
 113               [AC_LIBSOURCES([getopt.c, getopt1.c])
 114                EXTRAOBJ="$EXTRAOBJ getopt.\$(OBJEXT) getopt1.\$(OBJEXT)"])
 115
 116 AC_SUBST(EXTRAOBJ)
 117
 118 AC_CHECK_FUNCS(vsyslog inet_aton)
 119
 120 dnl INET6 is used by KAME/getnameinfo
 121 AC_CACHE_CHECK(for AF_INET6/PF_INET6,ac_cv_inet6,
 122 AC_COMPILE_IFELSE([
 123   AC_LANG_PROGRAM([[
 124     #include <sys/types.h>
 125     #include <sys/socket.h>
 126   ]],[[
 127     int foo = AF_INET6;
 128     int bar = PF_INET6;
 129   ]])],
 130   ac_cv_inet6=yes , ac_cv_inet6=no
 131 ))
 132 if test "x$ac_cv_inet6" = xyes
 133 then
 134     AC_DEFINE(INET6,1,Define to 1 if your system defines AF_INET6 and PF_INET6.)
 135 fi
 136
 137 # Under Red Hat 4.0 (and many other Linuxes) -lresolv is seriously flaky
 138 # and breaks gethostbyname(2).  It's better to use the bind stuff in the C
 139 # library.  So don't add -lresolv to the link list unless it's necessary
 140 # (It will be necessary when using GNU libc6).
 141 old_LIBS="$LIBS"
 142 for lib in '' -lresolv; do
 143     if test -z "$lib"; then
 144        AC_MSG_CHECKING([for res_search in libc])
 145     else
 146        AC_MSG_CHECKING([for res_search in $lib])
 147     fi
 148     LIBS="$old_LIBS $lib"
 149     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 150 #include <sys/types.h>
 151 #include <netinet/in.h>
 152 #ifdef HAVE_ARPA_NAMESER_H
 153 #include <arpa/nameser.h>
 154 #endif
 155 #ifdef HAVE_RESOLV_H
 156 #include <resolv.h>
 157 #endif
 158 extern int res_search();
 159 ]], [[res_search(0, 0, 0, 0, 0); dn_skipname(0,0);]])],
 160     [AC_MSG_RESULT([found])
 161      AC_DEFINE(HAVE_RES_SEARCH, [1],
 162                [Define to 1 if you have the 'res_search' and 'dn_skipname' functions.])
 163      break], [AC_MSG_RESULT([not found])])
 164      LIBS=$old_LIBS
 165 done
 166
 167 dnl Check for libcrypt -- it may live in libc or libcrypt, as on IRIX
 168 AC_CHECK_FUNC(crypt, , AC_CHECK_LIB(crypt,crypt))
 169
 170 AC_MSG_CHECKING(sys_siglist declaration in signal.h or unistd.h)
 171 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>
 172 /* NetBSD declares sys_siglist in <unistd.h>.  */
 173 #include <unistd.h>
 174 ]], [[char *msg = *(sys_siglist + 1);]])],[AC_DEFINE(SYS_SIGLIST_DECLARED,1,[Define if 'sys_siglist' is declared by <signal.h>.]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 175
 176 AC_DEFINE_UNQUOTED(PID_DIR, "/var/run", directory for PID lock files)
 177
 178 AC_ARG_ENABLE(pwmd,
 179         [  --enable-pwmd           enable Password Manager Daemon support],
 180         , [enable_pwmd=no])
 181
 182 if test "$enable_pwmd" = "yes"; then
 183     PKG_CHECK_EXISTS([libpwmd], have_libpwmd=1,
 184                      AC_MSG_ERROR([Could not find libpwmd pkg-config module.]))
 185
 186
 187     PKG_CHECK_MODULES([libpwmd], [libpwmd >= 6.0.0])
 188     AM_CONDITIONAL(HAVE_LIBPWMD, true)
 189     AC_DEFINE(HAVE_LIBPWMD, 1, [Define if you have libPWMD installed.])
 190 else
 191     AM_CONDITIONAL(HAVE_LIBPWMD, false)
 192 fi
 193
 194 # We may have a fallback MDA available in case the socket open to the
 195 # local SMTP listener fails.  Best to use procmail for this, as we know
 196 # it won't try delivering through local SMTP and cause a mail loop.
 197 # Sendmail without the -t option to use the message headers will work too,
 198 # not just for sendmail itself but for workalikes like exim.
 199 #
 200 # Note1: A disadvantage of using procmail is that local alias expansion
 201 # according to /etc/aliases won't get done if we fall back.  This doesn't
 202 # matter in single-drop mode.
 203 #
 204 # Note2: it would be a very bad idea to use any MDA that doesn't return
 205 # a refuse-to-deliver status on disk- or process-table-full
 206 # conditions; mail could get lost that way.  Sendmail and all of the MDAs
 207 # like exim that might be lurking under a sendmail alias) do the right
 208 # thing in this circumstance.  Matthias Andree warns that procmail does
 209 # not.
 210 #
 211 # Note3: Defalt value of fallback is now off.  Matthias writes:
 212 #
 213 # 1. there is no way to predict when the fallback is used. With some MTAs
 214 #    (such as those limiting load average), outer circumstances can cause
 215 #    the fallback to kick in.
 216 #
 217 # 2. the fallback changes fetchmail behaviour in unpredictable ways. It's
 218 #    not only about alias expansion, .forwards to special filters won't
 219 #    work, mail may end up in a different place (users claim "mail loss"
 220 #    for that).
 221 #
 222 # 3. The claim procmail did the right thing with its exit codes is plain
 223 #    wrong. I've seen procmail exit with code 1 when it should have exited
 224 #    with code 75, like, configuration errors. Procmail is a dangerous
 225 #    beast and is best replaced by maildrop.
 226 #
 227 # 4. if multiple choices exist (like procmail and maildrop), fetchmail
 228 #    cannot tell which one it should choose. Say, your MTA is configured
 229 #    to use maildrop to deliver to user's mailboxes, if fetchmail then
 230 #    chooses procmail, this is plain wrong.
 231 #
 232
 233 AC_PATH_PROG(procmail, procmail, "", $PATH:/usr/sbin)
 234 AC_PATH_PROG(sendmail, sendmail, "", $PATH:/usr/sbin:/usr/lib)
 235 AC_PATH_PROG(maildrop, maildrop, "", $PATH:/usr/local/bin)
 236
 237 ###     use option --disable-fallback to disable fallback MDA
 238 ###     use option --enable-fallback=procmail or
 239 ###                --enable-fallback=sendmail to select
 240 AC_ARG_ENABLE(fallback,
 241         [  --enable-fallback=procmail    enable procmail as fallback
 242   --enable-fallback=sendmail    enable /usr/sbin/sendmail as fallback
 243   --enable-fallback=maildrop    enable maildrop as fallback
 244   --enable-fallback=no          disable fallback],,[enable_fallback=no])
 245
 246 case "$enable_fallback" in
 247         sendmail)       if test -z "$sendmail" ; then
 248                                 AC_MSG_ERROR([Sendmail selected as fallback, but not found])
 249                                 #not reached
 250                         fi
 251                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$sendmail -i %T", Fallback MTA to use if defined)
 252                         AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 253                         ;;
 254         procmail)       if test -z "$procmail" ; then
 255                                 AC_MSG_ERROR([procmail selected as fallback, but not found])
 256                                 #not reached
 257                         fi
 258                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$procmail -d %T")
 259                         AC_MSG_NOTICE(Will use $procmail as fallback MDA.)
 260                         ;;
 261         maildrop)       if test -z "$maildrop" ; then
 262                                 AC_MSG_ERROR([maildrop selected as fallback, but not found])
 263                                 #not reached
 264                         fi
 265                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$maildrop -d %T")
 266                         AC_MSG_NOTICE(Will use $maildrop as fallback MDA.)
 267                         ;;
 268         no|unset)       AC_MSG_NOTICE(Will not use a fallback MDA.)
 269                         ;;
 270         auto|yes|set)   if test -n "$sendmail" ; then
 271                                 AC_DEFINE_UNQUOTED(FALLBACK_MDA,"$sendmail -i %T")
 272                                 AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 273                         else
 274                                 AC_MSG_WARN(No fallback MDA available.  procmail and maildrop are not eligible)
 275                                 AC_MSG_WARN(for automatic fallback MDA configuration for reliability reasons.)
 276                         fi
 277                         ;;
 278         *)              AC_MSG_ERROR([unkown value for --enable-fallback given: $enable_fallback])
 279                         #notreached
 280                         ;;
 281 esac
 282
 283 ###     use option --disable-POP3 to omit the POP3 support
 284 AC_ARG_ENABLE(POP3,
 285         [  --disable-POP3          don't compile in POP3 protocol support],
 286         [with_POP3=$enableval],
 287         [with_POP3=yes])
 288 test "$with_POP3" = "yes" && AC_DEFINE(POP3_ENABLE,1,Define if you want POP3 support compiled in)
 289 AM_CONDITIONAL(POP3_ENABLE, test "$with_POP3" = yes)
 290
 291 ###     use option --disable-IMAP to omit the IMAP support
 292 AC_ARG_ENABLE(IMAP,
 293         [  --disable-IMAP          don't compile in IMAP protocol support],
 294         [with_IMAP=$enableval],
 295         [with_IMAP=yes])
 296 test "$with_IMAP" = "yes" && AC_DEFINE(IMAP_ENABLE,1,Define if you want IMAP support compiled in)
 297 AM_CONDITIONAL(IMAP_ENABLE, test "$with_IMAP" = yes)
 298
 299 ###     use option --disable-ETRN to omit the ETRN support
 300 AC_ARG_ENABLE(ETRN,
 301         [  --disable-ETRN          don't compile in ETRN protocol support],
 302         [with_ETRN=$enableval],
 303         [with_ETRN=yes])
 304 test "$with_ETRN" = "yes" && AC_DEFINE(ETRN_ENABLE,1,Define if you want ETRN support compiled in.)
 305 AM_CONDITIONAL(ETRN_ENABLE, test "$with_ETRN" = yes)
 306
 307 ###     use option --disable-ODMR to omit the ODMR support
 308 AC_ARG_ENABLE(ODMR,
 309         [  --disable-ODMR          don't compile in ODMR protocol support],
 310         [with_ODMR=$enableval],
 311         [with_ODMR=yes])
 312 test "$with_ODMR" = "yes" && AC_DEFINE(ODMR_ENABLE,1,Define if you want ODMR support compiled in)
 313 AM_CONDITIONAL(ODMR_ENABLE, test "$with_ODMR" = yes)
 314
 315 ###     use option --enable-RPA to compile in the RPA support
 316 AC_ARG_ENABLE(RPA,
 317         [  --enable-RPA            compile in RPA protocol support],
 318         [with_RPA=$enableval],
 319         [with_RPA=no])
 320 test "$with_RPA" = "yes" && AC_DEFINE(RPA_ENABLE,1,Define if you want RPA support compiled in)
 321 AM_CONDITIONAL(RPA_ENABLE, test "$with_RPA" = yes)
 322
 323 ###     use option --enable-NTLM to compile in the NTLM support
 324 AC_ARG_ENABLE(NTLM,
 325         [  --enable-NTLM           compile in NTLM authentication support],
 326         [with_NTLM=$enableval],
 327         [with_NTLM=no])
 328 test "$with_NTLM" = "yes" && AC_DEFINE(NTLM_ENABLE,1,Define if you want NTLM authentication)
 329 AM_CONDITIONAL(NTLM_ENABLE, test "$with_NTLM" = yes)
 330
 331 ###     use option --enable-SDPS to compile in the SDPS support
 332 AC_ARG_ENABLE(SDPS,
 333         [  --enable-SDPS           compile in SDPS protocol support],
 334         [with_SDPS=$enableval],
 335         [with_SDPS=no])
 336 if test "$with_SDPS" = yes ; then
 337    if test "$with_POP3" != yes ; then
 338        AC_MSG_WARN([SDPS cannot be enabled with POP3 disabled. Disabling SDPS.])
 339        with_SDPS=no
 340    else
 341        AC_DEFINE(SDPS_ENABLE,1,Define if you want SDPS support compiled in)
 342    fi
 343 fi
 344 if test "$with_POP3" != yes && test "$with_IMAP"  != yes ; then
 345     AC_MSG_ERROR([You must enable at least one of POP3 and IMAP.])
 346 fi
 347
 348 AC_CACHE_SAVE
 349
 350 ###     use option --enable-opie to compile in the OPIE support
 351 AC_ARG_ENABLE(opie,
 352         [  --enable-opie           support OTP through the OPIE library],
 353         [ AC_CHECK_HEADER(opie.h,, [AC_MSG_ERROR([cannot find <opie.h>, which is required for OPIE support.])])
 354           AC_CHECK_LIB(opie,opiegenerator,, [AC_MSG_ERROR([cannot find libopie, which is required for OPIE support.])])
 355           with_opie=$enableval],
 356         [with_opie=no])
 357 test "$with_opie" = "yes" && AC_DEFINE(OPIE_ENABLE,1,Define if you want OPIE support compiled in)
 358
 359 dnl Mostly stolen from gnulib's getaddrinfo.m4
 360 AC_SEARCH_LIBS(getaddrinfo, [nsl socket])
 361 AC_CACHE_CHECK([for getaddrinfo],[fm_cv_getaddrinfo],[
 362   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 363 #include <sys/types.h>
 364 #include <sys/socket.h>
 365 #include <netdb.h>
 366   ]], [[getaddrinfo(0, 0, 0, 0);]])],[ fm_cv_getaddrinfo=yes],[ fm_cv_getaddrinfo=no ])
 367 ])
 368
 369 if test x"$fm_cv_getaddrinfo" = "xyes"; then
 370      AC_DEFINE(HAVE_GETADDRINFO, 1,
 371       [Define to 1 if you have the getaddrinfo function.])
 372 fi
 373
 374 AC_CACHE_CHECK([for getnameinfo],[fm_cv_getnameinfo],[
 375   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 376 #include <sys/types.h>
 377 #include <sys/socket.h>
 378 #include <netdb.h>
 379 #ifndef NULL
 380 #define NULL 0
 381 #endif
 382   ]], [[getnameinfo(NULL,0, NULL,0, NULL, 0, 0);]])],[ fm_cv_getnameinfo=yes],[ fm_cv_getnameinfo=no ])
 383 ])
 384 if test $fm_cv_getnameinfo = yes ; then
 385     AC_DEFINE(HAVE_GETNAMEINFO,1,[Define to 1 if your system has getnameinfo()])
 386 fi
 387
 388 AM_CONDITIONAL(NEED_GETADDRINFO, test "$fm_cv_getaddrinfo" != yes)
 389 AM_CONDITIONAL(NEED_GETNAMEINFO, test "$fm_cv_getnameinfo"   != yes)
 390
 391 AC_CHECK_FUNCS(inet_ntop)
 392 dnl Check if getaddrinfo is async-signal-safe - most implementations aren't
 393 if test "$fm_cv_getaddrinfo" = yes ; then
 394     AC_MSG_CHECKING(if your getaddrinfo is async-signal-safe)
 395     gai_ts=no
 396     dnl we have getaddrinfo() - check if the OS is known to have a async-signal-safe implementation
 397     case $host_os in
 398         darwin9*)                               gai_ts=yes ;;
 399         linux*)                                 gai_ts=yes ;;
 400         freebsd5.5|freebsd6*|freebsd7*)         gai_ts=yes ;;
 401         solaris2.8|solaris2.9|solaris2.10)      gai_ts=yes ;;
 402     esac
 403     AC_MSG_RESULT($gai_ts)
 404     if test $gai_ts = yes ; then
 405         AC_DEFINE(GETADDRINFO_ASYNCSAFE, 1, [define to 1 if you know your getaddrinfo function is async-signal-safe])
 406     fi
 407 fi
 408
 409 # This version of the Kerberos 5 options addresses the follwing issues:
 410 #
 411 # * Build correctly under Heimdal kerberos if it is compiled with db2 and
 412 #   OpenSSL support (Debian's is)
 413
 414 ###    use option --with-kerberos5=DIR to point at a Kerberos 5 directory
 415 ### make sure --with-ssl is run before --with-kerberos* !
 416 AC_ARG_WITH(kerberos5,
 417        [  --with-kerberos5=DIR    point fetchmail compilation at a Kerberos 5 directory],
 418 [
 419 if test "$with_kerberos5" != "no"
 420 then
 421 # Check for a OpenBSD special case
 422 if test "$with_kerberos5" = "yes" && ( test `uname` = "OpenBSD" )
 423 then
 424   AS_MESSAGE(checking kerberosV for OpenBSD...)
 425   AC_DEFINE(HEIMDAL,1,Define if you have HEIMDAL kerberos 5)
 426   AC_DEFINE(KERBEROS_V5,1,Define if you have Kerberos V5)
 427   CFLAGS="$CFLAGS -I/usr/include/kerberosV"
 428   LIBS="$LIBS -lasn1 -lkrb5 -lcom_err -lkafs"
 429 elif krb5-config 2> /dev/null >/dev/null ; then
 430   krb5_prefix=`krb5-config --prefix krb5`
 431   AC_MSG_RESULT([krb5-config points to kerberosV under $krb5_prefix])
 432   if test -f ${krb5_prefix}/include/et/com_err.h && \
 433    ! test -f ${krb5_prefix}/include/com_err.h  ; then
 434     CFLAGS="$CFLAGS -I${krb5_prefix}/include/et"
 435   fi
 436   unset krb5_prefix
 437   CFLAGS="$CFLAGS `krb5-config --cflags krb5`"
 438   LIBS="$LIBS `krb5-config --libs krb5`"
 439   AC_DEFINE(KERBEROS_V5)
 440 else
 441   if test "$with_kerberos5" != "yes"
 442   then
 443       LDFLAGS="$LDFLAGS -L${with_kerberos5}/lib"
 444       searchdirs="$with_kerberos5"
 445   else
 446       searchdirs="/usr/kerberos /usr/local/krb5 /usr/athena /usr"
 447   fi
 448   with_kerberos5=
 449   for dir in $searchdirs
 450   do AC_MSG_CHECKING([for Kerberos V in $dir])
 451      if test -f "$dir/include/krb5.h" || test -f "$dir/include/krb5/krb5.h"
 452      then
 453         if test -d "$dir/include/krb5" ; then CPPFLAGS="$CPPFLAGS -I$dir/include/krb5" ; fi
 454         ac_krblibs=
 455         if test -f "$dir/include/roken.h" || test -f "$dir/include/krb5/roken.h"
 456         then
 457            ac_krblibs="-lasn1 -lroken -lcom_err"
 458            AC_MSG_RESULT([Heimdal found])
 459           dnl Attempt to detect if we need to -ldb2 to link Heimdal
 460           dnl we assume we do if it is available
 461            AC_CHECK_LIB(db2, db_open, ac_krblibs="$ac_krblibs -ldb2", [],
 462                 ${LDFLAGS})
 463            AC_CHECK_LIB(des, des_string_to_key, libk5crypto=-ldes,
 464               AC_CHECK_LIB(crypto, MD5_Init, [],
 465                 AC_MSG_ERROR([DES libraries not found. Try adding --with-ssl to enable OpenSSL support]),
 466                 ${LDFLAGS} ${ac_krblibs}),
 467            ${LDFLAGS} ${ac_krblibs})
 468            AC_DEFINE(HEIMDAL)
 469         else
 470           AC_MSG_RESULT([found])
 471           ac_krblibs="-lcom_err"
 472            AC_CHECK_LIB(crypto,
 473              krb5_des_string_to_key,
 474              libk5crypto=-lcrypto,
 475                 AC_CHECK_LIB(k5crypto,
 476                    krb5_des_string_to_key,
 477                    libk5crypto=-lk5crypto,
 478                       AC_MSG_ERROR([Kerberos 5 DES libraries not found]),
 479                    ${LDFLAGS} ${ac_krblibs}),
 480                  ${LDFLAGS} ${ac_krblibs})
 481         fi
 482         AC_CHECK_LIB(krb5, krb5_init_context,[],
 483            continue,
 484            ${LDFLAGS} ${ac_krblibs})
 485         AC_DEFINE(KERBEROS_V5)
 486         test "$dir" != "/usr" && CFLAGS="$CFLAGS -I$dir/include"
 487         LDFLAGS="$LDFLAGS -L$dir/lib"
 488        LIBS="$LIBS $ac_krblibs $libk5crypto"
 489         with_kerberos5=$dir
 490         break
 491      else
 492         AC_MSG_RESULT([not found])
 493      fi
 494   done
 495   if test -z "$with_kerberos5" ; then
 496      AC_MSG_ERROR([Kerberos 5 libraries not found])
 497   fi
 498 fi
 499 fi
 500 ]) dnl --with-kerberos5=DIR
 501
 502 ###     use option --with-ssl to compile in the SSL support
 503 AC_ARG_WITH(ssl,
 504         [  --with-ssl=[DIR]        enable SSL support using libraries in DIR],
 505         [with_ssl=$withval],
 506         [with_ssl=yes])
 507 test "$with_ssl" != "no" && AC_DEFINE(SSL_ENABLE,1,Define if you want SSL support compiled in)
 508
 509 if test "$with_ssl" = "yes"
 510 then
 511     #   User didn't specify an SSL location.  Let's look at some common
 512     #   directories where SSL has been found in the past and try and auto
 513     #   configure for SSL.  OpenSSL determination will be made later.
 514     #   This will screw up if an OpenSSL install is located in a later
 515     #   directory than an older SSLeay install, but the user should fix that
 516     #   anyways and he can override on the configure line.
 517     #   Just testing for directories is not sufficient, /usr exists on
 518     #   all systems!
 519     for ac_dir in \
 520       /usr/local/ssl \
 521       /usr/local \
 522       /usr/ssl \
 523       /usr \
 524       /local/ssl \
 525       /opt/ssl \
 526       /opt/csw \
 527       ; \
 528     do
 529         if test -r "$ac_dir/include/openssl/ssl.h" ; then
 530             with_ssl=$ac_dir
 531             break;
 532         fi
 533     done
 534 fi
 535
 536 if test -n "$with_ssl" -a "$with_ssl" != "no"
 537 then
 538   # With the autoconfigure above, the only time this is going to be
 539   # true is going to be when we could not find the headers.  If they
 540   # are not in system standard locations, we are going to be broken.
 541   if test "$with_ssl" = "yes"
 542   then
 543     # Let's just define the standard location for the SSLeay root
 544     with_ssl="/usr/local/ssl"
 545   fi
 546   if test -r $with_ssl/include/openssl/ssl.h
 547   then
 548     ### ssl.h found under openssl.  Use openssl configuration preferentially,
 549     AC_MSG_NOTICE(Enabling OpenSSL support in $with_ssl.)
 550     test "$with_ssl" != "/usr" && CFLAGS="$CFLAGS -I$with_ssl/include"
 551     ### In Red Hat 9, this file includes a reference to <krb5.h>, so we
 552     ### force the Kerberos direcory onto the include path so it will build.
 553     CFLAGS="$CFLAGS -I/usr/kerberos/include"
 554     ### OpenBSD comes with ssl headers
 555   else
 556     AC_MSG_ERROR([SSL support enabled, but OpenSSL not found])
 557   fi
 558   LDFLAGS="$LDFLAGS -L$with_ssl/lib"
 559   LIBS="$LIBS -lssl -lcrypto"
 560   dnl check if -ldl is needed
 561   AC_MSG_CHECKING([for additional library dependencies of SSL])
 562   found=0
 563   save_LIBS="$LIBS"
 564   for i in "" "-ldl" ; do
 565       LIBS="$LDFLAGS $save_LIBS $i"
 566       AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <openssl/ssl.h>],[SSL_library_init()])],[found=1; break])
 567   done
 568   if test $found = 0 ; then
 569       AC_MSG_RESULT([error])
 570       AC_MSG_ERROR([cannot link with SSL - check config.log])
 571   fi
 572   LIBS="$save_LIBS $i"
 573   if test "$i" = "" ; then i="(none)" ; fi
 574   AC_MSG_RESULT($i)
 575   dnl XXX FIXME: use pkg-config if available!
 576   AC_DEFINE(SSL_ENABLE)
 577 else
 578   AC_MSG_WARN(Disabling SSL support.)
 579   AC_MSG_WARN(Consider re-running configure --with-ssl.)
 580 fi
 581
 582 case "$LIBS" in *-lssl*)
 583         AC_CHECK_DECLS([SSLv2_client_method],,,[#include <openssl/ssl.h>])
 584         ;;
 585 esac
 586
 587 ###     use option --with-socks=DIR to point at SOCKS library
 588 AC_ARG_WITH(socks,
 589         [  --with-socks[=DIR]      add built-in SOCKS firewall access],
 590 [
 591 if test "$with_socks" != no
 592 then
 593     if test "$with_socks" != yes
 594     then
 595         LDFLAGS="$LDFLAGS -L$with_socks"
 596     else
 597         AC_CHECK_LIB(socks, Rconnect,,
 598                AC_MSG_ERROR([could not find libsocks which is needed for built-in SOCKS support]))
 599     fi
 600     AC_DEFINE(HAVE_SOCKS,1,Define if you want built-in SOCKS support)
 601     CFLAGS="$CFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 602     LIBS="-lsocks $LIBS"
 603 fi])
 604
 605 ###     use option --with-socks5=DIR to point at SOCKS library
 606 AC_ARG_WITH(socks5,
 607         [  --with-socks5[=DIR]     add built-in SOCKS5 firewall access],
 608 [
 609 if test "$with_socks5" != no
 610 then
 611   if test "$with_socks5" != yes
 612   then
 613     LDFLAGS="$LDFLAGS -L$with_socks5"
 614   fi
 615   ac_savedLDFLAGS="$LDFLAGS"
 616   LDFLAGS="$LDFLAGS $LDFLAGS"
 617   AC_CHECK_LIB(socks5, SOCKSconnect,,
 618         AC_MSG_ERROR([could not find libsocks5 which is needed for built-in SOCKS5 support]))
 619   AC_DEFINE(HAVE_SOCKS)
 620   CFLAGS="$CFLAGS -Dconnect=SOCKSconnect -Dgetsockname=SOCKSgetsockname -Dbind=SOCKSbind -Daccept=SOCKSaccept -Dlisten=SOCKSlisten -Dselect=SOCKSselect -Drecvfrom=SOCKSrecvfrom -Dsendto=SOCKSsendto -Drecv=SOCKSrecv -Dsend=SOCKSsend -Dread=SOCKSread -Dwrite=SOCKSwrite -Drresvport=SOCKSrresvport -Dshutdown=SOCKSshutdown -Dlisten=SOCKSlisten -Dclose=SOCKSclose -Ddup=SOCKSdup -Ddup2=SOCKSdup2 -Dgethostbyname=SOCKSgethostbyname"
 621   AC_CHECK_FUNC(SOCKSfclose, [CFLAGS="$CFLAGS -Dfclose=SOCKSfclose"])
 622   LDFLAGS="$ac_savedLDFLAGS"
 623 fi])
 624
 625 dnl for libesmtp/ modules:
 626 ACX_WHICH_GETHOSTBYNAME_R
 627
 628 ###     use option --with-hesiod=DIR to point at a HESIOD directory
 629 AC_ma_SEARCH_PACKAGE(hesiod, hesiod_getmailhost, /usr/athena /usr /usr/local,hesiod, hesiod.h)
 630
 631 ###     use option --with-gssapi=DIR to compile in GSSAPI support
 632 AC_ARG_WITH(gssapi,
 633         [  --with-gssapi[=DIR]     compile in GSSAPI support using libraries in DIR],
 634 [
 635 if test "$with_gssapi" != "no"
 636 then
 637   if test "$with_gssapi" = "yes" -a -n "$with_kerberos5"
 638   then
 639     with_gssapi=$with_kerberos5
 640   fi
 641
 642   if test "$with_gssapi" != "yes" -a -n "$with_gssapi"
 643   then
 644     CFLAGS="$CFLAGS -I$with_gssapi/include"
 645     LDFLAGS="$LDFLAGS -L$with_gssapi/lib"
 646   fi
 647
 648   dnl obtain gssapi default libs
 649   if krb5-config --libs gssapi 2>/dev/null >/dev/null ; then
 650       LIBS="$LIBS `krb5-config --libs gssapi`"
 651   else
 652     AC_CHECK_LIB(gss, gss_check_version, LIBS="$LIBS -lgss", nogss=t)
 653     if test -n "$nogss"
 654     then
 655       # -lgss not found
 656       if test "$with_gssapi" = yes ; then
 657           with_gssapi=/usr
 658       fi
 659       if test -f "$with_gssapi/include/roken.h" -o -f "$with_gssapi/include/krb5/roken.h"
 660       then
 661          # have roken.h, assume Heimdal
 662          case `uname` in
 663              NetBSD) LIBS="$LIBS -lkrb5" ;;
 664              *)      LIBS="$LIBS -lkrb5 -lasn1 -ldes -lroken -ldb -ldl" ;;
 665          esac
 666          AC_CHECK_LIB(gssapi, gss_init_sec_context,LIBS="$LIBS -lgssapi",
 667                       AC_MSG_ERROR([could not find libgssapi which is needed for GSSAPI support]), )
 668          AC_DEFINE(HEIMDAL)
 669       else
 670          # no roken.h, assume MIT
 671          AC_CHECK_LIB(gssapi_krb5, gss_init_sec_context,LIBS="$LIBS -lgssapi_krb5",
 672                       AC_MSG_ERROR([could not find libgssapi_krb5 which is needed for GSSAPI support]), -lkrb5)
 673       fi
 674     fi
 675   fi
 676   AC_DEFINE(GSSAPI,1,Define if you want GSSAPI authentication)
 677   if test "$with_gssapi" != yes ; then
 678     CPPFLAGS="$CPPFLAGS -I$with_gssapi/include"
 679   fi
 680   AC_CHECK_HEADERS(gss.h gssapi.h gssapi/gssapi.h gssapi/gssapi_generic.h)
 681   AC_CHECK_DECLS(GSS_C_NT_HOSTBASED_SERVICE,,,[
 682     AC_INCLUDES_DEFAULT
 683     #if HAVE_GSS_H
 684     #include <gss.h>
 685     #endif
 686     #if HAVE_GSSAPI_GSSAPI_H
 687     #include <gssapi/gssapi.h>
 688     #elif HAVE_GSSAPI_H
 689     #include <gssapi.h>
 690     #endif
 691     #if HAVE_GSSAPI_GSSAPI_GENERIC_H
 692     #include <gssapi/gssapi_generic.h>
 693     #endif
 694     ])
 695 fi])
 696
 697 AC_CONFIG_FILES([Makefile po/Makefile.in genlsm.sh])
 698 AC_OUTPUT
 699
 700 dnl Local Variables:
 701 dnl comment-start: "dnl "
 702 dnl comment-end: ""
 703 dnl comment-start-skip: "\\bdnl\\b\\s *"
 704 dnl compile-command: "make configure config.h.in"
 705 dnl End: