Pileus Git - grits/blob - configure.ac

   1 m4_define([grits_release], [0.8])
   2 m4_define([grits_version], [5:0:0])
   3 m4_define([grits_subdir],  [grits5])
   4
   5 # Init and options
   6 AC_INIT([grits], [grits_release], [andy753421@gmail.com])
   7 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability foreign])
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_MACRO_DIR([m4])
  10 #AM_SILENT_RULES([yes])
  11
  12 # For library versioning
  13 LIB_VERSION=grits_version
  14 GRITS_SUBDIR=grits_subdir
  15 AC_SUBST(LIB_VERSION)
  16 AC_SUBST(GRITS_SUBDIR)
  17
  18 # Fix broken libtool
  19 lt_cv_sys_lib_dlsearch_path_spec="/lib /lib32 /lib64 /usr/lib /usr/lib32 /usr/lib64"
  20
  21 # Check for required programs
  22 AC_PROG_CC
  23 AC_PROG_LIBTOOL
  24 DOLT
  25 PKG_PROG_PKG_CONFIG
  26 GTK_DOC_CHECK(1.9)
  27
  28 # Check for required packages
  29 PKG_CHECK_MODULES(GLIB,  glib-2.0 >= 2.32 gobject-2.0 gthread-2.0 gmodule-2.0)
  30 PKG_CHECK_MODULES(CAIRO, cairo)
  31 PKG_CHECK_MODULES(SOUP,  libsoup-2.4 >= 2.26)
  32
  33 # Check for gtk 3
  34 AC_ARG_ENABLE([gtk3],
  35         AS_HELP_STRING([--enable-gtk3], [Build with gtk3 support]))
  36 AS_IF([test "$enable_gtk3" = "yes"],
  37         [PKG_CHECK_MODULES(GTK, gtk+-3.0 >= 3.0)],
  38         [PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.18)])
  39 AS_IF([test "$enable_gtk3" = "yes"],
  40         [GTK_VERSION=gtk+-3.0],
  41         [GTK_VERSION=gtk+-2.0])
  42 AC_SUBST(GTK_VERSION)
  43
  44 # Test for windowing system
  45 case "${host}" in
  46         *mingw32*) SYS="WIN" ;;
  47         *cygwin*)  SYS="WIN" ;;
  48         *apple*)   SYS="MAC" ;;
  49         *)         SYS="X11" ;;
  50 esac
  51 AM_CONDITIONAL([SYS_WIN], test "$SYS" = "WIN")
  52 AM_CONDITIONAL([SYS_MAC], test "$SYS" = "MAC")
  53 AM_CONDITIONAL([SYS_X11], test "$SYS" = "X11")
  54
  55 # OpenGL flags
  56 GL_CFLAGS="-DSYS_$SYS"
  57 case "$SYS" in
  58         "WIN") GL_LIBS="-lglu32 -lopengl32" ;;
  59         "MAC") GL_LIBS="-framework OpenGL" ;;
  60         "X11") GL_LIBS="-lX11 -lGL -lGLU" ;;
  61 esac
  62 AC_SUBST([GL_CFLAGS])
  63 AC_SUBST([GL_LIBS])
  64
  65 # Check for relative build
  66 AC_ARG_ENABLE(relative, [AS_HELP_STRING([--enable-relative],
  67         [enable runtime search paths @<:@default=no@:>@])],
  68         [DOTS=".."; ac_default_prefix="/"])
  69 AC_SUBST([DOTS])
  70
  71 # Output
  72 AC_CONFIG_FILES([
  73         Makefile
  74         src/Makefile
  75         src/data/Makefile
  76         src/objects/Makefile
  77         src/plugins/Makefile
  78         src/grits.pc
  79         docs/Makefile
  80         docs/api/Makefile
  81 ])
  82 AC_OUTPUT