Pileus Git - grits/blob - configure.ac

   1 m4_define([grits_release], [0.6.2])
   2 m4_define([grits_version], [2:1:0])
   3 m4_define([grits_subdir],  [grits2])
   4
   5 # Init and options
   6 AC_INIT([grits], [grits_release], [andy753421@gmail.com])
   7 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability foreign])
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_MACRO_DIR([m4])
  10 #AM_SILENT_RULES([yes])
  11
  12 # For library versioning
  13 LIB_VERSION=grits_version
  14 GRITS_SUBDIR=grits_subdir
  15 AC_SUBST(LIB_VERSION)
  16 AC_SUBST(GRITS_SUBDIR)
  17
  18 # Fix broken libtool
  19 lt_cv_sys_lib_dlsearch_path_spec="/lib /lib32 /lib64 /usr/lib /usr/lib32 /usr/lib64"
  20
  21 # Check for required programs
  22 AC_PROG_CC
  23 AC_PROG_LIBTOOL
  24 DOLT
  25 PKG_PROG_PKG_CONFIG
  26 GTK_DOC_CHECK(1.9)
  27
  28 # Check for required packages
  29 PKG_CHECK_MODULES(GLIB,  glib-2.0 >= 2.14 gobject-2.0 gthread-2.0)
  30 PKG_CHECK_MODULES(CAIRO, cairo)
  31 PKG_CHECK_MODULES(GTK,   gtk+-2.0 >= 2.16)
  32 PKG_CHECK_MODULES(SOUP,  libsoup-2.4 >= 2.26)
  33
  34 # Check for glut for example plugin
  35 AC_CHECK_LIB(glut, glutSolidTeapot, GLUT_LIBS="-lglut")
  36 AM_CONDITIONAL(HAVE_GLUT, test "$GLUT_LIBS" != "")
  37 AC_SUBST(GLUT_LIBS)
  38
  39 # Test for Windows vs. Unix
  40 case "${host}" in
  41         *mingw32*) WIN32="yes" ;;
  42         *cygwin*)  WIN32="yes" ;;
  43         *)         WIN32="no"  ;;
  44 esac
  45 if test "$WIN32" = yes; then
  46         ac_default_prefix="/"
  47 fi
  48 AM_CONDITIONAL([WIN32],    test "$WIN32" = "yes")
  49 AM_CONDITIONAL([NOTWIN32], test "$WIN32" = "no")
  50
  51 # Configure GL flags
  52 if test "$WIN32" = yes; then
  53         GL_CFLAGS=""
  54         GL_LIBS="-lglu32 -lopengl32"
  55 else
  56         GL_CFLAGS=""
  57         GL_LIBS="-lGL -lGLU"
  58 fi
  59 AC_SUBST([GL_CFLAGS])
  60 AC_SUBST([GL_LIBS])
  61
  62 # Output
  63 AC_CONFIG_FILES([
  64         Makefile
  65         src/Makefile
  66         src/data/Makefile
  67         src/objects/Makefile
  68         src/plugins/Makefile
  69         src/grits.pc
  70         docs/Makefile
  71         docs/api/Makefile
  72 ])
  73 AC_OUTPUT