+
+
+##################################################
+# Checks for gdk-pixbuf
+##################################################
+
+AC_MSG_CHECKING(whether to build gmodulized gdk-pixbuf)
+
+AC_ARG_ENABLE(modules, [ --disable-modules disable dynamic module loading],[
+ if test x$withval = xyes; then
+ with_modules=yes
+ else
+ with_modules=no
+ fi
+])
+
+dynworks=false
+deps=
+if test x$with_modules = xno; then
+ AC_MSG_RESULT(no)
+else
+ AC_MSG_RESULT(yes)
+ AC_MSG_CHECKING(whether dynamic modules work)
+ ## for loop is to strip newline
+ tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-2.0`
+ for I in $tmp; do
+ dynworks=$I
+ done
+
+ dnl Now we check to see if our libtool supports shared lib deps
+ dnl (in a rather ugly way even)
+ if $dynworks; then
+ pixbuf_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
+ pixbuf_deplibs_check=`$pixbuf_libtool_config | \
+ grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
+ sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
+ if test "x$pixbuf_deplibs_check" = "xnone" || \
+ test "x$pixbuf_deplibs_check" = "xunknown" || \
+ test "x$pixbuf_deplibs_check" = "x"; then
+ dynworks=false
+ fi
+ fi
+
+ if $dynworks; then
+ AC_DEFINE(USE_GMODULE)
+ AC_MSG_RESULT(yes)
+ else
+ AC_MSG_RESULT(no)
+ fi
+fi
+
+dnl We allow people to disable image loaders explicitely, but if they don't we error
+dnl out so that people don't accidentally build without them.
+
+AC_ARG_WITH(libpng, [ --without-libpng disable PNG loader for gdk-pixbuf])
+AC_ARG_WITH(libjpeg, [ --without-libjpeg disable JPEG loader for gdk-pixbuf])
+AC_ARG_WITH(libtiff, [ --without-libtiff disable TIFF loader for gdk-pixbuf])
+
+dnl Test for libtiff
+ if test x$with_libtiff != xno && test -z "$LIBTIFF"; then
+ AC_CHECK_LIB(tiff, TIFFReadScanline,
+ [AC_CHECK_HEADER(tiffio.h,
+ TIFF='tiff'; LIBTIFF='-ltiff',
+ AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***))],
+ [AC_CHECK_LIB(tiff, TIFFWriteScanline,
+ [AC_CHECK_HEADER(tiffio.h,
+ TIFF='tiff'; LIBTIFF='-ltiff -ljpeg -lz',
+ AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***))],
+ [AC_CHECK_LIB(tiff34, TIFFFlushData,
+ [AC_CHECK_HEADER(tiffio.h,
+ TIFF='tiff'; LIBTIFF='-ltiff34 -ljpeg -lz',
+ AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***))],
+ AC_MSG_WARN(*** TIFF plug-in will not be built (TIFF library not found) ***), -ljpeg -lz -lm)], -ljpeg -lz -lm)], -lm)
+ fi
+
+ if test x$with_libtiff != xno && test -z "$LIBTIFF"; then
+ AC_MSG_ERROR([
+*** Checks for TIFF loader failed. You can build without it by passing
+*** --without-libtiff to configure but some programs using GTK+ may
+*** not work properly])
+ fi
+
+dnl Test for libjpeg
+ if test x$with_libjpeg != xno && test -z "$LIBJPEG"; then
+ AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
+ jpeg_ok=yes,
+ jpeg_ok=no
+ AC_MSG_WARN(*** JPEG loader will not be built (JPEG library not found) ***))
+ if test "$jpeg_ok" = yes; then
+ AC_MSG_CHECKING([for jpeglib.h])
+ AC_TRY_CPP(
+[#include <stdio.h>
+#undef PACKAGE
+#undef VERSION
+#undef HAVE_STDLIB_H
+#include <jpeglib.h>],
+ jpeg_ok=yes,
+ jpeg_ok=no)
+ AC_MSG_RESULT($jpeg_ok)
+ if test "$jpeg_ok" = yes; then
+ LIBJPEG='-ljpeg'
+ AC_CHECK_LIB(jpeg, jpeg_simple_progression,
+ AC_DEFINE(HAVE_PROGRESSIVE_JPEG),
+ AC_MSG_WARN(JPEG library does not support progressive saving.))
+ else
+ AC_MSG_WARN(*** JPEG loader will not be built (JPEG header file not found) ***)
+ fi
+ fi
+ fi
+
+ if test x$with_libjpeg != xno && test -z "$LIBJPEG"; then
+ AC_MSG_ERROR([
+*** Checks for JPEG loader failed. You can build without it by passing
+*** --without-libjpeg to configure but some programs using GTK+ may
+*** not work properly])
+ fi
+
+dnl Test for libpng
+ if test x$with_libpng != xno && test -z "$LIBPNG"; then
+ AC_MSG_CHECKING(for libpng12)
+ if $PKG_CONFIG --exists libpng12 ; then
+ AC_MSG_RESULT(yes)
+ PNG='png'
+ PNG_DEP_CFLAGS_PACKAGES=libpng12
+ LIBPNG=`$PKG_CONFIG --libs libpng12`
+ else
+ AC_MSG_RESULT(no)
+ AC_CHECK_LIB(png, png_read_info,
+ [AC_CHECK_HEADER(png.h,
+ png_ok=yes,
+ png_ok=no)],
+ AC_MSG_WARN(*** PNG loader will not be built (PNG library not found) ***), -lz -lm)
+ if test "$png_ok" = yes; then
+ AC_MSG_CHECKING([for png_structp in png.h])
+ AC_TRY_COMPILE([#include <png.h>],
+ [png_structp pp; png_infop info; png_colorp cmap; png_create_read_struct;],
+ png_ok=yes,
+ png_ok=no)
+ AC_MSG_RESULT($png_ok)
+ if test "$png_ok" = yes; then
+ PNG='png'; LIBPNG='-lpng -lz'
+ else
+ AC_MSG_WARN(*** PNG loader will not be built (PNG library is too old) ***)
+ fi
+ else
+ AC_MSG_WARN(*** PNG loader will not be built (PNG header file not found) ***)
+ fi
+ fi
+ fi
+
+ if test x$with_libpng != xno && test -z "$LIBPNG"; then
+ AC_MSG_ERROR([
+*** Checks for PNG loader failed. You can build without it by passing
+*** --without-libpng to configure but many programs using GTK+ will
+*** not work properly. The PNG loader is also needed if you are compiling
+*** from CVS.])
+ fi
+
+AC_SUBST(LIBTIFF)
+AC_SUBST(LIBJPEG)
+AC_SUBST(LIBPNG)
+
+AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
+
+#
+# Allow building some or all gdk-pixbuf loaders included
+#
+AC_MSG_CHECKING(pixbuf loaders to build)
+
+AC_ARG_WITH(included_loaders, [ --with-included-loaders=LOADER1,LOADER2,... build the specified loaders into gdk-pixbuf (only used if module loading disabled)])
+
+if $dynworks; then
+ :
+else
+ ## if the option was specified, leave it; otherwise disable included loaders
+ if test x$with_included_loaders = xno; then
+ with_included_loaders=yes
+ fi
+fi
+
+all_loaders="png,bmp,wbmp,gif,ico,jpeg,pnm,ras,tiff,xpm,tga"
+included_loaders=""
+# If no loaders specified, include all
+if test "x$with_included_loaders" = xyes ; then
+ included_loaders="$all_loaders"
+else
+ included_loaders="$with_included_loaders"
+fi
+
+AC_MSG_RESULT($included_loaders)
+
+INCLUDED_LOADER_OBJ=
+INCLUDED_LOADER_DEFINE=
+
+IFS="${IFS= }"; gtk_save_ifs="$IFS"; IFS=","
+for loader in $included_loaders; do
+ if echo "$all_loaders" | grep "\(^\|\,\)$loader\(\$\|\,\)" > /dev/null; then
+ :
+ else
+ AC_MSG_ERROR([the specified loader $loader does not exist])
+ fi
+
+ INCLUDED_LOADER_OBJ="$INCLUDED_LOADER_OBJ libpixbufloader-static-$loader.la"
+ INCLUDED_LOADER_DEFINE="$INCLUDED_LOADER_DEFINE -DINCLUDE_$loader"
+done
+IFS="$gtk_save_ifs"
+AC_SUBST(INCLUDED_LOADER_OBJ)
+AC_SUBST(INCLUDED_LOADER_DEFINE)
+
+AC_HEADER_SYS_WAIT
+
+AC_TYPE_SIGNAL
+
+AM_CONDITIONAL(HAVE_TIFF, test "x$LIBTIFF" != x)
+AM_CONDITIONAL(HAVE_PNG, test "x$LIBPNG" != x)
+AM_CONDITIONAL(HAVE_JPEG, test "x$LIBJPEG" != x)
+
+if $dynworks ; then
+ STATIC_LIB_DEPS=
+ if echo "$included_loaders" | grep "\(^\|\,\)tiff\(\$\|\,\)" > /dev/null; then
+ STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBTIFF"
+ fi
+ if echo "$included_loaders" | grep "\(^\|\,\)jpeg\(\$\|\,\)" > /dev/null; then
+ STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBJPEG"
+ fi
+ if echo "$included_loaders" | grep "\(^\|\,\)png\(\$\|\,\)" > /dev/null; then
+ STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBPNG"
+ fi
+else
+ STATIC_LIB_DEPS="$LIBTIFF $LIBJPEG $LIBPNG"
+fi
+
+# Checks to see if we should compile in MMX support (there will be
+# a runtime test when the code is actually run to see if it should
+# be used - this just checks if we can compile it.)
+#
+# This code is partially taken from Mesa
+#
+AC_MSG_CHECKING(for x86 platform)
+case $host_cpu in
+ i386|i486|i586|i686|i786|k6|k7)
+ use_x86_asm=yes
+ ;;
+ *)
+ use_x86_asm=no
+esac
+AC_MSG_RESULT($use_x86_asm)
+
+use_mmx_asm=no
+if test $use_x86_asm = yes; then
+ save_ac_ext=$ac_ext
+ ac_ext=S
+
+ AC_MSG_CHECKING(compiler support for MMX)
+ cp $srcdir/gdk-pixbuf/pixops/scale_line_22_33_mmx.S conftest.S
+ if AC_TRY_EVAL(ac_compile); then
+ use_mmx_asm=yes
+ fi
+
+ rm -rf conftest*
+
+ ac_ext=$save_ac_ext
+ if test $use_mmx_asm = yes; then
+ AC_DEFINE(USE_MMX)
+ AC_MSG_RESULT(yes)
+ else
+ AC_MSG_RESULT(no)
+ fi
+fi
+
+AM_CONDITIONAL(USE_MMX, test x$use_mmx_asm = xyes)
+
+
+GDK_PIXBUF_PACKAGES="gmodule-2.0 gobject-2.0"
+GDK_PIXBUF_EXTRA_LIBS="$STATIC_LIB_DEPS $MATH_LIB"
+GDK_PIXBUF_EXTRA_CFLAGS=
+GDK_PIXBUF_DEP_LIBS="`$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES` $GDK_PIXBUF_EXTRA_LIBS"
+GDK_PIXBUF_DEP_CFLAGS="`$PKG_CONFIG --cflags gthread-2.0 $GDK_PIXBUF_PACKAGES $PNG_DEP_CFLAGS_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS"
+
+AC_SUBST(GDK_PIXBUF_PACKAGES)
+AC_SUBST(GDK_PIXBUF_EXTRA_LIBS)
+AC_SUBST(GDK_PIXBUF_EXTRA_CFLAGS)
+AC_SUBST(GDK_PIXBUF_DEP_LIBS)
+AC_SUBST(GDK_PIXBUF_DEP_CFLAGS)
+
+
+########################################
+# Windowing system checks
+########################################
+
+GDK_EXTRA_LIBS=$GDK_WLIBS
+GDK_EXTRA_CFLAGS=
+
+FREETYPE_LIBS=
+FREETYPE_CFLAGS=
+if test "x$gdktarget" = "xlinux-fb" || test "x$gdktarget" = "xx11" ; then
+ #
+ # Checks for FreeType
+ #
+ have_freetype=false
+ AC_PATH_PROG(FREETYPE_CONFIG, freetype-config, no)
+ if test "x$FREETYPE_CONFIG" != "xno" ; then
+ FREETYPE_CFLAGS=`$FREETYPE_CONFIG --cflags`
+ FREETYPE_LIBS=`$FREETYPE_CONFIG --libs`
+
+ AC_CHECK_LIB(freetype, FT_New_Face, have_freetype=true
+ ,:,$FREETYPE_LIBS)
+
+ if $have_freetype ; then
+ gtk_save_cppflags="$CPPFLAGS"
+ CPPFLAGS="$CPPFLAGS $FREETYPE_CFLAGS"
+
+ AC_MSG_CHECKING([For sufficiently new FreeType (at least 2.0.1)])
+ AC_TRY_COMPILE([
+#include <freetype/freetype.h>
+#include FT_ERRORS_H
+ ],
+ [(void)1;],:,have_freetype=false)
+ if $have_freetype ; then
+ AC_MSG_RESULT(yes)
+ else
+ AC_MSG_RESULT(no)
+ fi
+
+ CPPFLAGS="$gtk_save_cppflags"
+ fi
+ fi
+ AC_SUBST(FREETYPE_LIBS)
+ AC_SUBST(FREETYPE_CFLAGS)
+fi
+
+if test "x$gdktarget" = "xx11"; then
+ # We start off with the libraries from Pango
+
+ if $PKG_CONFIG --exists pangox ; then : ; else
+ AC_MSG_ERROR([pangox Pango backend is required for x11 target])
+ fi
+
+ ## be sure we also have Pango built with xft support
+ if $PKG_CONFIG --exists pangoxft ; then
+ PANGO_PACKAGES="pangox pangoxft"
+ have_xft=true
+ AC_DEFINE(HAVE_XFT)
+ if $have_freetype ; then
+ :
+ else
+ AC_MSG_ERROR([pangoxft Pango backend found but did not find freetype libraries])
+ fi
+ else
+ PANGO_PACKAGES="pangox"
+ have_xft=false
+ fi
+
+ AM_CONDITIONAL(HAVE_XFT, $have_xft)
+
+ #
+ # If Pango included the shared library dependencies from X11 in
+ # the pkg-config output, then we use that (to avoid duplicates).
+ # but if they were omitted to avoid binary compatibility problems
+ # then we need to repeat the checks.
+ #
+ x_libs="`$PKG_CONFIG --libs $PANGO_PACKAGES`"
+ case x_libs in
+ *-lX11*) pango_omitted_x_deps=no ;;
+ *) pango_omitted_x_deps=yes ;;
+ esac
+
+ x_cflags="`$PKG_CONFIG --cflags $PANGO_PACKAGES`"
+ x_extra_libs=
+
+ if test $pango_omitted_x_deps = yes ; then
+ AC_PATH_XTRA
+
+ if test x$no_x = xyes ; then
+ AC_MSG_ERROR([X development libraries not found])
+ fi
+
+ x_libs="$X_LIBS -lX11 $X_EXTRA_LIBS"
+
+ #
+ # Checks for Xft/XRender
+ #
+ XFT_LIBS=""
+ XFT_CFLAGS=""
+ if test $have_xft = true ; then
+ gtk_save_cppflags="$CPPFLAGS"
+ CPPFLAGS="$CPPFLAGS $x_cflags"
+ have_xft=false
+
+ AC_CHECK_LIB(Xrender, XRenderFindFormat,
+ [AC_CHECK_LIB(Xft, XftFontOpen,
+ [AC_CHECK_HEADER(X11/Xft/XftFreetype.h,
+ have_xft=true,:)],
+ :,-lXrender -lXext $x_libs $FREETYPE_LIBS)]
+ ,:,-lXext $x_libs)
+
+ CPPFLAGS="$gtk_save_cppflags"
+
+ if $have_xft ; then
+ x_libs="$X_LIBS -lXft -lXrender -lXext -lX11 $FREETYPE_LIBS $X_EXTRA_LIBS"
+ else
+ AC_MSG_ERROR([pangoxft Pango backend found, but Xft not found])
+ fi
+ fi
+ fi
+
+ ## Strip the .la files
+
+ x_libs_for_checks=""
+ for I in $x_libs ; do
+ case $I in
+ *.la) ;;
+ *) x_libs_for_checks="$x_libs_for_checks $I" ;;
+ esac
+ done
+
+ # Sanity check for the X11 library
+ AC_CHECK_LIB(X11, XOpenDisplay, :,
+ AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]),
+ $x_libs_for_checks)
+
+ if test "x$enable_shm" = "xyes"; then
+ # Check for the Xext library (needed for XShm extention)
+ AC_CHECK_LIB(Xext, XShmAttach,
+ if test -z "`echo $x_libs | grep "\-lXext" 2> /dev/null`"; then
+ x_extra_libs="-lXext"
+ fi,
+ # On AIX, it is in XextSam instead, but we still need -lXext
+ AC_CHECK_LIB(XextSam, XShmAttach,
+ if test -z "`echo $x_libs | grep "\-lXext" 2> /dev/null`"; then
+ x_extra_libs="-lXextSam -lXext"
+ else
+ x_extra_libs="-lXextSam"
+ fi, , $x_libs_for_checks),
+ $x_libs_for_checks)
+ fi
+
+ GDK_PIXBUF_XLIB_EXTRA_CFLAGS="$x_cflags"
+ # Don't ever pull in the pangoxft libraries for gdk-pixbuf-x11
+ GDK_PIXBUF_XLIB_EXTRA_LIBS="$x_extra_libs `$PKG_CONFIG --libs pangox`"
+
+ # Check for shaped window extension
+
+ AC_CHECK_LIB(Xext, XShapeCombineMask,
+ if test -z "`echo $x_extra_libs $x_libs | grep "\-lXext" 2> /dev/null`"; then
+ x_extra_libs="-lXext $x_extra_libs"
+ fi
+ AC_DEFINE(HAVE_SHAPE_EXT),
+ ,
+ $x_libs_for_checks)
+
+ # Check for XConvertCase (X11R6 specific)
+
+ AC_CHECK_LIB(X11, XConvertCase,
+ AC_DEFINE(HAVE_XCONVERTCASE),
+ ,
+ $x_libs_for_checks)
+
+ # Check for XIM support.
+
+ AC_CHECK_LIB(X11, XUnregisterIMInstantiateCallback,
+ : ,
+ enable_xim_inst="no",
+ $x_libs_for_checks)
+
+ # On Solaris, calling XRegisterIMInstantiateCallback seems to
+ # cause an immediate segfault, so we disable it, unless
+ # the user specifically forces it to be on.
+
+ if test x$enable_xim_inst = xmaybe ; then
+ case host in
+ *-*-solaris*)
+ enable_xim_inst="no"
+ ;;
+ *)
+ enable_xim_inst="yes"
+ ;;
+ esac
+ fi
+
+ if test "x$enable_xim" = "xyes"; then
+ GTK_XIM_FLAGS="-DUSE_XIM"
+ if test "x$enable_xim_inst" = "xyes"; then
+ AC_DEFINE(USE_X11R6_XIM)
+ fi
+ fi
+
+ # Check for XKB support.
+
+ if test "x$enable_xkb" = "xyes"; then
+ AC_MSG_WARN(XKB support explicitly enabled)
+ AC_DEFINE(HAVE_XKB)
+ elif test "x$enable_xkb" = "xmaybe"; then
+ AC_CHECK_LIB(X11, XkbQueryExtension,
+ AC_DEFINE(HAVE_XKB),
+ ,
+ $x_libs_for_checks)
+ else
+ AC_MSG_WARN(XKB support explicitly disabled)
+ fi
+
+ x_cflags="$X_CFLAGS"
+ x_ldflags="$X_LDFLAGS"
+
+ # set up things for XInput
+
+ if test "x$with_xinput" = "xxfree" || test "x$with_xinput" = "xyes"; then
+ AC_DEFINE(XINPUT_XFREE)
+ x_extra_libs="-lXi $x_extra_libs"
+ else
+ AC_DEFINE(XINPUT_NONE)
+ fi
+
+ AM_CONDITIONAL(XINPUT_XFREE, test x$with_xinput = xxfree)
+
+ if test "x$enable_shm" = "xyes"; then
+ # Check for shared memory
+ AC_CHECK_HEADER(sys/ipc.h, AC_DEFINE(HAVE_IPC_H), no_sys_ipc=yes)
+ AC_CHECK_HEADER(sys/shm.h, AC_DEFINE(HAVE_SHM_H), no_sys_shm=yes)
+
+ # Check for the X shared memory extension header file
+ have_xshm=no
+ AC_MSG_CHECKING(X11/extensions/XShm.h)
+ if test "x$no_xext_lib" = "xyes"; then
+ :
+ else
+ gtk_save_CFLAGS="$CFLAGS"
+ CFLAGS="$CFLAGS $x_cflags"
+ AC_TRY_COMPILE([
+#include <stdlib.h>
+#include <sys/types.h>
+#include <sys/ipc.h>
+#include <sys/shm.h>
+#include <X11/Xlib.h>
+#include <X11/Xutil.h>
+#include <X11/extensions/XShm.h>
+], [XShmSegmentInfo *x_shm_info;], have_xshm=yes)
+ CFLAGS="$gtk_save_CFLAGS"
+ fi
+ AC_MSG_RESULT($have_xshm)
+ if test $have_xshm = yes ; then
+ AC_DEFINE(HAVE_XSHM_H)
+ fi
+ fi
+
+ GDK_EXTRA_CFLAGS=
+ if test $pango_omitted_x_deps = yes ; then
+ GDK_EXTRA_LIBS="$x_extra_libs $x_libs $GDK_EXTRA_LIBS"
+ else
+ GDK_EXTRA_LIBS="$x_extra_libs $GDK_EXTRA_LIBS"
+ fi
+
+ AM_CONDITIONAL(USE_X11, true)
+else
+ AM_CONDITIONAL(USE_X11, false)
+fi
+
+if test "x$gdktarget" = "xwin32"; then
+ # We start off with the libraries from Pango
+
+ ## be sure we also have Pango built with win32 support
+ PANGO_PACKAGES="pangowin32"
+
+ if test x$have_wintab = xyes; then
+ GDK_WIN32_EXTRA_CFLAGS="-I $with_wintab/include"
+ AC_SUBST(GDK_WIN32_EXTRA_CFLAGS)
+ fi
+
+ GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -user32 -limm32 -lshell32 -lole32 -luuid"
+ AM_CONDITIONAL(USE_WIN32, true)
+else
+ AM_CONDITIONAL(USE_WIN32, false)
+fi
+
+AC_SUBST(xinput_progs)
+
+GDK_PIXBUF_XLIB_PACKAGES=
+GDK_PIXBUF_XLIB_DEP_LIBS="`$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $GDK_PIXBUF_XLIB_PACKAGES` $GDK_PIXBUF_XLIB_EXTRA_LIBS $GDK_PIXBUF_EXTRA_LIBS"
+GDK_PIXBUF_XLIB_DEP_CFLAGS="`$PKG_CONFIG --cflags gthread-2.0 $GDK_PIXBUF_PACKAGES $GDK_PIXBUF_XLIB_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_PIXBUF_XLIB_EXTRA_CFLAGS"
+
+AC_SUBST(GDK_PIXBUF_XLIB_PACKAGES)
+AC_SUBST(GDK_PIXBUF_XLIB_EXTRA_LIBS)
+AC_SUBST(GDK_PIXBUF_XLIB_EXTRA_CFLAGS)
+AC_SUBST(GDK_PIXBUF_XLIB_DEP_LIBS)
+AC_SUBST(GDK_PIXBUF_XLIB_DEP_CFLAGS)
+
+if test "x$gdktarget" = "xlinux-fb"; then
+ if $have_freetype ; then
+ :
+ else
+ AC_MSG_ERROR([Using linux-fb backend but freetype was not found])
+ fi
+
+ ft2_libs="`$PKG_CONFIG --libs pangoft2`"
+ case ft2_libs in
+ *-lfreetype*) pango_omitted_ft2_deps=no ;;
+ *) pango_omitted_ft2_deps=yes ;;
+ esac
+
+ CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
+
+ if test x$enable_shadowfb = xyes ; then
+ AC_DEFINE(ENABLE_SHADOW_FB)
+ fi
+
+ if test x$enable_fbmanager = xyes ; then
+ AC_DEFINE(ENABLE_FB_MANAGER)
+ AM_CONDITIONAL(ENABLE_FB_MANAGER, true)
+ else
+ AM_CONDITIONAL(ENABLE_FB_MANAGER, false)
+ fi
+
+ GDK_EXTRA_CFLAGS=""
+ if test $pango_omitted_ft2_deps = yes ; then
+ GDK_EXTRA_LIBS="$FREETYPE_LIBS $GDK_EXTRA_LIBS"
+ fi
+
+ AM_CONDITIONAL(USE_LINUX_FB, true)
+else
+ AM_CONDITIONAL(USE_LINUX_FB, false)
+ AM_CONDITIONAL(ENABLE_FB_MANAGER, false)
+fi
+
+#
+# Pick correct Pango packages to use
+#
+
+if test "x$gdktarget" = "xx11"; then
+ if $have_xft = true ; then
+ PANGO_PACKAGES="pangox pangoxft"
+ else
+ PANGO_PACKAGES=pangox
+ fi
+elif test "x$gdktarget" = "xwin32"; then
+ PANGO_PACKAGES=pangowin32
+elif test "x$gdktarget" = "xlinux-fb"; then
+ PANGO_PACKAGES=pangoft2
+else
+ PANGO_PACKAGES=pango
+fi
+
+# Check for Pango flags
+
+AC_MSG_CHECKING(Pango flags)
+if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
+ PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
+ PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
+
+ AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
+else
+ AC_MSG_ERROR([
+*** Pango not found. Pango is required to build GTK+.
+*** See http://www.pango.org for Pango information.
+*** For the framebuffer target, you will need to build
+*** Pango with freetype support.
+])
+fi
+
+CFLAGS="$CFLAGS $PANGO_CFLAGS"
+
+if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
+ :
+else
+ AC_CHECK_LIB(pango-1.0, pango_context_new, :, AC_MSG_ERROR([
+*** Can't link to Pango. Pango is required to build
+*** GTK+. For more information see http://www.pango.org]), $PANGO_LIBS)
+fi
+
+CFLAGS="$saved_cflags"
+LDFLAGS="$saved_ldflags"
+
+GDK_PACKAGES=$PANGO_PACKAGES
+GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $GDK_PACKAGES` $GDK_PIXBUF_EXTRA_LIBS"
+GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags gthread-2.0 $GDK_PIXBUF_PACKAGES $GDK_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_EXTRA_CFLAGS"
+
+#
+# If we aren't writing explicit dependencies, then don't put the extra libraries we need
+# into the pkg-config files
+#
+if test $enable_explicit_deps != yes ; then
+ GDK_EXTRA_LIBS=
+fi
+
+AC_SUBST(GDK_PACKAGES)
+AC_SUBST(GDK_EXTRA_LIBS)
+AC_SUBST(GDK_EXTRA_CFLAGS)
+AC_SUBST(GDK_DEP_LIBS)
+AC_SUBST(GDK_DEP_CFLAGS)
+
+
+########################################
+# Check for Accessibility Toolkit flags
+########################################
+
+ATK_PACKAGES=atk
+AC_MSG_CHECKING(ATK flags)
+if $PKG_CONFIG --exists $ATK_PACKAGES ; then
+ ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
+ ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
+
+ AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
+else
+ AC_MSG_ERROR([
+*** Accessibility Toolkit not found. Accessibility Toolkit is required
+*** to build GTK+.
+])
+fi
+
+if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
+ :
+else
+ AC_CHECK_LIB(atk-1.0, atk_object_get_type, : , AC_MSG_ERROR([
+ *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
+ *** to build GTK+]), $ATK_LIBS $GLIB_LIBS)
+fi
+
+GTK_PACKAGES=atk
+GTK_EXTRA_LIBS=
+GTK_EXTRA_CFLAGS=
+GTK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $GDK_PACKAGES $GTK_PACKAGES` $GTK_EXTRA_LIBS $GDK_PIXBUF_EXTRA_LIBS"
+GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags gthread-2.0 $GDK_PIXBUF_PACKAGES $GDK_PACKAGES $GTK_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
+
+AC_SUBST(GTK_PACKAGES)
+AC_SUBST(GTK_EXTRA_LIBS)
+AC_SUBST(GTK_EXTRA_CFLAGS)
+AC_SUBST(GTK_DEP_LIBS)
+AC_SUBST(GTK_DEP_CFLAGS)
+
+