Pileus Git - ~andy/sunrise/blob - x11-libs/pdcurses/pdcurses-3.4.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=2
   6
   7 inherit autotools eutils
   8
   9 MY_P=${P/pdc/PDC}
  10
  11 DESCRIPTION="A public domain curses library for DOS, OS/2, Win32, X11"
  12 HOMEPAGE="http://pdcurses.sourceforge.net/"
  13 SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
  14
  15 LICENSE="MIT public-domain"
  16 SLOT="0"
  17 KEYWORDS="~amd64 ~x86"
  18 # TODO: add SDL support
  19 IUSE="doc examples nextaw Xaw3d"
  20
  21 RDEPEND="Xaw3d? ( x11-libs/libXaw3d )
  22         !Xaw3d? (
  23                 nextaw? ( x11-libs/neXtaw )
  24                 !nextaw? ( x11-libs/libXaw )
  25         )"
  26 DEPEND="${RDEPEND}
  27         x11-proto/xproto"
  28
  29 S=${WORKDIR}/${MY_P}
  30
  31 pkg_setup() {
  32         if use nextaw && use Xaw3d ; then
  33                 elog "You have both nextaw and Xaw3d USE-flags set, Xaw3d will be used."
  34         fi
  35 }
  36
  37 src_prepare() {
  38         epatch "${FILESDIR}/${P}-configure.patch"
  39
  40         # Fixing soname problem
  41         sed -i -e "s/\(\$(LD_RXLIB1)\)/\1 -Wl,-soname,libXcurses.so.${PV%.*}/" \
  42                 x11/Makefile.in || die
  43
  44         # Fixing absolute symlinks
  45         sed -i -e 's:\(ln -f -s \)$(libdir)/:\1:' \
  46                 Makefile.in || die
  47
  48         # Fixing tuidemo path
  49         sed -i -e 's:\.\.[/\\]demos[/\\]::' \
  50                 demos/tuidemo.c || die
  51
  52         # If enabled, uses "manext" to create a 160K doc/PDCurses.txt
  53         if ! use doc ; then
  54                 sed -i -e '/cd doc; $(MAKE)/d' \
  55                         Makefile.in || die
  56         fi
  57
  58         # Removing the $(DEMOS) from all target
  59         if ! use examples ; then
  60                 sed -i -e 's/\(^all:[\t a-zA-Z$()]*\) $(DEMOS)/\1/' \
  61                         x11/Makefile.in || die
  62         fi
  63
  64         eautoreconf
  65 }
  66
  67 src_configure() {
  68         econf \
  69                 $(use_with nextaw) \
  70                 $(use_with Xaw3d xaw3d)
  71 }
  72
  73 src_install() {
  74         emake DESTDIR="${D}" install || die
  75         dodoc HISTORY IMPLEMNT README doc/*.txt || die
  76
  77         if use examples ; then
  78                 insinto /usr/share/doc/${PF}/examples
  79                 doins demos/*.[ch] || die
  80
  81                 exeinto /usr/share/doc/${PF}/examples
  82                 cd "${S}/x11" || die
  83                 # Which one is better?
  84                 #doins $(sed -e 's/^DEMOS[ \t]*=\(.*\)/\1/p' -e 'd' Makefile.in)
  85                 doexe $(sed -n -e 's/^DEMOS[ \t]*=\(.*\)/\1/p' Makefile.in) || die
  86         fi
  87 }