Pileus Git - ~andy/sunrise/blob - www-apps/flyspray/flyspray-0.9.9.6.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI="2"
   6
   7 # we need webapp's default pkg_setup()
   8 inherit eutils webapp
   9
  10 DESCRIPTION="An uncomplicated web-based bug tracking system"
  11 HOMEPAGE="http://flyspray.org/"
  12 SRC_URI="http://flyspray.org/${P}.zip"
  13
  14 LICENSE="LGPL-2.1"
  15 KEYWORDS="~amd64"
  16 IUSE="graphviz"
  17
  18 # need_apache and friends not used because they aren't EAPI="2" friendly
  19 DEPEND="app-arch/unzip"
  20 RDEPEND="graphviz? ( media-gfx/graphviz )
  21         virtual/httpd-php:5.3
  22         || ( =dev-lang/php-5.3*[mysql]
  23                 =dev-lang/php-5.3*[mysqli]
  24                 =dev-lang/php-5.3*[postgres] )
  25         dev-php/adodb"
  26
  27 src_prepare () {
  28         #http://bugs.flyspray.org/task/1617
  29         epatch "${FILESDIR}"/${P}-system-adodb.patch
  30
  31         mv htaccess.dist .htaccess || die
  32         touch ${PN}.conf.php || die
  33
  34         rm -r adodb || die "removing bundled dev-php/adodb"
  35 }
  36
  37 src_install () {
  38         webapp_src_preinst
  39
  40         dodoc docs/*.txt || die
  41         rm -r docs || die
  42
  43         insinto "${MY_HTDOCSDIR}"
  44         doins -r . || die
  45
  46         webapp_serverowned "${MY_HTDOCSDIR}"/{attachments,cache,${PN}.conf.php}
  47         webapp_configfile "${MY_HTDOCSDIR}"/{.htaccess,${PN}.conf.php}
  48
  49         webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
  50         webapp_src_install
  51 }