Pileus Git - ~andy/sunrise/blob - sys-fs/ntfs3g-ar/ntfs3g-ar-2010.10.2.3.ebuild

   1 # Copyright 1999-2011 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=2
   6 inherit linux-info versionator
   7
   8 MY_PN="${PN/3g-ar/-3g}"
   9 MY_PV="$(get_version_component_range 1-3)AR.$(get_version_component_range 4)"
  10 MY_P="${MY_PN}-${MY_PV}"
  11
  12 DESCRIPTION="NTFS-3G variant supporting ACLs, junction points, compression and more"
  13 HOMEPAGE="http://pagesperso-orange.fr/b.andre/advanced-ntfs-3g.html"
  14 SRC_URI="http://pagesperso-orange.fr/b.andre/${MY_P}.tgz"
  15
  16 LICENSE="GPL-2"
  17 SLOT="0"
  18 KEYWORDS="~amd64 ~x86"
  19 IUSE="acl debug external-fuse suid udev"
  20
  21 RDEPEND="external-fuse? ( >=sys-fs/fuse-2.8.0 )
  22         !sys-fs/ntfs3g
  23         sys-apps/attr"
  24 DEPEND="${RDEPEND}"
  25
  26 S="${WORKDIR}/${MY_P}"
  27
  28 pkg_setup() {
  29         if use external-fuse && use kernel_linux; then
  30                 if kernel_is lt 2 6 9; then
  31                         die "Your kernel is too old."
  32                 fi
  33                 CONFIG_CHECK="~FUSE_FS"
  34                 FUSE_FS_WARNING="You need to have FUSE module built to use ntfs-3g"
  35                 linux-info_pkg_setup
  36         fi
  37 }
  38
  39 src_configure() {
  40         econf \
  41                 --docdir="/usr/share/doc/${PF}" \
  42                 --enable-ldscript \
  43                 --disable-ldconfig \
  44                 --with-fuse=$(use external-fuse && echo external || echo internal) \
  45                 $(use_enable acl posix-acls) \
  46                 $(use_enable debug)
  47 }
  48
  49 src_install() {
  50         emake DESTDIR="${D}" install || die "install failed"
  51
  52         prepalldocs || die "prepalldocs failed"
  53         dodoc AUTHORS ChangeLog CREDITS || die "dodoc failed"
  54
  55         use suid && { fperms u+s "/bin/${MY_PN}" || die "set suid failed" ; }
  56
  57         if use udev; then
  58                 insinto /etc/udev/rules.d/
  59                 doins "${FILESDIR}/99-ntfs3g.rules" || die "udev rules install failed"
  60         fi
  61 }
  62
  63 pkg_postinst() {
  64         ewarn "This is an advanced features release of the ntfs-3g package. It"
  65         ewarn "passes standard tests on i386 and x86_64 CPUs but users should"
  66         ewarn "still backup their data.  More info at:"
  67         ewarn "http://pagesperso-orange.fr/b.andre/advanced-ntfs-3g.html"
  68
  69         if use suid; then
  70                 ewarn
  71                 ewarn "You have chosen to install ${PN} with the binary setuid root. This"
  72                 ewarn "means that if there any undetected vulnerabilities in the binary,"
  73                 ewarn "then local users may be able to gain root access on your machine."
  74         fi
  75 }