Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8 #include <string.h>
   9
  10 #include "config.h"
  11 #include "fetchmail.h"
  12 #include "rcfile_y.h"
  13
  14 int prc_lineno = 1;
  15
  16 #ifdef LEXDEBUG
  17 #define SETSTATE(n)     if (yydebug) do {BEGIN(n); fprintf(stderr, "Entering lexer state %d\n", n);} while (0)
  18 #else
  19 #define SETSTATE(n)     BEGIN(n)
  20 #endif /* LEXDEBUG */
  21 %}
  22
  23 /* this doesn't work with Linux lex, see the INSTALL file */
  24 %o 7000
  25 %a 4000
  26 %p 3000
  27
  28 %s NAME AUTH
  29
  30 %%
  31
  32 \"[^\"]*\"      {
  33                         char buf[MSGBUFSIZE];
  34
  35                         yytext[strlen(yytext)-1] = '\0';
  36                         escapes(yytext+1, buf);
  37                         yylval.sval = (char *) xstrdup(buf);
  38                         SETSTATE(0);
  39                         return STRING;
  40                 }
  41 \'[^\']*\'      {
  42                         char buf[MSGBUFSIZE];
  43
  44                         yytext[strlen(yytext)-1] = '\0';
  45                         escapes(yytext+1, buf);
  46                         yylval.sval = (char *) xstrdup(buf);
  47                         SETSTATE(0);
  48                         return STRING;
  49                 }
  50
  51 "*"             { BEGIN(0); return WILDCARD; }
  52
  53 <NAME>[^=;:, \t\r\n]+   {
  54                         char buf[MSGBUFSIZE];
  55
  56                         escapes(yytext, buf);
  57                         yylval.sval = (char *) xstrdup(buf);
  58                         SETSTATE(0);
  59                         return STRING;
  60                 }
  61
  62 set             { return SET; }
  63 logfile         { return LOGFILE; }
  64 idfile          { return IDFILE; }
  65 daemon          { return DAEMON; }
  66 syslog          { return SYSLOG; }
  67 invisible       { return INVISIBLE; }
  68 showdots        { return SHOWDOTS; }
  69 postmaster      { return POSTMASTER; }
  70 bouncemail      { return BOUNCEMAIL; }
  71 spambounce      { return SPAMBOUNCE; }
  72 warnings        { return WARNINGS; }
  73
  74 defaults        { return DEFAULTS; }
  75 server          { return POLL; }
  76 poll            { return POLL; }
  77 skip            { return SKIP; }
  78 via             { return VIA; }
  79 aka             { return AKA; }
  80 local(domains)  { return LOCALDOMAINS; }
  81 proto(col)?     { return PROTOCOL; }
  82 service         { return SERVICE; }
  83 port            { return PORT; }
  84 interval        { return INTERVAL; }
  85 preauth(enticate)?      { SETSTATE(AUTH); return AUTHENTICATE; }
  86 auth(enticate)? { SETSTATE(AUTH); return AUTHENTICATE; }
  87 any             { SETSTATE(0); return ANY; }
  88 gssapi          { SETSTATE(0); return GSSAPI; }
  89 kerberos(_v)?4  { SETSTATE(0); return KERBEROS4; }
  90 kerberos(_v)?5  { SETSTATE(0); return KERBEROS5; }
  91 kerberos        { SETSTATE(0); return KERBEROS; }
  92 ssh             { SETSTATE(0); return SSH; }
  93 <AUTH>password { SETSTATE(0); return PASSWORD; }
  94 timeout         { return TIMEOUT;}
  95 envelope        { return ENVELOPE; }
  96 qvirtual        { return QVIRTUAL; }
  97 principal       { return PRINCIPAL; }
  98
  99 user(name)?     {SETSTATE(NAME); return USERNAME; }
 100 pass(word)?     {SETSTATE(NAME); return PASSWORD; }
 101 folder(s)?      { return FOLDER; }
 102 smtp(host)?     { return SMTPHOST; }
 103 smtpaddress     { return SMTPADDRESS; }
 104 smtpname        { return SMTPNAME; }
 105 antispam        { return SPAMRESPONSE; }
 106 mda             { return MDA; }
 107 bsmtp           { return BSMTP; }
 108 lmtp            { return LMTP; }
 109 pre(connect)?   { return PRECONNECT; }
 110 post(connect)?  { return POSTCONNECT; }
 111 netsec          { return NETSEC; }
 112 interface       { return INTERFACE; }
 113 monitor         { return MONITOR; }
 114 plugin          { return PLUGIN; }
 115 plugout         { return PLUGOUT; }
 116 batchlimit      { return BATCHLIMIT; }
 117 fetchlimit      { return FETCHLIMIT; }
 118 expunge         { return EXPUNGE; }
 119 properties      { return PROPERTIES; }
 120
 121 is              { SETSTATE(NAME); return IS; }
 122 here            { return HERE; }
 123 there           { return THERE; }
 124 to              { SETSTATE(NAME); return TO; }
 125 =               { SETSTATE(NAME); return MAP; }
 126
 127 nobouncemail    |
 128 nouidl          |
 129 nocheckalias    |
 130 nodns           |
 131 noenvelope      |
 132 nokeep          |
 133 noflush         |
 134 nofetchall      |
 135 norewrite       |
 136 noforcecr       |
 137 nostripcr       |
 138 nopass8(bits)?  |
 139 nodropstatus    |
 140 nodropdelivered |
 141 nomimedec(ode)? |
 142 noidle          {
 143                    yyless(2);
 144                    return NO;
 145                 }
 146
 147 no              {return NO;}
 148
 149 keep            { return KEEP; }
 150 flush           { return FLUSH; }
 151 fetchall        { return FETCHALL; }
 152 rewrite         { return REWRITE; }
 153 forcecr         { return FORCECR; }
 154 stripcr         { return STRIPCR; }
 155 pass8(bits)?    { return PASS8BITS; }
 156 dropstatus      { return DROPSTATUS; }
 157 dropdelivered   { return DROPDELIVERED; }
 158 mimedec(ode)?   { return MIMEDECODE; }
 159 idle            { return IDLE; }
 160 dns             { return DNS; }
 161 uidl            { return UIDL; }
 162 ssl             { return SSL; }
 163 sslkey          { return SSLKEY; }
 164 sslcert         { return SSLCERT; }
 165 checkalias      { return CHECKALIAS; }
 166
 167 limit           { return LIMIT; }
 168
 169 with            {/* EMPTY */}
 170 and             {/* EMPTY */}
 171 has             {/* EMPTY */}
 172 wants           {/* EMPTY */}
 173 options         {/* EMPTY */}
 174 [;:,]           {/* EMPTY */}
 175
 176 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
 177 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
 178 (sdps)|(SDPS)   { return SDPS; }
 179 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
 180 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
 181 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
 182 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
 183 (odmr)|(ODMR)   { yylval.proto = P_ODMR;  return PROTO; }
 184 (kpop)|(KPOP)   { return KPOP; }
 185
 186 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 187
 188 -?[0-9]+/[^a-zA-Z]      { yylval.number = atoi(yytext); return NUMBER; }
 189
 190 [^=;:, \t\r\n]+ {
 191                         char buf[MSGBUFSIZE];
 192
 193                         escapes(yytext, buf);
 194                         yylval.sval = (char *) xstrdup(buf);
 195                         return STRING;
 196                 }
 197
 198 [ \t\r]+        ;       /* whitespace */
 199
 200 %%
 201
 202 void escapes(cp, tp)
 203 /* process standard C-style escape sequences in a string */
 204 const char      *cp;    /* source string with escapes */
 205 char            *tp;    /* target buffer for digested string */
 206 {
 207     while (*cp)
 208     {
 209         int     cval = 0;
 210
 211         if (*cp == '\\' && strchr("0123456789xX", cp[1]))
 212         {
 213             char *dp;
 214             const char *hex = "00112233445566778899aAbBcCdDeEfF";
 215             int dcount = 0;
 216
 217             if (*++cp == 'x' || *cp == 'X')
 218                 for (++cp; (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 219                     cval = (cval * 16) + (dp - hex) / 2;
 220             else if (*cp == '0')
 221                 while (strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 222                     cval = (cval * 8) + (*cp++ - '0');
 223             else
 224                 while ((strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 225                     cval = (cval * 10) + (*cp++ - '0');
 226         }
 227         else if (*cp == '\\')           /* C-style character escapes */
 228         {
 229             switch (*++cp)
 230             {
 231             case '\\': cval = '\\'; break;
 232             case 'n': cval = '\n'; break;
 233             case 't': cval = '\t'; break;
 234             case 'b': cval = '\b'; break;
 235             case 'r': cval = '\r'; break;
 236             default: cval = *cp;
 237             }
 238             cp++;
 239         }
 240         else
 241             cval = *cp++;
 242         *tp++ = cval;
 243     }
 244     *tp = '\0';
 245 }
 246