Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8 #include <string.h>
   9
  10 #include "config.h"
  11 #include "fetchmail.h"
  12 #include "rcfile_y.h"
  13
  14 int prc_lineno = 1;
  15
  16 #ifdef LEXDEBUG
  17 #define SETSTATE(n)     do {BEGIN(n); if (yydebug) fprintf(stderr, "Entering lexer state %d\n", n);} while (0)
  18 #else
  19 #define SETSTATE(n)     BEGIN(n)
  20 #endif /* LEXDEBUG */
  21 %}
  22
  23 /* this doesn't work with Linux lex, see the INSTALL file */
  24 %o 7000
  25 %a 4000
  26 %p 3000
  27
  28 %s NAME AUTH
  29
  30 %%
  31
  32 \"[^\"]*\"      {
  33                         char buf[MSGBUFSIZE];
  34
  35                         yytext[strlen(yytext)-1] = '\0';
  36                         escapes(yytext+1, buf);
  37                         yylval.sval = (char *) xstrdup(buf);
  38                         SETSTATE(0);
  39                         return STRING;
  40                 }
  41 \'[^\']*\'      {
  42                         char buf[MSGBUFSIZE];
  43
  44                         yytext[strlen(yytext)-1] = '\0';
  45                         escapes(yytext+1, buf);
  46                         yylval.sval = (char *) xstrdup(buf);
  47                         SETSTATE(0);
  48                         return STRING;
  49                 }
  50
  51 "*"             { BEGIN(0); return WILDCARD; }
  52
  53 <NAME>[^=;:, \t\r\n]+   {
  54                         char buf[MSGBUFSIZE];
  55
  56                         escapes(yytext, buf);
  57                         yylval.sval = (char *) xstrdup(buf);
  58                         SETSTATE(0);
  59                         return STRING;
  60                 }
  61
  62 set             { return SET; }
  63 logfile         { return LOGFILE; }
  64 idfile          { return IDFILE; }
  65 daemon          { return DAEMON; }
  66 syslog          { return SYSLOG; }
  67 invisible       { return INVISIBLE; }
  68 showdots        { return SHOWDOTS; }
  69 postmaster      { return POSTMASTER; }
  70 bouncemail      { return BOUNCEMAIL; }
  71 spambounce      { return SPAMBOUNCE; }
  72 warnings        { return WARNINGS; }
  73 tracepolls      { return TRACEPOLLS; }
  74
  75 defaults        { return DEFAULTS; }
  76 server          { return POLL; }
  77 poll            { return POLL; }
  78 skip            { return SKIP; }
  79 via             { return VIA; }
  80 aka             { return AKA; }
  81 local(domains)  { return LOCALDOMAINS; }
  82 proto(col)?     { return PROTOCOL; }
  83 service         { return SERVICE; }
  84 port            { return PORT; }
  85 interval        { return INTERVAL; }
  86 preauth(enticate)?      { SETSTATE(AUTH); return AUTHENTICATE; }
  87 auth(enticate)? { SETSTATE(AUTH); return AUTHENTICATE; }
  88 any             { SETSTATE(0); yylval.proto = A_ANY; return AUTHTYPE;}
  89 gssapi          { SETSTATE(0); yylval.proto = A_GSSAPI; return AUTHTYPE;}
  90 kerberos(_v)?4  { SETSTATE(0); yylval.proto = A_KERBEROS_V4; return AUTHTYPE;}
  91 kerberos(_v)?5  { SETSTATE(0); yylval.proto = A_KERBEROS_V5; return AUTHTYPE;}
  92 kerberos        { SETSTATE(0); yylval.proto = A_KERBEROS_V4; return AUTHTYPE;}
  93 ssh             { SETSTATE(0); yylval.proto = A_SSH; return AUTHTYPE;}
  94 cram(-md5)?     { SETSTATE(0); yylval.proto = A_CRAM_MD5; return AUTHTYPE;}
  95 ntlm            { SETSTATE(0); yylval.proto = A_NTLM; return AUTHTYPE;}
  96 <AUTH>password  { SETSTATE(0); yylval.proto = A_PASSWORD; return AUTHTYPE;}
  97 timeout         { return TIMEOUT;}
  98 envelope        { return ENVELOPE; }
  99 qvirtual        { return QVIRTUAL; }
 100 principal       { return PRINCIPAL; }
 101 esmtpname       { return ESMTPNAME; }
 102 esmtppassword   { return ESMTPPASSWORD; }
 103
 104
 105 user(name)?     {SETSTATE(NAME); return USERNAME; }
 106 <INITIAL,NAME>pass(word)?       {SETSTATE(NAME); return PASSWORD; }
 107 folder(s)?      { return FOLDER; }
 108 smtp(host)?     { return SMTPHOST; }
 109 fetchdomains    { return FETCHDOMAINS; }
 110 smtpaddress     { return SMTPADDRESS; }
 111 smtpname        { return SMTPNAME; }
 112 antispam        { return SPAMRESPONSE; }
 113 mda             { return MDA; }
 114 bsmtp           { return BSMTP; }
 115 lmtp            { return LMTP; }
 116 pre(connect)?   { return PRECONNECT; }
 117 post(connect)?  { return POSTCONNECT; }
 118 netsec          { return NETSEC; }
 119 interface       { return INTERFACE; }
 120 monitor         { return MONITOR; }
 121 plugin          { return PLUGIN; }
 122 plugout         { return PLUGOUT; }
 123 batchlimit      { return BATCHLIMIT; }
 124 fetchlimit      { return FETCHLIMIT; }
 125 expunge         { return EXPUNGE; }
 126 properties      { return PROPERTIES; }
 127
 128 is              { SETSTATE(NAME); return IS; }
 129 here            { return HERE; }
 130 there           { return THERE; }
 131 to              { SETSTATE(NAME); return TO; }
 132 =               { SETSTATE(NAME); return MAP; }
 133
 134 nobouncemail    |
 135 nouidl          |
 136 nocheckalias    |
 137 nodns           |
 138 noenvelope      |
 139 nokeep          |
 140 noflush         |
 141 nofetchall      |
 142 norewrite       |
 143 noforcecr       |
 144 nostripcr       |
 145 nopass8(bits)?  |
 146 nodropstatus    |
 147 nodropdelivered |
 148 nomimedec(ode)? |
 149 nospambounce    |
 150 noidle          {
 151                    yyless(2);
 152                    return NO;
 153                 }
 154
 155 no              {return NO;}
 156
 157 keep            { return KEEP; }
 158 flush           { return FLUSH; }
 159 fetchall        { return FETCHALL; }
 160 rewrite         { return REWRITE; }
 161 forcecr         { return FORCECR; }
 162 stripcr         { return STRIPCR; }
 163 pass8(bits)?    { return PASS8BITS; }
 164 dropstatus      { return DROPSTATUS; }
 165 dropdelivered   { return DROPDELIVERED; }
 166 mimedec(ode)?   { return MIMEDECODE; }
 167 idle            { return IDLE; }
 168 dns             { return DNS; }
 169 uidl            { return UIDL; }
 170 ssl             { return SSL; }
 171 sslkey          { return SSLKEY; }
 172 sslcert         { return SSLCERT; }
 173 sslproto        { return SSLPROTO; }
 174 sslcertck       { return SSLCERTCK; }
 175 sslcertpath     { return SSLCERTPATH; }
 176 sslfingerprint  { return SSLFINGERPRINT; }
 177 checkalias      { return CHECKALIAS; }
 178
 179 limit           { return LIMIT; }
 180
 181 with            {/* EMPTY */}
 182 and             {/* EMPTY */}
 183 has             {/* EMPTY */}
 184 wants           {/* EMPTY */}
 185 options         {/* EMPTY */}
 186 [;:,]           {/* EMPTY */}
 187
 188 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
 189 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
 190 (sdps)|(SDPS)   { return SDPS; }
 191 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
 192 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
 193 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
 194 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
 195 (odmr)|(ODMR)   { yylval.proto = P_ODMR;  return PROTO; }
 196 (kpop)|(KPOP)   { return KPOP; }
 197
 198 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 199
 200 -?[0-9]+/[^a-zA-Z]      { yylval.number = atoi(yytext); return NUMBER; }
 201
 202 [^=;:, \t\r\n]+ {
 203                         char buf[MSGBUFSIZE];
 204
 205                         escapes(yytext, buf);
 206                         yylval.sval = (char *) xstrdup(buf);
 207                         return STRING;
 208                 }
 209
 210 [ \t\r]+        ;       /* whitespace */
 211
 212 %%
 213
 214 void escapes(cp, tp)
 215 /* process standard C-style escape sequences in a string */
 216 const char      *cp;    /* source string with escapes */
 217 char            *tp;    /* target buffer for digested string */
 218 {
 219     while (*cp)
 220     {
 221         int     cval = 0;
 222
 223         if (*cp == '\\' && strchr("0123456789xX", cp[1]))
 224         {
 225             char *dp;
 226             const char *hex = "00112233445566778899aAbBcCdDeEfF";
 227             int dcount = 0;
 228
 229             if (*++cp == 'x' || *cp == 'X')
 230                 for (++cp; (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 231                     cval = (cval * 16) + (dp - hex) / 2;
 232             else if (*cp == '0')
 233                 while (strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 234                     cval = (cval * 8) + (*cp++ - '0');
 235             else
 236                 while ((strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 237                     cval = (cval * 10) + (*cp++ - '0');
 238         }
 239         else if (*cp == '\\')           /* C-style character escapes */
 240         {
 241             switch (*++cp)
 242             {
 243             case '\\': cval = '\\'; break;
 244             case 'n': cval = '\n'; break;
 245             case 't': cval = '\t'; break;
 246             case 'b': cval = '\b'; break;
 247             case 'r': cval = '\r'; break;
 248             default: cval = *cp;
 249             }
 250             cp++;
 251         }
 252         else
 253             cval = *cp++;
 254         *tp++ = cval;
 255     }
 256     *tp = '\0';
 257 }
 258