Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8 #include <string.h>
   9
  10 #include "config.h"
  11 #include "fetchmail.h"
  12 #include "rcfile_y.h"
  13
  14 int prc_lineno = 1;
  15
  16 #ifdef LEXDEBUG
  17 #define SETSTATE(n)     if (yydebug) do {BEGIN(n); fprintf(stderr, "Entering lexer state %d\n", n);} while (0)
  18 #else
  19 #define SETSTATE(n)     BEGIN(n)
  20 #endif /* LEXDEBUG */
  21 %}
  22
  23 /* this doesn't work with Linux lex, see the INSTALL file */
  24 %o 7000
  25 %a 4000
  26 %p 3000
  27
  28 %s NAME PREAUTH
  29
  30 %%
  31
  32 \"[^\"]*\"      {
  33                         char buf[MSGBUFSIZE];
  34
  35                         yytext[strlen(yytext)-1] = '\0';
  36                         escapes(yytext+1, buf);
  37                         yylval.sval = (char *) xstrdup(buf);
  38                         SETSTATE(0);
  39                         return STRING;
  40                 }
  41 \'[^\']*\'      {
  42                         char buf[MSGBUFSIZE];
  43
  44                         yytext[strlen(yytext)-1] = '\0';
  45                         escapes(yytext+1, buf);
  46                         yylval.sval = (char *) xstrdup(buf);
  47                         SETSTATE(0);
  48                         return STRING;
  49                 }
  50
  51 "*"             { BEGIN(0); return WILDCARD; }
  52
  53 <NAME>[^=;:, \t\r\n]+   {
  54                         char buf[MSGBUFSIZE];
  55
  56                         escapes(yytext, buf);
  57                         yylval.sval = (char *) xstrdup(buf);
  58                         SETSTATE(0);
  59                         return STRING;
  60                 }
  61
  62 set             { return SET; }
  63 logfile         { return LOGFILE; }
  64 idfile          { return IDFILE; }
  65 daemon          { return DAEMON; }
  66 syslog          { return SYSLOG; }
  67 invisible       { return INVISIBLE; }
  68 showdots        { return SHOWDOTS; }
  69 postmaster      { return POSTMASTER; }
  70 bouncemail      { return BOUNCEMAIL; }
  71 warnings        { return WARNINGS; }
  72
  73 defaults        { return DEFAULTS; }
  74 server          { return POLL; }
  75 poll            { return POLL; }
  76 skip            { return SKIP; }
  77 via             { return VIA; }
  78 aka             { return AKA; }
  79 local(domains)  { return LOCALDOMAINS; }
  80 proto(col)?     { return PROTOCOL; }
  81 service         { return SERVICE; }
  82 port            { return PORT; }
  83 interval        { return INTERVAL; }
  84 preauth(enticate)?      { SETSTATE(PREAUTH); return PREAUTHENTICATE; }
  85 kerberos(_v)?4  { SETSTATE(0); return KERBEROS4; }
  86 kerberos(_v)?5  { SETSTATE(0); return KERBEROS5; }
  87 kerberos        { SETSTATE(0); return KERBEROS; }
  88 ssh             { SETSTATE(0); return SSH; }
  89 <PREAUTH>password { SETSTATE(0); return PASSWORD; }
  90 timeout         { return TIMEOUT;}
  91 envelope        { return ENVELOPE; }
  92 qvirtual        { return QVIRTUAL; }
  93 principal       { return PRINCIPAL; }
  94
  95 user(name)?     {SETSTATE(NAME); return USERNAME; }
  96 pass(word)?     {SETSTATE(NAME); return PASSWORD; }
  97 folder(s)?      { return FOLDER; }
  98 smtp(host)?     { return SMTPHOST; }
  99 smtpaddress     { return SMTPADDRESS; }
 100 antispam        { return SPAMRESPONSE; }
 101 mda             { return MDA; }
 102 bsmtp           { return BSMTP; }
 103 lmtp            { return LMTP; }
 104 pre(connect)?   { return PRECONNECT; }
 105 post(connect)?  { return POSTCONNECT; }
 106 netsec          { return NETSEC; }
 107 interface       { return INTERFACE; }
 108 monitor         { return MONITOR; }
 109 plugin          { return PLUGIN; }
 110 plugout         { return PLUGOUT; }
 111 batchlimit      { return BATCHLIMIT; }
 112 fetchlimit      { return FETCHLIMIT; }
 113 expunge         { return EXPUNGE; }
 114 properties      { return PROPERTIES; }
 115
 116 is              { SETSTATE(NAME); return IS; }
 117 here            { return HERE; }
 118 there           { return THERE; }
 119 to              { SETSTATE(NAME); return TO; }
 120 =               { SETSTATE(NAME); return MAP; }
 121
 122 nobouncemail    |
 123 nouidl          |
 124 nocheckalias    |
 125 nodns           |
 126 noenvelope      |
 127 nokeep          |
 128 noflush         |
 129 nofetchall      |
 130 norewrite       |
 131 noforcecr       |
 132 nostripcr       |
 133 nopass8(bits)?  |
 134 nodropstatus    |
 135 nodropdelivered |
 136 nomimedec(ode)? |
 137 noidle          {
 138                    yyless(2);
 139                    return NO;
 140                 }
 141
 142 no              {return NO;}
 143
 144 keep            { return KEEP; }
 145 flush           { return FLUSH; }
 146 fetchall        { return FETCHALL; }
 147 rewrite         { return REWRITE; }
 148 forcecr         { return FORCECR; }
 149 stripcr         { return STRIPCR; }
 150 pass8(bits)?    { return PASS8BITS; }
 151 dropstatus      { return DROPSTATUS; }
 152 dropdelivered   { return DROPDELIVERED; }
 153 mimedec(ode)?   { return MIMEDECODE; }
 154 idle            { return IDLE; }
 155 dns             { return DNS; }
 156 uidl            { return UIDL; }
 157 ssl             { return SSL; }
 158 sslkey          { return SSLKEY; }
 159 sslcert         { return SSLCERT; }
 160 checkalias      { return CHECKALIAS; }
 161
 162 limit           { return LIMIT; }
 163
 164 with            {/* EMPTY */}
 165 and             {/* EMPTY */}
 166 has             {/* EMPTY */}
 167 wants           {/* EMPTY */}
 168 options         {/* EMPTY */}
 169 [;:,]           {/* EMPTY */}
 170
 171 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
 172 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
 173 (sdps)|(SDPS)   { return SDPS; }
 174 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
 175 (imap-k4)|(IMAP-K4)   { yylval.proto = P_IMAP_K4;  return PROTO; }
 176 (imap-gss)|(IMAP-GSS) { yylval.proto = P_IMAP_GSS;  return PROTO; }
 177 (imap-crammd5)|(IMAP-CRAMMD5) { yylval.proto = P_IMAP_CRAM_MD5;  return PROTO; }
 178 (imap-login)|(IMAP-LOGIN) { yylval.proto = P_IMAP_LOGIN;  return PROTO; }
 179 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
 180 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
 181 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
 182 (kpop)|(KPOP)   { return KPOP; }
 183
 184 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 185
 186 -?[0-9]+/[^a-zA-Z]      { yylval.number = atoi(yytext); return NUMBER; }
 187
 188 [^=;:, \t\r\n]+ {
 189                         char buf[MSGBUFSIZE];
 190
 191                         escapes(yytext, buf);
 192                         yylval.sval = (char *) xstrdup(buf);
 193                         return STRING;
 194                 }
 195
 196 [ \t\r]+        ;       /* whitespace */
 197
 198 %%
 199
 200 void escapes(cp, tp)
 201 /* process standard C-style escape sequences in a string */
 202 const char      *cp;    /* source string with escapes */
 203 char            *tp;    /* target buffer for digested string */
 204 {
 205     while (*cp)
 206     {
 207         int     cval = 0;
 208
 209         if (*cp == '\\' && strchr("0123456789xX", cp[1]))
 210         {
 211             char *dp;
 212             const char *hex = "00112233445566778899aAbBcCdDeEfF";
 213             int dcount = 0;
 214
 215             if (*++cp == 'x' || *cp == 'X')
 216                 for (++cp; (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 217                     cval = (cval * 16) + (dp - hex) / 2;
 218             else if (*cp == '0')
 219                 while (strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 220                     cval = (cval * 8) + (*cp++ - '0');
 221             else
 222                 while ((strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 223                     cval = (cval * 10) + (*cp++ - '0');
 224         }
 225         else if (*cp == '\\')           /* C-style character escapes */
 226         {
 227             switch (*++cp)
 228             {
 229             case '\\': cval = '\\'; break;
 230             case 'n': cval = '\n'; break;
 231             case 't': cval = '\t'; break;
 232             case 'b': cval = '\b'; break;
 233             case 'r': cval = '\r'; break;
 234             default: cval = *cp;
 235             }
 236             cp++;
 237         }
 238         else
 239             cval = *cp++;
 240         *tp++ = cval;
 241     }
 242     *tp = '\0';
 243 }
 244