Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8 #include <string.h>
   9
  10 #include "config.h"
  11 #include "fetchmail.h"
  12 #include "rcfile_y.h"
  13
  14 int prc_lineno = 1;
  15
  16 #ifdef LEXDEBUG
  17 #define SETSTATE(n)     if (yydebug) do {BEGIN(n); fprintf(stderr, "Entering lexer state %d\n", n);} while (0)
  18 #else
  19 #define SETSTATE(n)     BEGIN(n)
  20 #endif /* LEXDEBUG */
  21 %}
  22
  23 /* this doesn't work with Linux lex, see the INSTALL file */
  24 %o 7000
  25 %a 4000
  26 %p 3000
  27
  28 %s NAME PREAUTH
  29
  30 %%
  31
  32 \"[^\"]*\"      {
  33                         char buf[MSGBUFSIZE];
  34
  35                         yytext[strlen(yytext)-1] = '\0';
  36                         escapes(yytext+1, buf);
  37                         yylval.sval = (char *) xstrdup(buf);
  38                         SETSTATE(0);
  39                         return STRING;
  40                 }
  41 \'[^\']*\'      {
  42                         char buf[MSGBUFSIZE];
  43
  44                         yytext[strlen(yytext)-1] = '\0';
  45                         escapes(yytext+1, buf);
  46                         yylval.sval = (char *) xstrdup(buf);
  47                         SETSTATE(0);
  48                         return STRING;
  49                 }
  50
  51 "*"             { BEGIN(0); return WILDCARD; }
  52
  53 <NAME>[^=;:, \t\r\n]+   {
  54                         char buf[MSGBUFSIZE];
  55
  56                         escapes(yytext, buf);
  57                         yylval.sval = (char *) xstrdup(buf);
  58                         SETSTATE(0);
  59                         return STRING;
  60                 }
  61
  62 set             { return SET; }
  63 logfile         { return LOGFILE; }
  64 idfile          { return IDFILE; }
  65 daemon          { return DAEMON; }
  66 syslog          { return SYSLOG; }
  67 invisible       { return INVISIBLE; }
  68 postmaster      { return POSTMASTER; }
  69 bouncemail      { return BOUNCEMAIL; }
  70 warnings        { return WARNINGS; }
  71
  72 defaults        { return DEFAULTS; }
  73 server          { return POLL; }
  74 poll            { return POLL; }
  75 skip            { return SKIP; }
  76 via             { return VIA; }
  77 aka             { return AKA; }
  78 local(domains)  { return LOCALDOMAINS; }
  79 proto(col)?     { return PROTOCOL; }
  80 service         { return SERVICE; }
  81 port            { return PORT; }
  82 interval        { return INTERVAL; }
  83 preauth(enticate)?      { SETSTATE(PREAUTH); return PREAUTHENTICATE; }
  84 kerberos(_v)?4  { SETSTATE(0); return KERBEROS4; }
  85 kerberos(_v)?5  { SETSTATE(0); return KERBEROS5; }
  86 kerberos        { SETSTATE(0); return KERBEROS; }
  87 <PREAUTH>password { SETSTATE(0); return PASSWORD; }
  88 timeout         { return TIMEOUT;}
  89 envelope        { return ENVELOPE; }
  90 qvirtual        { return QVIRTUAL; }
  91
  92 user(name)?     {SETSTATE(NAME); return USERNAME; }
  93 pass(word)?     {SETSTATE(NAME); return PASSWORD; }
  94 folder(s)?      { return FOLDER; }
  95 smtp(host)?     { return SMTPHOST; }
  96 smtpaddress     { return SMTPADDRESS; }
  97 antispam        { return SPAMRESPONSE; }
  98 mda             { return MDA; }
  99 bsmtp           { return BSMTP; }
 100 lmtp            { return LMTP; }
 101 pre(connect)?   { return PRECONNECT; }
 102 post(connect)?  { return POSTCONNECT; }
 103 netsec          { return NETSEC; }
 104 interface       { return INTERFACE; }
 105 monitor         { return MONITOR; }
 106 plugin          { return PLUGIN; }
 107 plugout         { return PLUGIN; }
 108 batchlimit      { return BATCHLIMIT; }
 109 fetchlimit      { return FETCHLIMIT; }
 110 expunge         { return EXPUNGE; }
 111 properties      { return PROPERTIES; }
 112
 113 is              { SETSTATE(NAME); return IS; }
 114 here            { return HERE; }
 115 there           { return THERE; }
 116 to              { SETSTATE(NAME); return TO; }
 117 =               { SETSTATE(NAME); return MAP; }
 118
 119 nobouncemail    |
 120 nouidl          |
 121 nocheckalias    |
 122 nodns           |
 123 noenvelope      |
 124 nokeep          |
 125 noflush         |
 126 nofetchall      |
 127 norewrite       |
 128 noforcecr       |
 129 nostripcr       |
 130 nopass8(bits)?  |
 131 nodropstatus    |
 132 nomimedec(ode)? {
 133                    yyless(2);
 134                    return NO;
 135                 }
 136
 137 no              {return NO;}
 138
 139 keep            { return KEEP; }
 140 flush           { return FLUSH; }
 141 fetchall        { return FETCHALL; }
 142 rewrite         { return REWRITE; }
 143 forcecr         { return FORCECR; }
 144 stripcr         { return STRIPCR; }
 145 pass8(bits)?    { return PASS8BITS; }
 146 dropstatus      { return DROPSTATUS; }
 147 mimedec(ode)?   { return MIMEDECODE; }
 148 dns             { return DNS; }
 149 uidl            { return UIDL; }
 150 checkalias      { return CHECKALIAS; }
 151
 152 limit           { return LIMIT; }
 153
 154 with            {/* EMPTY */}
 155 and             {/* EMPTY */}
 156 has             {/* EMPTY */}
 157 wants           {/* EMPTY */}
 158 options         {/* EMPTY */}
 159 [;:,]           {/* EMPTY */}
 160
 161 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
 162 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
 163 (sdps)|(SDPS)   { return SDPS; }
 164 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
 165 (imap-k4)|(IMAP-K4)   { yylval.proto = P_IMAP_K4;  return PROTO; }
 166 (imap-gss)|(IMAP-GSS) { yylval.proto = P_IMAP_GSS;  return PROTO; }
 167 (imap-crammd5)|(IMAP-CRAMMD5) { yylval.proto = P_IMAP_CRAM_MD5;  return PROTO; }
 168 (imap-login)|(IMAP-LOGIN) { yylval.proto = P_IMAP_LOGIN;  return PROTO; }
 169 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
 170 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
 171 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
 172 (kpop)|(KPOP)   { return KPOP; }
 173
 174 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 175
 176 -?[0-9]+                { yylval.number = atoi(yytext); return NUMBER; }
 177
 178 [^=;:, \t\r\n]+ {
 179                         char buf[MSGBUFSIZE];
 180
 181                         escapes(yytext, buf);
 182                         yylval.sval = (char *) xstrdup(buf);
 183                         return STRING;
 184                 }
 185
 186 [ \t\r]+        ;       /* whitespace */
 187
 188 %%
 189
 190 void escapes(cp, tp)
 191 /* process standard C-style escape sequences in a string */
 192 const char      *cp;    /* source string with escapes */
 193 char            *tp;    /* target buffer for digested string */
 194 {
 195     while (*cp)
 196     {
 197         int     cval = 0;
 198
 199         if (*cp == '\\' && strchr("0123456789xX", cp[1]))
 200         {
 201             char *dp;
 202             const char *hex = "00112233445566778899aAbBcCdDeEfF";
 203             int dcount = 0;
 204
 205             if (*++cp == 'x' || *cp == 'X')
 206                 for (++cp; (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 207                     cval = (cval * 16) + (dp - hex) / 2;
 208             else if (*cp == '0')
 209                 while (strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 210                     cval = (cval * 8) + (*cp++ - '0');
 211             else
 212                 while ((strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 213                     cval = (cval * 10) + (*cp++ - '0');
 214         }
 215         else if (*cp == '\\')           /* C-style character escapes */
 216         {
 217             switch (*++cp)
 218             {
 219             case '\\': cval = '\\'; break;
 220             case 'n': cval = '\n'; break;
 221             case 't': cval = '\t'; break;
 222             case 'b': cval = '\b'; break;
 223             case 'r': cval = '\r'; break;
 224             default: cval = *cp;
 225             }
 226             cp++;
 227         }
 228         else
 229             cval = *cp++;
 230         *tp++ = cval;
 231     }
 232     *tp = '\0';
 233 }
 234