Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file, to be used with GNU flex.
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8
   9 #include "config.h"
  10 #include "fetchmail.h"
  11 #include "xmalloc.h"
  12 #include "rcfile_y.h"
  13
  14 #include <string.h>
  15
  16 int prc_lineno = 1;
  17
  18 #ifdef LEXDEBUG
  19 #define SETSTATE(n)     do {BEGIN(n); if (yydebug) fprintf(stderr, "Entering lexer state %d\n", n);} while (0)
  20 #else
  21 #define SETSTATE(n)     BEGIN(n)
  22 #endif /* LEXDEBUG */
  23
  24 #define YY_NO_INPUT
  25
  26 %}
  27
  28 %option nounput noyywrap
  29 %option warn nodefault
  30 %option 8bit batch
  31
  32 %s NAME AUTH
  33
  34 %%
  35
  36 \"[^\"]*\"      |
  37 \'[^\']*\'      {
  38                         char *in = xstrndup(yytext+1, yyleng-2);
  39                         escapes(in, in);
  40                         yylval.sval = in;
  41                         SETSTATE(0);
  42                         return STRING;
  43                 }
  44
  45 <NAME>[^=;:, \t\r\n]+   {
  46                         char *in = xstrdup(yytext);
  47                         escapes(in, in);
  48                         yylval.sval = in;
  49                         SETSTATE(0);
  50                         return STRING;
  51                 }
  52
  53 set             { return SET; }
  54 logfile         { return LOGFILE; }
  55 idfile          { return IDFILE; }
  56 pidfile         { return PIDFILE; }
  57 daemon          { return DAEMON; }
  58 syslog          { return SYSLOG; }
  59 invisible       { return INVISIBLE; }
  60 showdots        { return SHOWDOTS; }
  61 postmaster      { return POSTMASTER; }
  62 bouncemail      { return BOUNCEMAIL; }
  63 spambounce      { return SPAMBOUNCE; }
  64 softbounce      { return SOFTBOUNCE; }
  65 warnings        { return WARNINGS; }
  66 tracepolls      { return TRACEPOLLS; }
  67
  68 defaults        { return DEFAULTS; }
  69 server          { return POLL; }
  70 poll            { return POLL; }
  71 skip            { return SKIP; }
  72 via             { return VIA; }
  73 aka             { return AKA; }
  74 local(domains)? { return LOCALDOMAINS; }
  75 proto(col)?     { return PROTOCOL; }
  76 service         { return SERVICE; }
  77 port            { return PORT; }
  78 interval        { return INTERVAL; }
  79 preauth(enticate)?      { SETSTATE(AUTH); return AUTHENTICATE; }
  80 auth(enticate)? { SETSTATE(AUTH); return AUTHENTICATE; }
  81 any             { SETSTATE(0); yylval.proto = A_ANY; return AUTHTYPE;}
  82 gssapi          { SETSTATE(0); yylval.proto = A_GSSAPI; return AUTHTYPE;}
  83 kerberos(_v)?5  { SETSTATE(0); yylval.proto = A_KERBEROS_V5; return AUTHTYPE;}
  84 kerberos        { SETSTATE(0); yylval.proto = A_KERBEROS_V5; return AUTHTYPE;}
  85 ssh             { SETSTATE(0); yylval.proto = A_SSH; return AUTHTYPE;}
  86 external        { SETSTATE(0); yylval.proto = A_EXTERNAL; return AUTHTYPE;}
  87 (otp|opie)      { SETSTATE(0); yylval.proto = A_OTP; return AUTHTYPE;}
  88 cram(-md5)?     { SETSTATE(0); yylval.proto = A_CRAM_MD5; return AUTHTYPE;}
  89 msn             { SETSTATE(0); yylval.proto = A_MSN; return AUTHTYPE;}
  90 ntlm            { SETSTATE(0); yylval.proto = A_NTLM; return AUTHTYPE;}
  91 <AUTH>password  { SETSTATE(0); yylval.proto = A_PASSWORD; return AUTHTYPE;}
  92 timeout         { return TIMEOUT;}
  93 envelope        { return ENVELOPE; }
  94 qvirtual        { return QVIRTUAL; }
  95 principal       { return PRINCIPAL; }
  96 esmtpname       { return ESMTPNAME; }
  97 esmtppassword   { return ESMTPPASSWORD; }
  98 bad-header      { return BADHEADER; }
  99 accept          { return ACCEPT; }
 100 reject          { return REJECT_; }
 101
 102 user(name)?     {SETSTATE(NAME); return USERNAME; }
 103 <INITIAL,NAME>pass(word)?       {SETSTATE(NAME); return PASSWORD; }
 104 folder(s)?      { return FOLDER; }
 105 smtp(host)?     { return SMTPHOST; }
 106 fetchdomains    { return FETCHDOMAINS; }
 107 smtpaddress     { return SMTPADDRESS; }
 108 smtpname        { return SMTPNAME; }
 109 antispam        { return SPAMRESPONSE; }
 110 mda             { return MDA; }
 111 bsmtp           { return BSMTP; }
 112 lmtp            { return LMTP; }
 113 pre(connect)?   { return PRECONNECT; }
 114 post(connect)?  { return POSTCONNECT; }
 115 interface       { return INTERFACE; }
 116 monitor         { return MONITOR; }
 117 plugin          { return PLUGIN; }
 118 plugout         { return PLUGOUT; }
 119 batchlimit      { return BATCHLIMIT; }
 120 fetchlimit      { return FETCHLIMIT; }
 121 fetchsizelimit  { return FETCHSIZELIMIT; }
 122 fastuidl        { return FASTUIDL; }
 123 expunge         { return EXPUNGE; }
 124 properties      { return PROPERTIES; }
 125
 126 is              { SETSTATE(NAME); return IS; }
 127 here            { return HERE; }
 128 there           { return THERE; }
 129 to              { SETSTATE(NAME); return TO; }
 130 =               { SETSTATE(NAME); return MAP; }
 131
 132 nobouncemail    |
 133 nouidl          |
 134 nocheckalias    |
 135 nodns           |
 136 noenvelope      |
 137 nokeep          |
 138 noflush         |
 139 nolimitflush    |
 140 nofetchall      |
 141 norewrite       |
 142 noforcecr       |
 143 nostripcr       |
 144 nopass8(bits)?  |
 145 nodropstatus    |
 146 nodropdelivered |
 147 nomimedec(ode)? |
 148 nospambounce    |
 149 noidle          {
 150                    yyless(2);
 151                    return NO;
 152                 }
 153
 154 no              {return NO;}
 155
 156 keep            { return KEEP; }
 157 flush           { return FLUSH; }
 158 limitflush      { return LIMITFLUSH; }
 159 fetchall        { return FETCHALL; }
 160 rewrite         { return REWRITE; }
 161 forcecr         { return FORCECR; }
 162 stripcr         { return STRIPCR; }
 163 pass8(bits)?    { return PASS8BITS; }
 164 dropstatus      { return DROPSTATUS; }
 165 dropdelivered   { return DROPDELIVERED; }
 166 mimedec(ode)?   { return MIMEDECODE; }
 167 idle            { return IDLE; }
 168 dns             { return DNS; }
 169 uidl            { return UIDL; }
 170 ssl             { return SSL; }
 171 sslkey          { return SSLKEY; }
 172 sslcert         { return SSLCERT; }
 173 sslproto        { return SSLPROTO; }
 174 sslcertck       { return SSLCERTCK; }
 175 sslcertfile     { return SSLCERTFILE; }
 176 sslcertpath     { return SSLCERTPATH; }
 177 sslcommonname   { return SSLCOMMONNAME; }
 178 sslfingerprint  { return SSLFINGERPRINT; }
 179 checkalias      { return CHECKALIAS; }
 180
 181 limit           { return LIMIT; }
 182
 183 with            {/* EMPTY */}
 184 and             {/* EMPTY */}
 185 has             {/* EMPTY */}
 186 wants           {/* EMPTY */}
 187 options         {/* EMPTY */}
 188 [;:,]           {/* EMPTY */}
 189
 190 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
 191 (sdps)|(SDPS)   { return SDPS; }
 192 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
 193 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
 194 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
 195 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
 196 (odmr)|(ODMR)   { yylval.proto = P_ODMR;  return PROTO; }
 197 (kpop)|(KPOP)   { return KPOP; }
 198
 199 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 200
 201 -?[0-9]+        { yylval.number = atoi(yytext); return NUMBER; }
 202
 203 [^=;:, \t\r\n]+ {
 204                         char *in = xstrdup(yytext);
 205                         escapes(in, in);
 206                         yylval.sval = in;
 207                         return STRING;
 208                 }
 209
 210 [ \t\r]+        ;       /* whitespace */
 211
 212 %%
 213
 214 /** process standard C-style escape sequences in a string,
 215  * this can never lengthen the output, so cp and tp may overlap as long
 216  * as cp >= tp. */
 217 void escapes(const char *cp /** source string with escapes */,
 218              char       *tp /** target buffer for digested string */)
 219 {
 220     while (*cp)
 221     {
 222         int     cval = 0;
 223
 224         /* we MUST check for NUL explicitly, as strchr(string, 0) will
 225          * always succeed! */
 226         if (*cp == '\\' && cp[1] && strchr("0123456789xX", cp[1]))
 227         {
 228             const char *dp;
 229             const char *hex = "00112233445566778899aAbBcCdDeEfF";
 230             int dcount = 0;
 231
 232             if (*++cp == 'x' || *cp == 'X')
 233                 for (++cp; *cp && (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 234                     cval = (cval * 16) + (dp - hex) / 2;
 235             else if (*cp == '0')
 236                 while (*cp && strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 237                     cval = (cval * 8) + (*cp++ - '0');
 238             else
 239                 while (*cp && (strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 240                     cval = (cval * 10) + (*cp++ - '0');
 241         }
 242         else if (*cp == '\\')           /* C-style character escapes */
 243         {
 244             switch (*++cp)
 245             {
 246             case '\n': cp++; continue;  /* backslash before LF to join lines */
 247             case '\0': goto done;          /* ignore backslash at file end */
 248             case '\\': cval = '\\'; break;
 249             case 'n': cval = '\n'; break;
 250             case 't': cval = '\t'; break;
 251             case 'b': cval = '\b'; break;
 252             case 'r': cval = '\r'; break;
 253             default: cval = *cp;
 254             }
 255             cp++;
 256         }
 257         else
 258             cval = *cp++;
 259         *tp++ = cval;
 260     }
 261 done:
 262     *tp = '\0';
 263 }