Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file, to be used with GNU flex.
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8 #include <string.h>
   9
  10 #include "config.h"
  11 #include "fetchmail.h"
  12 #include "xmalloc.h"
  13 #include "rcfile_y.h"
  14
  15 int prc_lineno = 1;
  16
  17 #ifdef LEXDEBUG
  18 #define SETSTATE(n)     do {BEGIN(n); if (yydebug) fprintf(stderr, "Entering lexer state %d\n", n);} while (0)
  19 #else
  20 #define SETSTATE(n)     BEGIN(n)
  21 #endif /* LEXDEBUG */
  22
  23 #define YY_NO_INPUT
  24
  25 %}
  26
  27 %option nounput noyywrap
  28 %option warn nodefault
  29 %option 8bit batch
  30
  31 %s NAME AUTH
  32
  33 %%
  34
  35 \"[^\"]*\"      |
  36 \'[^\']*\'      {
  37                         char *in = xstrndup(yytext+1, yyleng-2);
  38                         escapes(in, in);
  39                         yylval.sval = in;
  40                         SETSTATE(0);
  41                         return STRING;
  42                 }
  43
  44 <NAME>[^=;:, \t\r\n]+   {
  45                         char *in = xstrdup(yytext);
  46                         escapes(in, in);
  47                         yylval.sval = in;
  48                         SETSTATE(0);
  49                         return STRING;
  50                 }
  51
  52 set             { return SET; }
  53 logfile         { return LOGFILE; }
  54 idfile          { return IDFILE; }
  55 pidfile         { return PIDFILE; }
  56 daemon          { return DAEMON; }
  57 syslog          { return SYSLOG; }
  58 invisible       { return INVISIBLE; }
  59 showdots        { return SHOWDOTS; }
  60 postmaster      { return POSTMASTER; }
  61 bouncemail      { return BOUNCEMAIL; }
  62 spambounce      { return SPAMBOUNCE; }
  63 softbounce      { return SOFTBOUNCE; }
  64 warnings        { return WARNINGS; }
  65 tracepolls      { return TRACEPOLLS; }
  66
  67 defaults        { return DEFAULTS; }
  68 server          { return POLL; }
  69 poll            { return POLL; }
  70 skip            { return SKIP; }
  71 via             { return VIA; }
  72 aka             { return AKA; }
  73 local(domains)? { return LOCALDOMAINS; }
  74 proto(col)?     { return PROTOCOL; }
  75 service         { return SERVICE; }
  76 port            { return PORT; }
  77 interval        { return INTERVAL; }
  78 preauth(enticate)?      { SETSTATE(AUTH); return AUTHENTICATE; }
  79 auth(enticate)? { SETSTATE(AUTH); return AUTHENTICATE; }
  80 any             { SETSTATE(0); yylval.proto = A_ANY; return AUTHTYPE;}
  81 gssapi          { SETSTATE(0); yylval.proto = A_GSSAPI; return AUTHTYPE;}
  82 kerberos(_v)?5  { SETSTATE(0); yylval.proto = A_KERBEROS_V5; return AUTHTYPE;}
  83 kerberos        { SETSTATE(0); yylval.proto = A_KERBEROS_V5; return AUTHTYPE;}
  84 ssh             { SETSTATE(0); yylval.proto = A_SSH; return AUTHTYPE;}
  85 external        { SETSTATE(0); yylval.proto = A_EXTERNAL; return AUTHTYPE;}
  86 (otp|opie)      { SETSTATE(0); yylval.proto = A_OTP; return AUTHTYPE;}
  87 cram(-md5)?     { SETSTATE(0); yylval.proto = A_CRAM_MD5; return AUTHTYPE;}
  88 msn             { SETSTATE(0); yylval.proto = A_MSN; return AUTHTYPE;}
  89 ntlm            { SETSTATE(0); yylval.proto = A_NTLM; return AUTHTYPE;}
  90 <AUTH>password  { SETSTATE(0); yylval.proto = A_PASSWORD; return AUTHTYPE;}
  91 timeout         { return TIMEOUT;}
  92 envelope        { return ENVELOPE; }
  93 qvirtual        { return QVIRTUAL; }
  94 principal       { return PRINCIPAL; }
  95 esmtpname       { return ESMTPNAME; }
  96 esmtppassword   { return ESMTPPASSWORD; }
  97 bad-header      { return BADHEADER; }
  98 accept          { return ACCEPT; }
  99 reject          { return REJECT_; }
 100
 101 user(name)?     {SETSTATE(NAME); return USERNAME; }
 102 <INITIAL,NAME>pass(word)?       {SETSTATE(NAME); return PASSWORD; }
 103 folder(s)?      { return FOLDER; }
 104 smtp(host)?     { return SMTPHOST; }
 105 fetchdomains    { return FETCHDOMAINS; }
 106 smtpaddress     { return SMTPADDRESS; }
 107 smtpname        { return SMTPNAME; }
 108 antispam        { return SPAMRESPONSE; }
 109 mda             { return MDA; }
 110 bsmtp           { return BSMTP; }
 111 lmtp            { return LMTP; }
 112 pre(connect)?   { return PRECONNECT; }
 113 post(connect)?  { return POSTCONNECT; }
 114 interface       { return INTERFACE; }
 115 monitor         { return MONITOR; }
 116 plugin          { return PLUGIN; }
 117 plugout         { return PLUGOUT; }
 118 batchlimit      { return BATCHLIMIT; }
 119 fetchlimit      { return FETCHLIMIT; }
 120 fetchsizelimit  { return FETCHSIZELIMIT; }
 121 fastuidl        { return FASTUIDL; }
 122 expunge         { return EXPUNGE; }
 123 properties      { return PROPERTIES; }
 124
 125 is              { SETSTATE(NAME); return IS; }
 126 here            { return HERE; }
 127 there           { return THERE; }
 128 to              { SETSTATE(NAME); return TO; }
 129 =               { SETSTATE(NAME); return MAP; }
 130
 131 nobouncemail    |
 132 nouidl          |
 133 nocheckalias    |
 134 nodns           |
 135 noenvelope      |
 136 nokeep          |
 137 noflush         |
 138 nolimitflush    |
 139 nofetchall      |
 140 norewrite       |
 141 noforcecr       |
 142 nostripcr       |
 143 nopass8(bits)?  |
 144 nodropstatus    |
 145 nodropdelivered |
 146 nomimedec(ode)? |
 147 nospambounce    |
 148 noidle          {
 149                    yyless(2);
 150                    return NO;
 151                 }
 152
 153 no              {return NO;}
 154
 155 keep            { return KEEP; }
 156 flush           { return FLUSH; }
 157 limitflush      { return LIMITFLUSH; }
 158 fetchall        { return FETCHALL; }
 159 rewrite         { return REWRITE; }
 160 forcecr         { return FORCECR; }
 161 stripcr         { return STRIPCR; }
 162 pass8(bits)?    { return PASS8BITS; }
 163 dropstatus      { return DROPSTATUS; }
 164 dropdelivered   { return DROPDELIVERED; }
 165 mimedec(ode)?   { return MIMEDECODE; }
 166 idle            { return IDLE; }
 167 dns             { return DNS; }
 168 uidl            { return UIDL; }
 169 ssl             { return SSL; }
 170 sslkey          { return SSLKEY; }
 171 sslcert         { return SSLCERT; }
 172 sslproto        { return SSLPROTO; }
 173 sslcertck       { return SSLCERTCK; }
 174 sslcertfile     { return SSLCERTFILE; }
 175 sslcertpath     { return SSLCERTPATH; }
 176 sslcommonname   { return SSLCOMMONNAME; }
 177 sslfingerprint  { return SSLFINGERPRINT; }
 178 checkalias      { return CHECKALIAS; }
 179
 180 limit           { return LIMIT; }
 181
 182 with            {/* EMPTY */}
 183 and             {/* EMPTY */}
 184 has             {/* EMPTY */}
 185 wants           {/* EMPTY */}
 186 options         {/* EMPTY */}
 187 [;:,]           {/* EMPTY */}
 188
 189 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
 190 (sdps)|(SDPS)   { return SDPS; }
 191 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
 192 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
 193 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
 194 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
 195 (odmr)|(ODMR)   { yylval.proto = P_ODMR;  return PROTO; }
 196 (kpop)|(KPOP)   { return KPOP; }
 197
 198 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 199
 200 -?[0-9]+        { yylval.number = atoi(yytext); return NUMBER; }
 201
 202 [^=;:, \t\r\n]+ {
 203                         char *in = xstrdup(yytext);
 204                         escapes(in, in);
 205                         yylval.sval = in;
 206                         return STRING;
 207                 }
 208
 209 [ \t\r]+        ;       /* whitespace */
 210
 211 %%
 212
 213 /** process standard C-style escape sequences in a string,
 214  * this can never lengthen the output, so cp and tp may overlap as long
 215  * as cp >= tp. */
 216 void escapes(const char *cp /** source string with escapes */,
 217              char       *tp /** target buffer for digested string */)
 218 {
 219     while (*cp)
 220     {
 221         int     cval = 0;
 222
 223         /* we MUST check for NUL explicitly, as strchr(string, 0) will
 224          * always succeed! */
 225         if (*cp == '\\' && cp[1] && strchr("0123456789xX", cp[1]))
 226         {
 227             const char *dp;
 228             const char *hex = "00112233445566778899aAbBcCdDeEfF";
 229             int dcount = 0;
 230
 231             if (*++cp == 'x' || *cp == 'X')
 232                 for (++cp; *cp && (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 233                     cval = (cval * 16) + (dp - hex) / 2;
 234             else if (*cp == '0')
 235                 while (*cp && strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 236                     cval = (cval * 8) + (*cp++ - '0');
 237             else
 238                 while (*cp && (strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 239                     cval = (cval * 10) + (*cp++ - '0');
 240         }
 241         else if (*cp == '\\')           /* C-style character escapes */
 242         {
 243             switch (*++cp)
 244             {
 245             case '\n': cp++; continue;  /* backslash before LF to join lines */
 246             case '\0': goto done;          /* ignore backslash at file end */
 247             case '\\': cval = '\\'; break;
 248             case 'n': cval = '\n'; break;
 249             case 't': cval = '\t'; break;
 250             case 'b': cval = '\b'; break;
 251             case 'r': cval = '\r'; break;
 252             default: cval = *cp;
 253             }
 254             cp++;
 255         }
 256         else
 257             cval = *cp++;
 258         *tp++ = cval;
 259     }
 260 done:
 261     *tp = '\0';
 262 }