Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8 #include <string.h>
   9
  10 #include "config.h"
  11 #include "fetchmail.h"
  12 #include "rcfile_y.h"
  13
  14 int prc_lineno = 1;
  15
  16 #ifdef LEXDEBUG
  17 #define SETSTATE(n)     if (yydebug) do {BEGIN(n); fprintf(stderr, "Entering lexer state %d\n", n);} while (0)
  18 #else
  19 #define SETSTATE(n)     BEGIN(n)
  20 #endif /* LEXDEBUG */
  21 %}
  22
  23 /* this doesn't work with Linux lex, see the INSTALL file */
  24 %o 7000
  25 %a 4000
  26 %p 3000
  27
  28 %s NAME PREAUTH
  29
  30 %%
  31
  32 \"[^\"]*\"      {
  33                         char buf[MSGBUFSIZE];
  34
  35                         yytext[strlen(yytext)-1] = '\0';
  36                         escapes(yytext+1, buf);
  37                         yylval.sval = (char *) xstrdup(buf);
  38                         SETSTATE(0);
  39                         return STRING;
  40                 }
  41 \'[^\']*\'      {
  42                         char buf[MSGBUFSIZE];
  43
  44                         yytext[strlen(yytext)-1] = '\0';
  45                         escapes(yytext+1, buf);
  46                         yylval.sval = (char *) xstrdup(buf);
  47                         SETSTATE(0);
  48                         return STRING;
  49                 }
  50
  51 "*"             { BEGIN(0); return WILDCARD; }
  52
  53 <NAME>[^=;:, \t\r\n]+   {
  54                         char buf[MSGBUFSIZE];
  55
  56                         escapes(yytext, buf);
  57                         yylval.sval = (char *) xstrdup(buf);
  58                         SETSTATE(0);
  59                         return STRING;
  60                 }
  61
  62 set             { return SET; }
  63 logfile         { return LOGFILE; }
  64 idfile          { return IDFILE; }
  65 daemon          { return DAEMON; }
  66 syslog          { return SYSLOG; }
  67 invisible       { return INVISIBLE; }
  68 showdots        { return SHOWDOTS; }
  69 postmaster      { return POSTMASTER; }
  70 bouncemail      { return BOUNCEMAIL; }
  71 warnings        { return WARNINGS; }
  72
  73 defaults        { return DEFAULTS; }
  74 server          { return POLL; }
  75 poll            { return POLL; }
  76 skip            { return SKIP; }
  77 via             { return VIA; }
  78 aka             { return AKA; }
  79 local(domains)  { return LOCALDOMAINS; }
  80 proto(col)?     { return PROTOCOL; }
  81 service         { return SERVICE; }
  82 port            { return PORT; }
  83 interval        { return INTERVAL; }
  84 preauth(enticate)?      { SETSTATE(PREAUTH); return PREAUTHENTICATE; }
  85 kerberos(_v)?4  { SETSTATE(0); return KERBEROS4; }
  86 kerberos(_v)?5  { SETSTATE(0); return KERBEROS5; }
  87 kerberos        { SETSTATE(0); return KERBEROS; }
  88 ssh             { SETSTATE(0); return SSH; }
  89 <PREAUTH>password { SETSTATE(0); return PASSWORD; }
  90 timeout         { return TIMEOUT;}
  91 envelope        { return ENVELOPE; }
  92 qvirtual        { return QVIRTUAL; }
  93 principal       { return PRINCIPAL; }
  94
  95 user(name)?     {SETSTATE(NAME); return USERNAME; }
  96 pass(word)?     {SETSTATE(NAME); return PASSWORD; }
  97 folder(s)?      { return FOLDER; }
  98 smtp(host)?     { return SMTPHOST; }
  99 smtpaddress     { return SMTPADDRESS; }
 100 smtpname        { return SMTPNAME; }
 101 antispam        { return SPAMRESPONSE; }
 102 mda             { return MDA; }
 103 bsmtp           { return BSMTP; }
 104 lmtp            { return LMTP; }
 105 pre(connect)?   { return PRECONNECT; }
 106 post(connect)?  { return POSTCONNECT; }
 107 netsec          { return NETSEC; }
 108 interface       { return INTERFACE; }
 109 monitor         { return MONITOR; }
 110 plugin          { return PLUGIN; }
 111 plugout         { return PLUGOUT; }
 112 batchlimit      { return BATCHLIMIT; }
 113 fetchlimit      { return FETCHLIMIT; }
 114 expunge         { return EXPUNGE; }
 115 properties      { return PROPERTIES; }
 116
 117 is              { SETSTATE(NAME); return IS; }
 118 here            { return HERE; }
 119 there           { return THERE; }
 120 to              { SETSTATE(NAME); return TO; }
 121 =               { SETSTATE(NAME); return MAP; }
 122
 123 nobouncemail    |
 124 nouidl          |
 125 nocheckalias    |
 126 nodns           |
 127 noenvelope      |
 128 nokeep          |
 129 noflush         |
 130 nofetchall      |
 131 norewrite       |
 132 noforcecr       |
 133 nostripcr       |
 134 nopass8(bits)?  |
 135 nodropstatus    |
 136 nodropdelivered |
 137 nomimedec(ode)? |
 138 noidle          {
 139                    yyless(2);
 140                    return NO;
 141                 }
 142
 143 no              {return NO;}
 144
 145 keep            { return KEEP; }
 146 flush           { return FLUSH; }
 147 fetchall        { return FETCHALL; }
 148 rewrite         { return REWRITE; }
 149 forcecr         { return FORCECR; }
 150 stripcr         { return STRIPCR; }
 151 pass8(bits)?    { return PASS8BITS; }
 152 dropstatus      { return DROPSTATUS; }
 153 dropdelivered   { return DROPDELIVERED; }
 154 mimedec(ode)?   { return MIMEDECODE; }
 155 idle            { return IDLE; }
 156 dns             { return DNS; }
 157 uidl            { return UIDL; }
 158 ssl             { return SSL; }
 159 sslkey          { return SSLKEY; }
 160 sslcert         { return SSLCERT; }
 161 checkalias      { return CHECKALIAS; }
 162
 163 limit           { return LIMIT; }
 164
 165 with            {/* EMPTY */}
 166 and             {/* EMPTY */}
 167 has             {/* EMPTY */}
 168 wants           {/* EMPTY */}
 169 options         {/* EMPTY */}
 170 [;:,]           {/* EMPTY */}
 171
 172 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
 173 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
 174 (sdps)|(SDPS)   { return SDPS; }
 175 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
 176 (imap-k4)|(IMAP-K4)   { yylval.proto = P_IMAP_K4;  return PROTO; }
 177 (imap-gss)|(IMAP-GSS) { yylval.proto = P_IMAP_GSS;  return PROTO; }
 178 (imap-crammd5)|(IMAP-CRAMMD5) { yylval.proto = P_IMAP_CRAM_MD5;  return PROTO; }
 179 (imap-login)|(IMAP-LOGIN) { yylval.proto = P_IMAP_LOGIN;  return PROTO; }
 180 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
 181 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
 182 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
 183 (kpop)|(KPOP)   { return KPOP; }
 184
 185 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 186
 187 -?[0-9]+/[^a-zA-Z]      { yylval.number = atoi(yytext); return NUMBER; }
 188
 189 [^=;:, \t\r\n]+ {
 190                         char buf[MSGBUFSIZE];
 191
 192                         escapes(yytext, buf);
 193                         yylval.sval = (char *) xstrdup(buf);
 194                         return STRING;
 195                 }
 196
 197 [ \t\r]+        ;       /* whitespace */
 198
 199 %%
 200
 201 void escapes(cp, tp)
 202 /* process standard C-style escape sequences in a string */
 203 const char      *cp;    /* source string with escapes */
 204 char            *tp;    /* target buffer for digested string */
 205 {
 206     while (*cp)
 207     {
 208         int     cval = 0;
 209
 210         if (*cp == '\\' && strchr("0123456789xX", cp[1]))
 211         {
 212             char *dp;
 213             const char *hex = "00112233445566778899aAbBcCdDeEfF";
 214             int dcount = 0;
 215
 216             if (*++cp == 'x' || *cp == 'X')
 217                 for (++cp; (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 218                     cval = (cval * 16) + (dp - hex) / 2;
 219             else if (*cp == '0')
 220                 while (strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 221                     cval = (cval * 8) + (*cp++ - '0');
 222             else
 223                 while ((strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 224                     cval = (cval * 10) + (*cp++ - '0');
 225         }
 226         else if (*cp == '\\')           /* C-style character escapes */
 227         {
 228             switch (*++cp)
 229             {
 230             case '\\': cval = '\\'; break;
 231             case 'n': cval = '\n'; break;
 232             case 't': cval = '\t'; break;
 233             case 'b': cval = '\b'; break;
 234             case 'r': cval = '\r'; break;
 235             default: cval = *cp;
 236             }
 237             cp++;
 238         }
 239         else
 240             cval = *cp++;
 241         *tp++ = cval;
 242     }
 243     *tp = '\0';
 244 }
 245