Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8 #include <string.h>
   9
  10 #include "config.h"
  11 #include "fetchmail.h"
  12 #include "rcfile_y.h"
  13
  14 int prc_lineno = 1;
  15
  16 #ifdef LEXDEBUG
  17 #define SETSTATE(n)     if (yydebug) do {BEGIN(n); fprintf(stderr, "Entering lexer state %d\n", n);} while (0)
  18 #else
  19 #define SETSTATE(n)     BEGIN(n)
  20 #endif /* LEXDEBUG */
  21 %}
  22
  23 /* this doesn't work with Linux lex, see the INSTALL file */
  24 %o 7000
  25 %a 4000
  26 %p 3000
  27
  28 %s NAME PREAUTH
  29
  30 %%
  31
  32 \"[^\"]*\"      {
  33                         char buf[MSGBUFSIZE];
  34
  35                         yytext[strlen(yytext)-1] = '\0';
  36                         escapes(yytext+1, buf);
  37                         yylval.sval = (char *) xstrdup(buf);
  38                         SETSTATE(0);
  39                         return STRING;
  40                 }
  41 \'[^\']*\'      {
  42                         char buf[MSGBUFSIZE];
  43
  44                         yytext[strlen(yytext)-1] = '\0';
  45                         escapes(yytext+1, buf);
  46                         yylval.sval = (char *) xstrdup(buf);
  47                         SETSTATE(0);
  48                         return STRING;
  49                 }
  50
  51 "*"             { BEGIN(0); return WILDCARD; }
  52
  53 <NAME>[^=;:, \t\r\n]+   {
  54                         char buf[MSGBUFSIZE];
  55
  56                         escapes(yytext, buf);
  57                         yylval.sval = (char *) xstrdup(buf);
  58                         SETSTATE(0);
  59                         return STRING;
  60                 }
  61
  62 set             { return SET; }
  63 logfile         { return LOGFILE; }
  64 idfile          { return IDFILE; }
  65 daemon          { return DAEMON; }
  66 syslog          { return SYSLOG; }
  67 invisible       { return INVISIBLE; }
  68 showdots        { return SHOWDOTS; }
  69 postmaster      { return POSTMASTER; }
  70 bouncemail      { return BOUNCEMAIL; }
  71 spambounce      { return SPAMBOUNCE; }
  72 warnings        { return WARNINGS; }
  73
  74 defaults        { return DEFAULTS; }
  75 server          { return POLL; }
  76 poll            { return POLL; }
  77 skip            { return SKIP; }
  78 via             { return VIA; }
  79 aka             { return AKA; }
  80 local(domains)  { return LOCALDOMAINS; }
  81 proto(col)?     { return PROTOCOL; }
  82 service         { return SERVICE; }
  83 port            { return PORT; }
  84 interval        { return INTERVAL; }
  85 preauth(enticate)?      { SETSTATE(PREAUTH); return PREAUTHENTICATE; }
  86 kerberos(_v)?4  { SETSTATE(0); return KERBEROS4; }
  87 kerberos(_v)?5  { SETSTATE(0); return KERBEROS5; }
  88 kerberos        { SETSTATE(0); return KERBEROS; }
  89 ssh             { SETSTATE(0); return SSH; }
  90 <PREAUTH>password { SETSTATE(0); return PASSWORD; }
  91 timeout         { return TIMEOUT;}
  92 envelope        { return ENVELOPE; }
  93 qvirtual        { return QVIRTUAL; }
  94 principal       { return PRINCIPAL; }
  95
  96 user(name)?     {SETSTATE(NAME); return USERNAME; }
  97 pass(word)?     {SETSTATE(NAME); return PASSWORD; }
  98 folder(s)?      { return FOLDER; }
  99 smtp(host)?     { return SMTPHOST; }
 100 smtpaddress     { return SMTPADDRESS; }
 101 smtpname        { return SMTPNAME; }
 102 antispam        { return SPAMRESPONSE; }
 103 mda             { return MDA; }
 104 bsmtp           { return BSMTP; }
 105 lmtp            { return LMTP; }
 106 pre(connect)?   { return PRECONNECT; }
 107 post(connect)?  { return POSTCONNECT; }
 108 netsec          { return NETSEC; }
 109 interface       { return INTERFACE; }
 110 monitor         { return MONITOR; }
 111 plugin          { return PLUGIN; }
 112 plugout         { return PLUGOUT; }
 113 batchlimit      { return BATCHLIMIT; }
 114 fetchlimit      { return FETCHLIMIT; }
 115 expunge         { return EXPUNGE; }
 116 properties      { return PROPERTIES; }
 117
 118 is              { SETSTATE(NAME); return IS; }
 119 here            { return HERE; }
 120 there           { return THERE; }
 121 to              { SETSTATE(NAME); return TO; }
 122 =               { SETSTATE(NAME); return MAP; }
 123
 124 nobouncemail    |
 125 nouidl          |
 126 nocheckalias    |
 127 nodns           |
 128 noenvelope      |
 129 nokeep          |
 130 noflush         |
 131 nofetchall      |
 132 norewrite       |
 133 noforcecr       |
 134 nostripcr       |
 135 nopass8(bits)?  |
 136 nodropstatus    |
 137 nodropdelivered |
 138 nomimedec(ode)? |
 139 noidle          {
 140                    yyless(2);
 141                    return NO;
 142                 }
 143
 144 no              {return NO;}
 145
 146 keep            { return KEEP; }
 147 flush           { return FLUSH; }
 148 fetchall        { return FETCHALL; }
 149 rewrite         { return REWRITE; }
 150 forcecr         { return FORCECR; }
 151 stripcr         { return STRIPCR; }
 152 pass8(bits)?    { return PASS8BITS; }
 153 dropstatus      { return DROPSTATUS; }
 154 dropdelivered   { return DROPDELIVERED; }
 155 mimedec(ode)?   { return MIMEDECODE; }
 156 idle            { return IDLE; }
 157 dns             { return DNS; }
 158 uidl            { return UIDL; }
 159 ssl             { return SSL; }
 160 sslkey          { return SSLKEY; }
 161 sslcert         { return SSLCERT; }
 162 checkalias      { return CHECKALIAS; }
 163
 164 limit           { return LIMIT; }
 165
 166 with            {/* EMPTY */}
 167 and             {/* EMPTY */}
 168 has             {/* EMPTY */}
 169 wants           {/* EMPTY */}
 170 options         {/* EMPTY */}
 171 [;:,]           {/* EMPTY */}
 172
 173 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
 174 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
 175 (sdps)|(SDPS)   { return SDPS; }
 176 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
 177 (imap-k4)|(IMAP-K4)   { yylval.proto = P_IMAP_K4;  return PROTO; }
 178 (imap-gss)|(IMAP-GSS) { yylval.proto = P_IMAP_GSS;  return PROTO; }
 179 (imap-crammd5)|(IMAP-CRAMMD5) { yylval.proto = P_IMAP_CRAM_MD5;  return PROTO; }
 180 (imap-login)|(IMAP-LOGIN) { yylval.proto = P_IMAP_LOGIN;  return PROTO; }
 181 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
 182 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
 183 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
 184 (kpop)|(KPOP)   { return KPOP; }
 185
 186 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 187
 188 -?[0-9]+/[^a-zA-Z]      { yylval.number = atoi(yytext); return NUMBER; }
 189
 190 [^=;:, \t\r\n]+ {
 191                         char buf[MSGBUFSIZE];
 192
 193                         escapes(yytext, buf);
 194                         yylval.sval = (char *) xstrdup(buf);
 195                         return STRING;
 196                 }
 197
 198 [ \t\r]+        ;       /* whitespace */
 199
 200 %%
 201
 202 void escapes(cp, tp)
 203 /* process standard C-style escape sequences in a string */
 204 const char      *cp;    /* source string with escapes */
 205 char            *tp;    /* target buffer for digested string */
 206 {
 207     while (*cp)
 208     {
 209         int     cval = 0;
 210
 211         if (*cp == '\\' && strchr("0123456789xX", cp[1]))
 212         {
 213             char *dp;
 214             const char *hex = "00112233445566778899aAbBcCdDeEfF";
 215             int dcount = 0;
 216
 217             if (*++cp == 'x' || *cp == 'X')
 218                 for (++cp; (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 219                     cval = (cval * 16) + (dp - hex) / 2;
 220             else if (*cp == '0')
 221                 while (strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 222                     cval = (cval * 8) + (*cp++ - '0');
 223             else
 224                 while ((strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 225                     cval = (cval * 10) + (*cp++ - '0');
 226         }
 227         else if (*cp == '\\')           /* C-style character escapes */
 228         {
 229             switch (*++cp)
 230             {
 231             case '\\': cval = '\\'; break;
 232             case 'n': cval = '\n'; break;
 233             case 't': cval = '\t'; break;
 234             case 'b': cval = '\b'; break;
 235             case 'r': cval = '\r'; break;
 236             default: cval = *cp;
 237             }
 238             cp++;
 239         }
 240         else
 241             cval = *cp++;
 242         *tp++ = cval;
 243     }
 244     *tp = '\0';
 245 }
 246