Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %top{
   2 #include "config.h"
   3 }
   4
   5 %{
   6
   7 /*
   8  * rcfile_l.l -- lexer for the run control file, to be used with GNU flex.
   9  *
  10  * For license terms, see the file COPYING in this directory.
  11  */
  12 #include <string.h>
  13
  14 #include "fetchmail.h"
  15 #include "xmalloc.h"
  16 #include "rcfile_y.h"
  17
  18 int prc_lineno = 1;
  19
  20 #ifdef LEXDEBUG
  21 #define SETSTATE(n)     do {BEGIN(n); if (yydebug) fprintf(stderr, "Entering lexer state %d\n", n);} while (0)
  22 #else
  23 #define SETSTATE(n)     BEGIN(n)
  24 #endif /* LEXDEBUG */
  25
  26 #define YY_NO_INPUT
  27
  28 /* #define this to emit STRING pointers and contents to stderr while lexing.
  29  * Useful with ASan/LSan (address/leak sanitizer) and its
  30  * LSAN_OPTIONS=report_objects=1 to identify where the leaked strings go. */
  31 #undef STRING_DEBUG
  32
  33 #ifdef __cplusplus
  34 extern "C"
  35 #endif
  36 int yywrap(void) { return 1; }
  37
  38 %}
  39
  40 %option nounput yywrap warn nodefault 8bit batch
  41
  42 %s NAME AUTH
  43
  44 %%
  45
  46 \"[^\"]*\"      |
  47 \'[^\']*\'      {
  48                         char *in = xstrndup(yytext+1, yyleng-2);
  49                         escapes(in, in);
  50                         yylval.sval = in;
  51                         SETSTATE(0);
  52 #ifdef STRING_DEBUG
  53                         fprintf(stderr, "STRING1: %p %s\n", in, in);
  54 #endif
  55                         return STRING;
  56                 }
  57
  58 <NAME>[^=;:, \t\r\n]+   {
  59                         char *in = xstrdup(yytext);
  60                         escapes(in, in);
  61                         yylval.sval = in;
  62                         SETSTATE(0);
  63 #ifdef STRING_DEBUG
  64                         fprintf(stderr, "STRING2: %p %s\n", in, in);
  65 #endif
  66                         return STRING;
  67                 }
  68
  69 set             { return SET; }
  70 logfile         { return LOGFILE; }
  71 idfile          { return IDFILE; }
  72 pidfile         { return PIDFILE; }
  73 daemon          { return DAEMON; }
  74 syslog          { return SYSLOG; }
  75 invisible       { return INVISIBLE; }
  76 showdots        { return SHOWDOTS; }
  77 postmaster      { return POSTMASTER; }
  78 bouncemail      { return BOUNCEMAIL; }
  79 spambounce      { return SPAMBOUNCE; }
  80 softbounce      { return SOFTBOUNCE; }
  81 warnings        { return WARNINGS; }
  82 tracepolls      { return TRACEPOLLS; }
  83
  84 defaults        { return DEFAULTS; }
  85 server          { return POLL; }
  86 poll            { return POLL; }
  87 skip            { return SKIP; }
  88 via             { return VIA; }
  89 aka             { return AKA; }
  90 local(domains)? { return LOCALDOMAINS; }
  91 proto(col)?     { return PROTOCOL; }
  92 service         { return SERVICE; }
  93 port            { return PORT; }
  94 interval        { return INTERVAL; }
  95 preauth(enticate)?      { SETSTATE(AUTH); return AUTHENTICATE; }
  96 auth(enticate)? { SETSTATE(AUTH); return AUTHENTICATE; }
  97 any             { SETSTATE(0); yylval.proto = A_ANY; return AUTHTYPE;}
  98 gssapi          { SETSTATE(0); yylval.proto = A_GSSAPI; return AUTHTYPE;}
  99 kerberos(_v)?4  { SETSTATE(0); yylval.proto = A_KERBEROS_V4; return AUTHTYPE;}
 100 kerberos(_v)?5  { SETSTATE(0); yylval.proto = A_KERBEROS_V5; return AUTHTYPE;}
 101 kerberos        { SETSTATE(0); yylval.proto = A_KERBEROS_V4; return AUTHTYPE;}
 102 ssh             { SETSTATE(0); yylval.proto = A_SSH; return AUTHTYPE;}
 103 external        { SETSTATE(0); yylval.proto = A_EXTERNAL; return AUTHTYPE;}
 104 (otp|opie)      { SETSTATE(0); yylval.proto = A_OTP; return AUTHTYPE;}
 105 cram(-md5)?     { SETSTATE(0); yylval.proto = A_CRAM_MD5; return AUTHTYPE;}
 106 msn             { SETSTATE(0); yylval.proto = A_MSN; return AUTHTYPE;}
 107 ntlm            { SETSTATE(0); yylval.proto = A_NTLM; return AUTHTYPE;}
 108 <AUTH>password  { SETSTATE(0); yylval.proto = A_PASSWORD; return AUTHTYPE;}
 109 timeout         { return TIMEOUT;}
 110 envelope        { return ENVELOPE; }
 111 qvirtual        { return QVIRTUAL; }
 112 principal       { return PRINCIPAL; }
 113 esmtpname       { return ESMTPNAME; }
 114 esmtppassword   { return ESMTPPASSWORD; }
 115 bad-header      { return BADHEADER; }
 116 accept          { return ACCEPT; }
 117 reject          { return REJECT_; }
 118
 119 user(name)?     {SETSTATE(NAME); return USERNAME; }
 120 <INITIAL,NAME>pass(word)?       {SETSTATE(NAME); return PASSWORD; }
 121 folder(s)?      { return FOLDER; }
 122 smtp(host)?     { return SMTPHOST; }
 123 fetchdomains    { return FETCHDOMAINS; }
 124 smtpaddress     { return SMTPADDRESS; }
 125 smtpname        { return SMTPNAME; }
 126 antispam        { return SPAMRESPONSE; }
 127 mda             { return MDA; }
 128 bsmtp           { return BSMTP; }
 129 lmtp            { return LMTP; }
 130 pre(connect)?   { return PRECONNECT; }
 131 post(connect)?  { return POSTCONNECT; }
 132 interface       { return INTERFACE; }
 133 monitor         { return MONITOR; }
 134 plugin          { return PLUGIN; }
 135 plugout         { return PLUGOUT; }
 136 batchlimit      { return BATCHLIMIT; }
 137 fetchlimit      { return FETCHLIMIT; }
 138 fetchsizelimit  { return FETCHSIZELIMIT; }
 139 fastuidl        { return FASTUIDL; }
 140 expunge         { return EXPUNGE; }
 141 properties      { return PROPERTIES; }
 142
 143 is              { SETSTATE(NAME); return IS; }
 144 here            { return HERE; }
 145 there           { return THERE; }
 146 to              { SETSTATE(NAME); return TO; }
 147 =               { SETSTATE(NAME); return MAP; }
 148
 149 nobouncemail    |
 150 nouidl          |
 151 nocheckalias    |
 152 nodns           |
 153 noenvelope      |
 154 nokeep          |
 155 noflush         |
 156 nolimitflush    |
 157 nofetchall      |
 158 norewrite       |
 159 noforcecr       |
 160 nostripcr       |
 161 nopass8(bits)?  |
 162 nodropstatus    |
 163 nodropdelivered |
 164 nomimedec(ode)? |
 165 nospambounce    |
 166 noidle          {
 167                    yyless(2);
 168                    return NO;
 169                 }
 170
 171 no              {return NO;}
 172
 173 keep            { return KEEP; }
 174 flush           { return FLUSH; }
 175 limitflush      { return LIMITFLUSH; }
 176 fetchall        { return FETCHALL; }
 177 rewrite         { return REWRITE; }
 178 forcecr         { return FORCECR; }
 179 stripcr         { return STRIPCR; }
 180 pass8(bits)?    { return PASS8BITS; }
 181 dropstatus      { return DROPSTATUS; }
 182 dropdelivered   { return DROPDELIVERED; }
 183 mimedec(ode)?   { return MIMEDECODE; }
 184 idle            { return IDLE; }
 185 dns             { return DNS; }
 186 uidl            { return UIDL; }
 187 ssl             { return SSL; }
 188 sslkey          { return SSLKEY; }
 189 sslcert         { return SSLCERT; }
 190 sslproto        { return SSLPROTO; }
 191 sslcertck       { return SSLCERTCK; }
 192 sslcertfile     { return SSLCERTFILE; }
 193 sslcertpath     { return SSLCERTPATH; }
 194 sslcommonname   { return SSLCOMMONNAME; }
 195 sslfingerprint  { return SSLFINGERPRINT; }
 196 checkalias      { return CHECKALIAS; }
 197
 198 limit           { return LIMIT; }
 199
 200 with            {/* EMPTY */}
 201 and             {/* EMPTY */}
 202 has             {/* EMPTY */}
 203 wants           {/* EMPTY */}
 204 options         {/* EMPTY */}
 205 [;:,]           {/* EMPTY */}
 206
 207 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
 208 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
 209 (sdps)|(SDPS)   { return SDPS; }
 210 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
 211 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
 212 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
 213 (rpop)|(RPOP)   { yylval.proto = P_RPOP;  return PROTO; }
 214 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
 215 (odmr)|(ODMR)   { yylval.proto = P_ODMR;  return PROTO; }
 216 (kpop)|(KPOP)   { return KPOP; }
 217
 218 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 219
 220 -?[0-9]+        { yylval.number = atoi(yytext); return NUMBER; }
 221
 222 [^=;:, \t\r\n]+ {
 223                         char *in = xstrdup(yytext);
 224                         escapes(in, in);
 225                         yylval.sval = in;
 226 #ifdef STRING_DEBUG
 227                         fprintf(stderr, "STRING3: %p %s\n", in, in);
 228 #endif
 229                         return STRING;
 230                 }
 231
 232 [ \t\r]+        ;       /* whitespace */
 233
 234 %%
 235
 236 /** process standard C-style escape sequences in a string,
 237  * this can never lengthen the output, so cp and tp may overlap as long
 238  * as cp >= tp. */
 239 void escapes(const char *cp /** source string with escapes */,
 240              char       *tp /** target buffer for digested string */)
 241 {
 242     while (*cp)
 243     {
 244         int     cval = 0;
 245
 246         /* we MUST check for NUL explicitly, as strchr(string, 0) will
 247          * always succeed! */
 248         if (*cp == '\\' && cp[1] && strchr("0123456789xX", cp[1]))
 249         {
 250             const char *dp;
 251             const char *hex = "00112233445566778899aAbBcCdDeEfF";
 252             int dcount = 0;
 253
 254             if (*++cp == 'x' || *cp == 'X')
 255                 for (++cp; *cp && (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 256                     cval = (cval * 16) + (dp - hex) / 2;
 257             else if (*cp == '0')
 258                 while (*cp && strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 259                     cval = (cval * 8) + (*cp++ - '0');
 260             else
 261                 while (*cp && (strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 262                     cval = (cval * 10) + (*cp++ - '0');
 263         }
 264         else if (*cp == '\\')           /* C-style character escapes */
 265         {
 266             switch (*++cp)
 267             {
 268             case '\n': cp++; continue;  /* backslash before LF to join lines */
 269             case '\0': goto done;          /* ignore backslash at file end */
 270             case '\\': cval = '\\'; break;
 271             case 'n': cval = '\n'; break;
 272             case 't': cval = '\t'; break;
 273             case 'b': cval = '\b'; break;
 274             case 'r': cval = '\r'; break;
 275             default: cval = *cp;
 276             }
 277             cp++;
 278         }
 279         else
 280             cval = *cp++;
 281         *tp++ = cval;
 282     }
 283 done:
 284     *tp = '\0';
 285 }