Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8 #include <string.h>
   9
  10 #include "config.h"
  11 #include "fetchmail.h"
  12 #include "rcfile_y.h"
  13
  14 int prc_lineno = 1;
  15 %}
  16
  17 /* this doesn't work with Linux lex, see the INSTALL file */
  18 %o 7000
  19 %a 4000
  20 %p 3000
  21
  22 %s NAME
  23
  24 %%
  25
  26 \"[^\"]*\"      {
  27                         char buf[MSGBUFSIZE];
  28
  29                         yytext[strlen(yytext)-1] = '\0';
  30                         escapes(yytext+1, buf);
  31                         yylval.sval = (char *) xstrdup(buf);
  32                         BEGIN(0);
  33                         return STRING;
  34                 }
  35 \'[^\']*\'      {
  36                         char buf[MSGBUFSIZE];
  37
  38                         yytext[strlen(yytext)-1] = '\0';
  39                         escapes(yytext+1, buf);
  40                         yylval.sval = (char *) xstrdup(buf);
  41                         BEGIN(0);
  42                         return STRING;
  43                 }
  44
  45 <NAME>[^=;:, \t\r\n]+   {
  46                         char buf[MSGBUFSIZE];
  47
  48                         escapes(yytext, buf);
  49                         yylval.sval = (char *) xstrdup(buf);
  50                         BEGIN(0);
  51                         return STRING;
  52                 }
  53
  54 set             { return SET; }
  55 logfile         { return LOGFILE; }
  56 idfile          { return IDFILE; }
  57 daemon          { return DAEMON; }
  58 syslog          { return SYSLOG; }
  59 invisible       { return INVISIBLE; }
  60 postmaster      { return POSTMASTER; }
  61 bouncemail      { return BOUNCEMAIL; }
  62 warnings        { return WARNINGS; }
  63
  64 defaults        { return DEFAULTS; }
  65 server          { return POLL; }
  66 poll            { return POLL; }
  67 skip            { return SKIP; }
  68 via             { return VIA; }
  69 aka             { return AKA; }
  70 local(domains)  { return LOCALDOMAINS; }
  71 proto(col)?     { return PROTOCOL; }
  72 service         { return SERVICE; }
  73 port            { return PORT; }
  74 interval        { return INTERVAL; }
  75 auth(enticate)? { return AUTHENTICATE; }
  76 kerberos(_v)?4  { return KERBEROS4; }
  77 kerberos(_v)?5  { return KERBEROS5; }
  78 kerberos        { return KERBEROS; }
  79 timeout         { return TIMEOUT;}
  80 envelope        { return ENVELOPE; }
  81 qvirtual        { return QVIRTUAL; }
  82
  83 user(name)?     {BEGIN(NAME); return USERNAME; }
  84 pass(word)?     {BEGIN(NAME); return PASSWORD; }
  85 folder(s)?      { return FOLDER; }
  86 smtp(host)?     { return SMTPHOST; }
  87 smtpaddress     { return SMTPADDRESS; }
  88 antispam        { return SPAMRESPONSE; }
  89 mda             { return MDA; }
  90 bsmtp           { return BSMTP; }
  91 lmtp            { return LMTP; }
  92 pre(connect)?   { return PRECONNECT; }
  93 post(connect)?  { return POSTCONNECT; }
  94 netsec          { return NETSEC; }
  95 interface       { return INTERFACE; }
  96 monitor         { return MONITOR; }
  97 plugin          { return PLUGIN; }
  98 plugout         { return PLUGIN; }
  99 batchlimit      { return BATCHLIMIT; }
 100 fetchlimit      { return FETCHLIMIT; }
 101 expunge         { return EXPUNGE; }
 102 properties      { return PROPERTIES; }
 103
 104 is              { BEGIN(NAME); return IS; }
 105 here            { return HERE; }
 106 there           { return THERE; }
 107 to              { BEGIN(NAME); return TO; }
 108 =               { BEGIN(NAME); return MAP; }
 109 "*"             { BEGIN(0); return WILDCARD; }
 110
 111 nobouncemail    |
 112 nouidl          |
 113 nocheckalias    |
 114 nodns           |
 115 noenvelope      |
 116 nokeep          |
 117 noflush         |
 118 nofetchall      |
 119 norewrite       |
 120 noforcecr       |
 121 nostripcr       |
 122 nopass8(bits)?  |
 123 nodropstatus    |
 124 nomimedec(ode)? {
 125                    yyless(2);
 126                    return NO;
 127                 }
 128
 129 no              {return NO;}
 130
 131 keep            { return KEEP; }
 132 flush           { return FLUSH; }
 133 fetchall        { return FETCHALL; }
 134 rewrite         { return REWRITE; }
 135 forcecr         { return FORCECR; }
 136 stripcr         { return STRIPCR; }
 137 pass8(bits)?    { return PASS8BITS; }
 138 dropstatus      { return DROPSTATUS; }
 139 mimedec(ode)?   { return MIMEDECODE; }
 140 dns             { return DNS; }
 141 uidl            { return UIDL; }
 142 checkalias      { return CHECKALIAS; }
 143
 144 limit           { return LIMIT; }
 145
 146 with            {/* EMPTY */}
 147 and             {/* EMPTY */}
 148 has             {/* EMPTY */}
 149 wants           {/* EMPTY */}
 150 options         {/* EMPTY */}
 151 [;:,]           {/* EMPTY */}
 152
 153 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
 154 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
 155 (sdps)|(SDPS)   { return SDPS; }
 156 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
 157 (imap-k4)|(IMAP-K4)   { yylval.proto = P_IMAP_K4;  return PROTO; }
 158 (imap-gss)|(IMAP-GSS) { yylval.proto = P_IMAP_GSS;  return PROTO; }
 159 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
 160 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
 161 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
 162 (kpop)|(KPOP)   { return KPOP; }
 163
 164 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 165
 166 [0-9]+          { yylval.number = atoi(yytext); return NUMBER; }
 167
 168 [^=;:, \t\r\n]+ {
 169                         char buf[MSGBUFSIZE];
 170
 171                         escapes(yytext, buf);
 172                         yylval.sval = (char *) xstrdup(buf);
 173                         return STRING;
 174                 }
 175
 176 [ \t\r]+        ;       /* whitespace */
 177
 178 %%
 179
 180 void escapes(cp, tp)
 181 /* process standard C-style escape sequences in a string */
 182 const char      *cp;    /* source string with escapes */
 183 char            *tp;    /* target buffer for digested string */
 184 {
 185     while (*cp)
 186     {
 187         int     cval = 0;
 188
 189         if (*cp == '\\' && strchr("0123456789xX", cp[1]))
 190         {
 191             char *dp;
 192             const char *hex = "00112233445566778899aAbBcCdDeEfF";
 193             int dcount = 0;
 194
 195             if (*++cp == 'x' || *cp == 'X')
 196                 for (++cp; (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 197                     cval = (cval * 16) + (dp - hex) / 2;
 198             else if (*cp == '0')
 199                 while (strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 200                     cval = (cval * 8) + (*cp++ - '0');
 201             else
 202                 while ((strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 203                     cval = (cval * 10) + (*cp++ - '0');
 204         }
 205         else if (*cp == '\\')           /* C-style character escapes */
 206         {
 207             switch (*++cp)
 208             {
 209             case '\\': cval = '\\'; break;
 210             case 'n': cval = '\n'; break;
 211             case 't': cval = '\t'; break;
 212             case 'b': cval = '\b'; break;
 213             case 'r': cval = '\r'; break;
 214             default: cval = *cp;
 215             }
 216             cp++;
 217         }
 218         else
 219             cval = *cp++;
 220         *tp++ = cval;
 221     }
 222     *tp = '\0';
 223 }
 224