Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8 #include <string.h>
   9
  10 #include "config.h"
  11 #include "fetchmail.h"
  12 #include "rcfile_y.h"
  13
  14 int prc_lineno = 1;
  15 %}
  16
  17 /* this doesn't work with Linux lex, see the INSTALL file */
  18 %o 6000
  19 %a 4000
  20
  21 %%
  22
  23 set             { return SET; }
  24 logfile         { return LOGFILE; }
  25 daemon          { return DAEMON; }
  26 syslog          { return SYSLOG; }
  27
  28 defaults        { return DEFAULTS; }
  29 server          { return POLL; }
  30 poll            { return POLL; }
  31 skip            { return SKIP; }
  32 via             { return VIA; }
  33 aka             { return AKA; }
  34 local(domains)  { return LOCALDOMAINS; }
  35 proto(col)?     { return PROTOCOL; }
  36 port            { return PORT; }
  37 interval        { return INTERVAL; }
  38 auth(enticate)? { return AUTHENTICATE; }
  39 kerberos_v4     { return KERBEROS4; }
  40 kerberos        { return KERBEROS4; }
  41 timeout         { return TIMEOUT;}
  42 envelope        { return ENVELOPE; }
  43 qvirtual        { return QVIRTUAL; }
  44
  45 user(name)?     { return USERNAME; }
  46 pass(word)?     { return PASSWORD; }
  47 folder(s)?      { return FOLDER; }
  48 smtp(host)?     { return SMTPHOST; }
  49 mda             { return MDA; }
  50 pre(connect)?   { return PRECONNECT; }
  51 post(connect)?  { return POSTCONNECT; }
  52 interface       { return INTERFACE; }
  53 monitor         { return MONITOR; }
  54 batchlimit      { return BATCHLIMIT; }
  55 fetchlimit      { return FETCHLIMIT; }
  56 expunge         { return EXPUNGE; }
  57
  58 is              { return IS; }
  59 here            { return HERE; }
  60 there           { return THERE; }
  61 to              { return TO; }
  62 =               { return MAP; }
  63 "*"             { return WILDCARD; }
  64
  65 no/[kfrsdu \t].*        { return NO;}
  66
  67 keep            { return KEEP; }
  68 flush           { return FLUSH; }
  69 fetchall        { return FETCHALL; }
  70 rewrite         { return REWRITE; }
  71 forcecr         { return FORCECR; }
  72 stripcr         { return STRIPCR; }
  73 pass8(bits)?    { return PASS8BITS; }
  74 dropstatus?     { return DROPSTATUS; }
  75 dns             { return DNS; }
  76 uidl            { return UIDL; }
  77
  78 limit           { return LIMIT; }
  79
  80 with            {/* EMPTY */}
  81 and             {/* EMPTY */}
  82 has             {/* EMPTY */}
  83 wants           {/* EMPTY */}
  84 options         {/* EMPTY */}
  85 [;:,]           {/* EMPTY */}
  86
  87 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
  88 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
  89 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
  90 (imap-k4)|(IMAP-K4)   { yylval.proto = P_IMAP_K4;  return PROTO; }
  91 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
  92 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
  93 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
  94 (kpop)|(KPOP)   { return KPOP; }
  95
  96 remote(folder)? {
  97                 fprintf(stderr,
  98                         "fetchmail: `remote' keyword is gone, use `folder'\n");
  99                 }
 100
 101
 102 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 103
 104 [0-9]+          { yylval.number = atoi(yytext); return NUMBER; }
 105
 106 \"[^\"]*\"      {
 107                         char buf[POPBUFSIZE];
 108
 109                         yytext[strlen(yytext)-1] = '\0';
 110                         escapes(yytext+1, buf);
 111                         yylval.sval = (char *) xstrdup(buf);
 112                         return STRING;
 113                 }
 114 [^=;:, \t\r\n]+ {
 115                         char buf[POPBUFSIZE];
 116
 117                         escapes(yytext, buf);
 118                         yylval.sval = (char *) xstrdup(buf);
 119                         return STRING;
 120                 }
 121
 122 [ \t\r]+        ;       /* whitespace */
 123
 124 %%
 125
 126 void escapes(cp, tp)
 127 /* process standard C-style escape sequences in a string */
 128 const char      *cp;    /* source string with escapes */
 129 char            *tp;    /* target buffer for digested string */
 130 {
 131     while (*cp)
 132     {
 133         int     cval = 0;
 134
 135         if (*cp == '\\' && strchr("0123456789xX", cp[1]))
 136         {
 137             char *dp, *hex = "00112233445566778899aAbBcCdDeEfF";
 138             int dcount = 0;
 139
 140             if (*++cp == 'x' || *cp == 'X')
 141                 for (++cp; (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 142                     cval = (cval * 16) + (dp - hex) / 2;
 143             else if (*cp == '0')
 144                 while (strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 145                     cval = (cval * 8) + (*cp++ - '0');
 146             else
 147                 while ((strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 148                     cval = (cval * 10) + (*cp++ - '0');
 149         }
 150         else if (*cp == '\\')           /* C-style character escapes */
 151         {
 152             switch (*++cp)
 153             {
 154             case '\\': cval = '\\'; break;
 155             case 'n': cval = '\n'; break;
 156             case 't': cval = '\t'; break;
 157             case 'b': cval = '\b'; break;
 158             case 'r': cval = '\r'; break;
 159             default: cval = *cp;
 160             }
 161             cp++;
 162         }
 163         else
 164             cval = *cp++;
 165         *tp++ = cval;
 166     }
 167     *tp = '\0';
 168 }
 169