Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file, to be used with GNU flex.
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8 #include <string.h>
   9
  10 #include "config.h"
  11 #include "fetchmail.h"
  12 #include "xmalloc.h"
  13 #include "rcfile_y.h"
  14
  15 int prc_lineno = 1;
  16
  17 #ifdef LEXDEBUG
  18 #define SETSTATE(n)     do {BEGIN(n); if (yydebug) fprintf(stderr, "Entering lexer state %d\n", n);} while (0)
  19 #else
  20 #define SETSTATE(n)     BEGIN(n)
  21 #endif /* LEXDEBUG */
  22
  23 #define YY_NO_INPUT
  24
  25 %}
  26
  27 %option nounput noyywrap
  28 %option warn nodefault
  29 %option 8bit batch
  30
  31 %s NAME AUTH
  32
  33 %%
  34
  35 \"[^\"]*\"      |
  36 \'[^\']*\'      {
  37                         char *in = xstrndup(yytext+1, yyleng-2);
  38                         escapes(in, in);
  39                         yylval.sval = in;
  40                         SETSTATE(0);
  41                         return STRING;
  42                 }
  43
  44 "*"             {
  45                         SETSTATE(0);
  46                         return WILDCARD;
  47                 }
  48
  49 <NAME>[^=;:, \t\r\n]+   {
  50                         char *in = xstrdup(yytext);
  51                         escapes(in, in);
  52                         yylval.sval = in;
  53                         SETSTATE(0);
  54                         return STRING;
  55                 }
  56
  57 set             { return SET; }
  58 logfile         { return LOGFILE; }
  59 idfile          { return IDFILE; }
  60 pidfile         { return PIDFILE; }
  61 daemon          { return DAEMON; }
  62 syslog          { return SYSLOG; }
  63 invisible       { return INVISIBLE; }
  64 showdots        { return SHOWDOTS; }
  65 postmaster      { return POSTMASTER; }
  66 bouncemail      { return BOUNCEMAIL; }
  67 spambounce      { return SPAMBOUNCE; }
  68 softbounce      { return SOFTBOUNCE; }
  69 warnings        { return WARNINGS; }
  70 tracepolls      { return TRACEPOLLS; }
  71
  72 defaults        { return DEFAULTS; }
  73 server          { return POLL; }
  74 poll            { return POLL; }
  75 skip            { return SKIP; }
  76 via             { return VIA; }
  77 aka             { return AKA; }
  78 local(domains)? { return LOCALDOMAINS; }
  79 proto(col)?     { return PROTOCOL; }
  80 service         { return SERVICE; }
  81 port            { return PORT; }
  82 interval        { return INTERVAL; }
  83 preauth(enticate)?      { SETSTATE(AUTH); return AUTHENTICATE; }
  84 auth(enticate)? { SETSTATE(AUTH); return AUTHENTICATE; }
  85 any             { SETSTATE(0); yylval.proto = A_ANY; return AUTHTYPE;}
  86 gssapi          { SETSTATE(0); yylval.proto = A_GSSAPI; return AUTHTYPE;}
  87 kerberos(_v)?4  { SETSTATE(0); yylval.proto = A_KERBEROS_V4; return AUTHTYPE;}
  88 kerberos(_v)?5  { SETSTATE(0); yylval.proto = A_KERBEROS_V5; return AUTHTYPE;}
  89 kerberos        { SETSTATE(0); yylval.proto = A_KERBEROS_V4; return AUTHTYPE;}
  90 ssh             { SETSTATE(0); yylval.proto = A_SSH; return AUTHTYPE;}
  91 external        { SETSTATE(0); yylval.proto = A_EXTERNAL; return AUTHTYPE;}
  92 (otp|opie)      { SETSTATE(0); yylval.proto = A_OTP; return AUTHTYPE;}
  93 cram(-md5)?     { SETSTATE(0); yylval.proto = A_CRAM_MD5; return AUTHTYPE;}
  94 msn             { SETSTATE(0); yylval.proto = A_MSN; return AUTHTYPE;}
  95 ntlm            { SETSTATE(0); yylval.proto = A_NTLM; return AUTHTYPE;}
  96 <AUTH>password  { SETSTATE(0); yylval.proto = A_PASSWORD; return AUTHTYPE;}
  97 timeout         { return TIMEOUT;}
  98 envelope        { return ENVELOPE; }
  99 qvirtual        { return QVIRTUAL; }
 100 principal       { return PRINCIPAL; }
 101 esmtpname       { return ESMTPNAME; }
 102 esmtppassword   { return ESMTPPASSWORD; }
 103 bad-header      { return BADHEADER; }
 104 accept          { return ACCEPT; }
 105 reject          { return REJECT_; }
 106
 107 user(name)?     {SETSTATE(NAME); return USERNAME; }
 108 pwmd_socket     { return PWMD_SOCKET; }
 109 pwmd_file       { return PWMD_FILE; }
 110 pinentry_timeout        { return PINENTRY_TIMEOUT; }
 111 <INITIAL,NAME>pass(word)?       {SETSTATE(NAME); return PASSWORD; }
 112 folder(s)?      { return FOLDER; }
 113 smtp(host)?     { return SMTPHOST; }
 114 fetchdomains    { return FETCHDOMAINS; }
 115 smtpaddress     { return SMTPADDRESS; }
 116 smtpname        { return SMTPNAME; }
 117 antispam        { return SPAMRESPONSE; }
 118 mda             { return MDA; }
 119 bsmtp           { return BSMTP; }
 120 lmtp            { return LMTP; }
 121 pre(connect)?   { return PRECONNECT; }
 122 post(connect)?  { return POSTCONNECT; }
 123 interface       { return INTERFACE; }
 124 monitor         { return MONITOR; }
 125 plugin          { return PLUGIN; }
 126 plugout         { return PLUGOUT; }
 127 batchlimit      { return BATCHLIMIT; }
 128 fetchlimit      { return FETCHLIMIT; }
 129 fetchsizelimit  { return FETCHSIZELIMIT; }
 130 fastuidl        { return FASTUIDL; }
 131 expunge         { return EXPUNGE; }
 132 properties      { return PROPERTIES; }
 133
 134 is              { SETSTATE(NAME); return IS; }
 135 here            { return HERE; }
 136 there           { return THERE; }
 137 to              { SETSTATE(NAME); return TO; }
 138 =               { SETSTATE(NAME); return MAP; }
 139
 140 nobouncemail    |
 141 nouidl          |
 142 nocheckalias    |
 143 nodns           |
 144 noenvelope      |
 145 nokeep          |
 146 noflush         |
 147 nolimitflush    |
 148 nofetchall      |
 149 norewrite       |
 150 noforcecr       |
 151 nostripcr       |
 152 nopass8(bits)?  |
 153 nodropstatus    |
 154 nodropdelivered |
 155 nomimedec(ode)? |
 156 nospambounce    |
 157 noidle          {
 158                    yyless(2);
 159                    return NO;
 160                 }
 161
 162 no              {return NO;}
 163
 164 keep            { return KEEP; }
 165 flush           { return FLUSH; }
 166 limitflush      { return LIMITFLUSH; }
 167 fetchall        { return FETCHALL; }
 168 rewrite         { return REWRITE; }
 169 forcecr         { return FORCECR; }
 170 stripcr         { return STRIPCR; }
 171 pass8(bits)?    { return PASS8BITS; }
 172 dropstatus      { return DROPSTATUS; }
 173 dropdelivered   { return DROPDELIVERED; }
 174 mimedec(ode)?   { return MIMEDECODE; }
 175 idle            { return IDLE; }
 176 dns             { return DNS; }
 177 uidl            { return UIDL; }
 178 ssl             { return SSL; }
 179 sslkey          { return SSLKEY; }
 180 sslcert         { return SSLCERT; }
 181 sslproto        { return SSLPROTO; }
 182 sslcertck       { return SSLCERTCK; }
 183 sslcertfile     { return SSLCERTFILE; }
 184 sslcertpath     { return SSLCERTPATH; }
 185 sslcommonname   { return SSLCOMMONNAME; }
 186 sslfingerprint  { return SSLFINGERPRINT; }
 187 checkalias      { return CHECKALIAS; }
 188
 189 limit           { return LIMIT; }
 190
 191 with            {/* EMPTY */}
 192 and             {/* EMPTY */}
 193 has             {/* EMPTY */}
 194 wants           {/* EMPTY */}
 195 options         {/* EMPTY */}
 196 [;:,]           {/* EMPTY */}
 197
 198 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
 199 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
 200 (sdps)|(SDPS)   { return SDPS; }
 201 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
 202 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
 203 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
 204 (rpop)|(RPOP)   { yylval.proto = P_RPOP;  return PROTO; }
 205 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
 206 (odmr)|(ODMR)   { yylval.proto = P_ODMR;  return PROTO; }
 207 (kpop)|(KPOP)   { return KPOP; }
 208
 209 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 210
 211 -?[0-9]+        { yylval.number = atoi(yytext); return NUMBER; }
 212
 213 [^=;:, \t\r\n]+ {
 214                         char *in = xstrdup(yytext);
 215                         escapes(in, in);
 216                         yylval.sval = in;
 217                         return STRING;
 218                 }
 219
 220 [ \t\r]+        ;       /* whitespace */
 221
 222 %%
 223
 224 /** process standard C-style escape sequences in a string,
 225  * this can never lengthen the output, so cp and tp may overlap as long
 226  * as cp >= tp. */
 227 void escapes(const char *cp /** source string with escapes */,
 228              char       *tp /** target buffer for digested string */)
 229 {
 230     while (*cp)
 231     {
 232         int     cval = 0;
 233
 234         /* we MUST check for NUL explicitly, as strchr(string, 0) will
 235          * always succeed! */
 236         if (*cp == '\\' && cp[1] && strchr("0123456789xX", cp[1]))
 237         {
 238             const char *dp;
 239             const char *hex = "00112233445566778899aAbBcCdDeEfF";
 240             int dcount = 0;
 241
 242             if (*++cp == 'x' || *cp == 'X')
 243                 for (++cp; *cp && (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 244                     cval = (cval * 16) + (dp - hex) / 2;
 245             else if (*cp == '0')
 246                 while (*cp && strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 247                     cval = (cval * 8) + (*cp++ - '0');
 248             else
 249                 while (*cp && (strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 250                     cval = (cval * 10) + (*cp++ - '0');
 251         }
 252         else if (*cp == '\\')           /* C-style character escapes */
 253         {
 254             switch (*++cp)
 255             {
 256             case '\n': cp++; continue;  /* backslash before LF to join lines */
 257             case '\0': goto done;          /* ignore backslash at file end */
 258             case '\\': cval = '\\'; break;
 259             case 'n': cval = '\n'; break;
 260             case 't': cval = '\t'; break;
 261             case 'b': cval = '\b'; break;
 262             case 'r': cval = '\r'; break;
 263             default: cval = *cp;
 264             }
 265             cp++;
 266         }
 267         else
 268             cval = *cp++;
 269         *tp++ = cval;
 270     }
 271 done:
 272     *tp = '\0';
 273 }