Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8 #include <string.h>
   9
  10 #include "config.h"
  11 #include "fetchmail.h"
  12 #include "rcfile_y.h"
  13
  14 int prc_lineno = 1;
  15 %}
  16
  17 /* this doesn't work with Linux lex, see the INSTALL file */
  18 %o 6000
  19 %a 4000
  20
  21 %%
  22
  23 set             { return SET; }
  24 batchlimit      { return BATCHLIMIT; }
  25 fetchlimit      { return FETCHLIMIT; }
  26 logfile         { return LOGFILE; }
  27 daemon          { return DAEMON; }
  28 syslog          { return SYSLOG; }
  29
  30 defaults        { return DEFAULTS; }
  31 server          { return POLL; }
  32 poll            { return POLL; }
  33 skip            { return SKIP; }
  34 via             { return VIA; }
  35 aka             { return AKA; }
  36 local(domains)  { return LOCALDOMAINS; }
  37 proto(col)?     { return PROTOCOL; }
  38 port            { return PORT; }
  39 interval        { return INTERVAL; }
  40 auth(enticate)? { return AUTHENTICATE; }
  41 kerberos_v4     { return KERBEROS4; }
  42 kerberos        { return KERBEROS4; }
  43 timeout         { return TIMEOUT;}
  44 envelope        { return ENVELOPE; }
  45
  46 user(name)?     { return USERNAME; }
  47 pass(word)?     { return PASSWORD; }
  48 folder(s)?      { return FOLDER; }
  49 smtp(host)?     { return SMTPHOST; }
  50 mda             { return MDA; }
  51 pre(connect)?   { return PRECONNECT; }
  52 post(connect)?  { return POSTCONNECT; }
  53 interface       { return INTERFACE; }
  54 monitor         { return MONITOR; }
  55
  56 is              { return IS; }
  57 here            { return HERE; }
  58 there           { return THERE; }
  59 to              { return TO; }
  60 =               { return MAP; }
  61 "*"             { return WILDCARD; }
  62
  63 no/[kfrsdu \t].*        { return NO;}
  64
  65 keep            { return KEEP; }
  66 flush           { return FLUSH; }
  67 fetchall        { return FETCHALL; }
  68 rewrite         { return REWRITE; }
  69 forcecr         { return FORCECR; }
  70 stripcr         { return STRIPCR; }
  71 pass8(bits)?    { return PASS8BITS; }
  72 dropstatus?     { return DROPSTATUS; }
  73 dns             { return DNS; }
  74 uidl            { return UIDL; }
  75
  76 limit           { return LIMIT; }
  77
  78 with            {/* EMPTY */}
  79 and             {/* EMPTY */}
  80 has             {/* EMPTY */}
  81 wants           {/* EMPTY */}
  82 options         {/* EMPTY */}
  83 [;:,]           {/* EMPTY */}
  84
  85 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
  86 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
  87 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
  88 (imap-k4)|(IMAP-K4)   { yylval.proto = P_IMAP_K4;  return PROTO; }
  89 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
  90 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
  91 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
  92 (kpop)|(KPOP)   { return KPOP; }
  93
  94 remote(folder)? {
  95                 fprintf(stderr,
  96                         "fetchmail: `remote' keyword is gone, use `folder'\n");
  97                 }
  98
  99
 100 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 101
 102 [0-9]+          { yylval.number = atoi(yytext); return NUMBER; }
 103
 104 \"[^\"]*\"      {
 105                         char buf[POPBUFSIZE];
 106
 107                         yytext[strlen(yytext)-1] = '\0';
 108                         escapes(yytext+1, buf);
 109                         yylval.sval = (char *) xstrdup(buf);
 110                         return STRING;
 111                 }
 112 [^=;:, \t\r\n]+ {
 113                         char buf[POPBUFSIZE];
 114
 115                         escapes(yytext, buf);
 116                         yylval.sval = (char *) xstrdup(buf);
 117                         return STRING;
 118                 }
 119
 120 [ \t\r]+        ;       /* whitespace */
 121
 122 %%
 123
 124 void escapes(cp, tp)
 125 /* process standard C-style escape sequences in a string */
 126 const char      *cp;    /* source string with escapes */
 127 char            *tp;    /* target buffer for digested string */
 128 {
 129     while (*cp)
 130     {
 131         int     cval = 0;
 132
 133         if (*cp == '\\' && strchr("0123456789xX", cp[1]))
 134         {
 135             char *dp, *hex = "00112233445566778899aAbBcCdDeEfF";
 136             int dcount = 0;
 137
 138             if (*++cp == 'x' || *cp == 'X')
 139                 for (++cp; (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 140                     cval = (cval * 16) + (dp - hex) / 2;
 141             else if (*cp == '0')
 142                 while (strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 143                     cval = (cval * 8) + (*cp++ - '0');
 144             else
 145                 while ((strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 146                     cval = (cval * 10) + (*cp++ - '0');
 147         }
 148         else if (*cp == '\\')           /* C-style character escapes */
 149         {
 150             switch (*++cp)
 151             {
 152             case '\\': cval = '\\'; break;
 153             case 'n': cval = '\n'; break;
 154             case 't': cval = '\t'; break;
 155             case 'b': cval = '\b'; break;
 156             case 'r': cval = '\r'; break;
 157             default: cval = *cp;
 158             }
 159             cp++;
 160         }
 161         else
 162             cval = *cp++;
 163         *tp++ = cval;
 164     }
 165     *tp = '\0';
 166 }
 167