Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file, to be used with GNU flex.
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8
   9 #include "config.h"
  10 #include "fetchmail.h"
  11 #include "xmalloc.h"
  12 #include "rcfile_y.h"
  13
  14 #include <string.h>
  15
  16 int prc_lineno = 1;
  17
  18 #ifdef LEXDEBUG
  19 #define SETSTATE(n)     do {BEGIN(n); if (yydebug) fprintf(stderr, "Entering lexer state %d\n", n);} while (0)
  20 #else
  21 #define SETSTATE(n)     BEGIN(n)
  22 #endif /* LEXDEBUG */
  23
  24 #define YY_NO_INPUT
  25
  26 %}
  27
  28 %option nounput noyywrap
  29 %option warn nodefault
  30 %option 8bit batch
  31
  32 %s NAME AUTH
  33
  34 %%
  35
  36 \"[^\"]*\"      |
  37 \'[^\']*\'      {
  38                         char *in = xstrndup(yytext+1, yyleng-2);
  39                         escapes(in, in);
  40                         yylval.sval = in;
  41                         SETSTATE(0);
  42                         return STRING;
  43                 }
  44
  45 <NAME>[^=;:, \t\r\n]+   {
  46                         char *in = xstrdup(yytext);
  47                         escapes(in, in);
  48                         yylval.sval = in;
  49                         SETSTATE(0);
  50                         return STRING;
  51                 }
  52
  53 set             { return SET; }
  54 logfile         { return LOGFILE; }
  55 idfile          { return IDFILE; }
  56 pidfile         { return PIDFILE; }
  57 daemon          { return DAEMON; }
  58 syslog          { return SYSLOG; }
  59 invisible       { return INVISIBLE; }
  60 showdots        { return SHOWDOTS; }
  61 postmaster      { return POSTMASTER; }
  62 bouncemail      { return BOUNCEMAIL; }
  63 spambounce      { return SPAMBOUNCE; }
  64 softbounce      { return SOFTBOUNCE; }
  65 warnings        { return WARNINGS; }
  66 tracepolls      { return TRACEPOLLS; }
  67
  68 defaults        { return DEFAULTS; }
  69 server          { return POLL; }
  70 poll            { return POLL; }
  71 skip            { return SKIP; }
  72 via             { return VIA; }
  73 aka             { return AKA; }
  74 local(domains)? { return LOCALDOMAINS; }
  75 proto(col)?     { return PROTOCOL; }
  76 service         { return SERVICE; }
  77 port            { return PORT; }
  78 interval        { return INTERVAL; }
  79 preauth(enticate)?      { SETSTATE(AUTH); return AUTHENTICATE; }
  80 auth(enticate)? { SETSTATE(AUTH); return AUTHENTICATE; }
  81 any             { SETSTATE(0); yylval.proto = A_ANY; return AUTHTYPE;}
  82 gssapi          { SETSTATE(0); yylval.proto = A_GSSAPI; return AUTHTYPE;}
  83 kerberos(_v)?5  { SETSTATE(0); yylval.proto = A_KERBEROS_V5; return AUTHTYPE;}
  84 kerberos        { SETSTATE(0); yylval.proto = A_KERBEROS_V5; return AUTHTYPE;}
  85 ssh             { SETSTATE(0); yylval.proto = A_SSH; return AUTHTYPE;}
  86 external        { SETSTATE(0); yylval.proto = A_EXTERNAL; return AUTHTYPE;}
  87 (otp|opie)      { SETSTATE(0); yylval.proto = A_OTP; return AUTHTYPE;}
  88 cram(-md5)?     { SETSTATE(0); yylval.proto = A_CRAM_MD5; return AUTHTYPE;}
  89 msn             { SETSTATE(0); yylval.proto = A_MSN; return AUTHTYPE;}
  90 ntlm            { SETSTATE(0); yylval.proto = A_NTLM; return AUTHTYPE;}
  91 <AUTH>password  { SETSTATE(0); yylval.proto = A_PASSWORD; return AUTHTYPE;}
  92 timeout         { return TIMEOUT;}
  93 envelope        { return ENVELOPE; }
  94 qvirtual        { return QVIRTUAL; }
  95 principal       { return PRINCIPAL; }
  96 esmtpname       { return ESMTPNAME; }
  97 esmtppassword   { return ESMTPPASSWORD; }
  98 bad-header      { return BADHEADER; }
  99 accept          { return ACCEPT; }
 100 reject          { return REJECT_; }
 101 retrieve-error  { return RETRIEVEERROR; }
 102 abort           { return ABORT; }
 103 continue        { return CONTINUE; }
 104 markseen        { return MARKSEEN; }
 105
 106 user(name)?     {SETSTATE(NAME); return USERNAME; }
 107 <INITIAL,NAME>pass(word)?       {SETSTATE(NAME); return PASSWORD; }
 108 folder(s)?      { return FOLDER; }
 109 smtp(host)?     { return SMTPHOST; }
 110 fetchdomains    { return FETCHDOMAINS; }
 111 smtpaddress     { return SMTPADDRESS; }
 112 smtpname        { return SMTPNAME; }
 113 antispam        { return SPAMRESPONSE; }
 114 mda             { return MDA; }
 115 bsmtp           { return BSMTP; }
 116 lmtp            { return LMTP; }
 117 pre(connect)?   { return PRECONNECT; }
 118 post(connect)?  { return POSTCONNECT; }
 119 interface       { return INTERFACE; }
 120 monitor         { return MONITOR; }
 121 plugin          { return PLUGIN; }
 122 plugout         { return PLUGOUT; }
 123 batchlimit      { return BATCHLIMIT; }
 124 fetchlimit      { return FETCHLIMIT; }
 125 fetchsizelimit  { return FETCHSIZELIMIT; }
 126 fastuidl        { return FASTUIDL; }
 127 expunge         { return EXPUNGE; }
 128 properties      { return PROPERTIES; }
 129
 130 is              { SETSTATE(NAME); return IS; }
 131 here            { return HERE; }
 132 there           { return THERE; }
 133 to              { SETSTATE(NAME); return TO; }
 134 =               { SETSTATE(NAME); return MAP; }
 135
 136 nobouncemail    |
 137 nouidl          |
 138 nocheckalias    |
 139 nodns           |
 140 noenvelope      |
 141 nokeep          |
 142 noflush         |
 143 nolimitflush    |
 144 nofetchall      |
 145 norewrite       |
 146 noforcecr       |
 147 nostripcr       |
 148 nopass8(bits)?  |
 149 nodropstatus    |
 150 nodropdelivered |
 151 nomimedec(ode)? |
 152 nospambounce    |
 153 noidle          {
 154                    yyless(2);
 155                    return NO;
 156                 }
 157
 158 no              {return NO;}
 159
 160 keep            { return KEEP; }
 161 flush           { return FLUSH; }
 162 limitflush      { return LIMITFLUSH; }
 163 fetchall        { return FETCHALL; }
 164 rewrite         { return REWRITE; }
 165 forcecr         { return FORCECR; }
 166 stripcr         { return STRIPCR; }
 167 pass8(bits)?    { return PASS8BITS; }
 168 dropstatus      { return DROPSTATUS; }
 169 dropdelivered   { return DROPDELIVERED; }
 170 mimedec(ode)?   { return MIMEDECODE; }
 171 idle            { return IDLE; }
 172 dns             { return DNS; }
 173 uidl            { return UIDL; }
 174 ssl             { return SSL; }
 175 sslkey          { return SSLKEY; }
 176 sslcert         { return SSLCERT; }
 177 sslproto        { return SSLPROTO; }
 178 sslcertck       { return SSLCERTCK; }
 179 sslcertfile     { return SSLCERTFILE; }
 180 sslcertpath     { return SSLCERTPATH; }
 181 sslcommonname   { return SSLCOMMONNAME; }
 182 sslfingerprint  { return SSLFINGERPRINT; }
 183 checkalias      { return CHECKALIAS; }
 184
 185 limit           { return LIMIT; }
 186
 187 with            {/* EMPTY */}
 188 and             {/* EMPTY */}
 189 has             {/* EMPTY */}
 190 wants           {/* EMPTY */}
 191 options         {/* EMPTY */}
 192 [;:,]           {/* EMPTY */}
 193
 194 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
 195 (sdps)|(SDPS)   { return SDPS; }
 196 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
 197 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
 198 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
 199 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
 200 (odmr)|(ODMR)   { yylval.proto = P_ODMR;  return PROTO; }
 201 (kpop)|(KPOP)   { return KPOP; }
 202
 203 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 204
 205 -?[0-9]+        { yylval.number = atoi(yytext); return NUMBER; }
 206
 207 [^=;:, \t\r\n]+ {
 208                         char *in = xstrdup(yytext);
 209                         escapes(in, in);
 210                         yylval.sval = in;
 211                         return STRING;
 212                 }
 213
 214 [ \t\r]+        ;       /* whitespace */
 215
 216 %%
 217
 218 /** process standard C-style escape sequences in a string,
 219  * this can never lengthen the output, so cp and tp may overlap as long
 220  * as cp >= tp. */
 221 void escapes(const char *cp /** source string with escapes */,
 222              char       *tp /** target buffer for digested string */)
 223 {
 224     while (*cp)
 225     {
 226         int     cval = 0;
 227
 228         /* we MUST check for NUL explicitly, as strchr(string, 0) will
 229          * always succeed! */
 230         if (*cp == '\\' && cp[1] && strchr("0123456789xX", cp[1]))
 231         {
 232             const char *dp;
 233             const char *hex = "00112233445566778899aAbBcCdDeEfF";
 234             int dcount = 0;
 235
 236             if (*++cp == 'x' || *cp == 'X')
 237                 for (++cp; *cp && (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 238                     cval = (cval * 16) + (dp - hex) / 2;
 239             else if (*cp == '0')
 240                 while (*cp && strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 241                     cval = (cval * 8) + (*cp++ - '0');
 242             else
 243                 while (*cp && (strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 244                     cval = (cval * 10) + (*cp++ - '0');
 245         }
 246         else if (*cp == '\\')           /* C-style character escapes */
 247         {
 248             switch (*++cp)
 249             {
 250             case '\n': cp++; continue;  /* backslash before LF to join lines */
 251             case '\0': goto done;          /* ignore backslash at file end */
 252             case '\\': cval = '\\'; break;
 253             case 'n': cval = '\n'; break;
 254             case 't': cval = '\t'; break;
 255             case 'b': cval = '\b'; break;
 256             case 'r': cval = '\r'; break;
 257             default: cval = *cp;
 258             }
 259             cp++;
 260         }
 261         else
 262             cval = *cp++;
 263         *tp++ = cval;
 264     }
 265 done:
 266     *tp = '\0';
 267 }