Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8 #include <string.h>
   9
  10 #include "config.h"
  11 #include "fetchmail.h"
  12 #include "rcfile_y.h"
  13
  14 int prc_lineno = 1;
  15
  16 #ifdef LEXDEBUG
  17 #define SETSTATE(n)     do {BEGIN(n); if (yydebug) fprintf(stderr, "Entering lexer state %d\n", n);} while (0)
  18 #else
  19 #define SETSTATE(n)     BEGIN(n)
  20 #endif /* LEXDEBUG */
  21
  22 %}
  23
  24 /* this doesn't work with Linux lex, see the INSTALL file */
  25 %o 7000
  26 %a 4000
  27 %p 3000
  28 %option nounput noyywrap
  29
  30 %s NAME AUTH
  31
  32 %%
  33
  34 \"[^\"]*\"      {
  35                         yytext[yyleng-1] = '\0';
  36                         escapes(yytext+1, yytext);
  37                         yyleng = strlen(yytext);
  38                         yylval.sval = yytext;
  39                         SETSTATE(0);
  40                         return STRING;
  41                 }
  42 \'[^\']*\'      {
  43                         yytext[yyleng-1] = '\0';
  44                         escapes(yytext+1, yytext);
  45                         yyleng = strlen(yytext);
  46                         yylval.sval = yytext;
  47                         SETSTATE(0);
  48                         return STRING;
  49                 }
  50
  51 "*"             { BEGIN(0); return WILDCARD; }
  52
  53 <NAME>[^=;:, \t\r\n]+   {
  54                         static char *in;
  55                         static size_t ins;
  56
  57                         if ((size_t)yyleng + 1 > ins) {
  58                             ins = yyleng + 1;
  59                             in = (char *)xrealloc(in, ins);
  60                         }
  61                         memcpy(in, yytext, yyleng);
  62                         in[yyleng] = '\0';
  63                         escapes(in, in);
  64                         yyleng = strlen(in);
  65                         yylval.sval = in;
  66                         SETSTATE(0);
  67                         return STRING;
  68                 }
  69
  70 set             { return SET; }
  71 logfile         { return LOGFILE; }
  72 idfile          { return IDFILE; }
  73 pidfile         { return PIDFILE; }
  74 daemon          { return DAEMON; }
  75 syslog          { return SYSLOG; }
  76 invisible       { return INVISIBLE; }
  77 showdots        { return SHOWDOTS; }
  78 postmaster      { return POSTMASTER; }
  79 bouncemail      { return BOUNCEMAIL; }
  80 spambounce      { return SPAMBOUNCE; }
  81 softbounce      { return SOFTBOUNCE; }
  82 warnings        { return WARNINGS; }
  83 tracepolls      { return TRACEPOLLS; }
  84
  85 defaults        { return DEFAULTS; }
  86 server          { return POLL; }
  87 poll            { return POLL; }
  88 skip            { return SKIP; }
  89 via             { return VIA; }
  90 aka             { return AKA; }
  91 local(domains)  { return LOCALDOMAINS; }
  92 proto(col)?     { return PROTOCOL; }
  93 service         { return SERVICE; }
  94 port            { return PORT; }
  95 interval        { return INTERVAL; }
  96 preauth(enticate)?      { SETSTATE(AUTH); return AUTHENTICATE; }
  97 auth(enticate)? { SETSTATE(AUTH); return AUTHENTICATE; }
  98 any             { SETSTATE(0); yylval.proto = A_ANY; return AUTHTYPE;}
  99 gssapi          { SETSTATE(0); yylval.proto = A_GSSAPI; return AUTHTYPE;}
 100 kerberos(_v)?4  { SETSTATE(0); yylval.proto = A_KERBEROS_V4; return AUTHTYPE;}
 101 kerberos(_v)?5  { SETSTATE(0); yylval.proto = A_KERBEROS_V5; return AUTHTYPE;}
 102 kerberos        { SETSTATE(0); yylval.proto = A_KERBEROS_V4; return AUTHTYPE;}
 103 ssh             { SETSTATE(0); yylval.proto = A_SSH; return AUTHTYPE;}
 104 external        { SETSTATE(0); yylval.proto = A_EXTERNAL; return AUTHTYPE;}
 105 (otp|opie)      { SETSTATE(0); yylval.proto = A_OTP; return AUTHTYPE;}
 106 cram(-md5)?     { SETSTATE(0); yylval.proto = A_CRAM_MD5; return AUTHTYPE;}
 107 msn             { SETSTATE(0); yylval.proto = A_MSN; return AUTHTYPE;}
 108 ntlm            { SETSTATE(0); yylval.proto = A_NTLM; return AUTHTYPE;}
 109 <AUTH>password  { SETSTATE(0); yylval.proto = A_PASSWORD; return AUTHTYPE;}
 110 timeout         { return TIMEOUT;}
 111 envelope        { return ENVELOPE; }
 112 qvirtual        { return QVIRTUAL; }
 113 principal       { return PRINCIPAL; }
 114 esmtpname       { return ESMTPNAME; }
 115 esmtppassword   { return ESMTPPASSWORD; }
 116
 117
 118 user(name)?     {SETSTATE(NAME); return USERNAME; }
 119 <INITIAL,NAME>pass(word)?       {SETSTATE(NAME); return PASSWORD; }
 120 folder(s)?      { return FOLDER; }
 121 smtp(host)?     { return SMTPHOST; }
 122 fetchdomains    { return FETCHDOMAINS; }
 123 smtpaddress     { return SMTPADDRESS; }
 124 smtpname        { return SMTPNAME; }
 125 antispam        { return SPAMRESPONSE; }
 126 mda             { return MDA; }
 127 bsmtp           { return BSMTP; }
 128 lmtp            { return LMTP; }
 129 pre(connect)?   { return PRECONNECT; }
 130 post(connect)?  { return POSTCONNECT; }
 131 interface       { return INTERFACE; }
 132 monitor         { return MONITOR; }
 133 plugin          { return PLUGIN; }
 134 plugout         { return PLUGOUT; }
 135 batchlimit      { return BATCHLIMIT; }
 136 fetchlimit      { return FETCHLIMIT; }
 137 fetchsizelimit  { return FETCHSIZELIMIT; }
 138 fastuidl        { return FASTUIDL; }
 139 expunge         { return EXPUNGE; }
 140 properties      { return PROPERTIES; }
 141
 142 is              { SETSTATE(NAME); return IS; }
 143 here            { return HERE; }
 144 there           { return THERE; }
 145 to              { SETSTATE(NAME); return TO; }
 146 =               { SETSTATE(NAME); return MAP; }
 147
 148 nobouncemail    |
 149 nouidl          |
 150 nocheckalias    |
 151 nodns           |
 152 noenvelope      |
 153 nokeep          |
 154 noflush         |
 155 nolimitflush    |
 156 nofetchall      |
 157 norewrite       |
 158 noforcecr       |
 159 nostripcr       |
 160 nopass8(bits)?  |
 161 nodropstatus    |
 162 nodropdelivered |
 163 nomimedec(ode)? |
 164 nospambounce    |
 165 noidle          {
 166                    yyless(2);
 167                    return NO;
 168                 }
 169
 170 no              {return NO;}
 171
 172 keep            { return KEEP; }
 173 flush           { return FLUSH; }
 174 limitflush      { return LIMITFLUSH; }
 175 fetchall        { return FETCHALL; }
 176 rewrite         { return REWRITE; }
 177 forcecr         { return FORCECR; }
 178 stripcr         { return STRIPCR; }
 179 pass8(bits)?    { return PASS8BITS; }
 180 dropstatus      { return DROPSTATUS; }
 181 dropdelivered   { return DROPDELIVERED; }
 182 mimedec(ode)?   { return MIMEDECODE; }
 183 idle            { return IDLE; }
 184 dns             { return DNS; }
 185 uidl            { return UIDL; }
 186 ssl             { return SSL; }
 187 sslkey          { return SSLKEY; }
 188 sslcert         { return SSLCERT; }
 189 sslproto        { return SSLPROTO; }
 190 sslcertck       { return SSLCERTCK; }
 191 sslcertpath     { return SSLCERTPATH; }
 192 sslcommonname   { return SSLCOMMONNAME; }
 193 sslfingerprint  { return SSLFINGERPRINT; }
 194 checkalias      { return CHECKALIAS; }
 195
 196 limit           { return LIMIT; }
 197
 198 with            {/* EMPTY */}
 199 and             {/* EMPTY */}
 200 has             {/* EMPTY */}
 201 wants           {/* EMPTY */}
 202 options         {/* EMPTY */}
 203 [;:,]           {/* EMPTY */}
 204
 205 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
 206 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
 207 (sdps)|(SDPS)   { return SDPS; }
 208 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
 209 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
 210 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
 211 (rpop)|(RPOP)   { yylval.proto = P_RPOP;  return PROTO; }
 212 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
 213 (odmr)|(ODMR)   { yylval.proto = P_ODMR;  return PROTO; }
 214 (kpop)|(KPOP)   { return KPOP; }
 215
 216 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 217
 218 -?[0-9]+        { yylval.number = atoi(yytext); return NUMBER; }
 219
 220 [^=;:, \t\r\n]+ {
 221                         escapes(yytext, yytext);
 222                         yyleng = strlen(yytext);
 223                         yylval.sval = yytext;
 224                         return STRING;
 225                 }
 226
 227 [ \t\r]+        ;       /* whitespace */
 228
 229 %%
 230
 231 /** process standard C-style escape sequences in a string,
 232  * this can never lengthen the output, so cp and tp may overlap as long
 233  * as cp >= tp. */
 234 void escapes(const char *cp /** source string with escapes */,
 235              char       *tp /** target buffer for digested string */)
 236 {
 237     while (*cp)
 238     {
 239         int     cval = 0;
 240
 241         /* we MUST check for NUL explicitly, as strchr(string, 0) will
 242          * always succeed! */
 243         if (*cp == '\\' && cp[1] && strchr("0123456789xX", cp[1]))
 244         {
 245             char *dp;
 246             const char *hex = "00112233445566778899aAbBcCdDeEfF";
 247             int dcount = 0;
 248
 249             if (*++cp == 'x' || *cp == 'X')
 250                 for (++cp; *cp && (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 251                     cval = (cval * 16) + (dp - hex) / 2;
 252             else if (*cp == '0')
 253                 while (*cp && strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 254                     cval = (cval * 8) + (*cp++ - '0');
 255             else
 256                 while (*cp && (strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 257                     cval = (cval * 10) + (*cp++ - '0');
 258         }
 259         else if (*cp == '\\')           /* C-style character escapes */
 260         {
 261             switch (*++cp)
 262             {
 263             case '\n': cp++; continue;  /* backslash before LF to join lines */
 264             case '\0': goto done;          /* ignore backslash at file end */
 265             case '\\': cval = '\\'; break;
 266             case 'n': cval = '\n'; break;
 267             case 't': cval = '\t'; break;
 268             case 'b': cval = '\b'; break;
 269             case 'r': cval = '\r'; break;
 270             default: cval = *cp;
 271             }
 272             cp++;
 273         }
 274         else
 275             cval = *cp++;
 276         *tp++ = cval;
 277     }
 278 done:
 279     *tp = '\0';
 280 }