Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8
   9 #include "config.h"
  10 #include "fetchmail.h"
  11 #include "rcfile_y.h"
  12
  13 int prc_lineno = 1;
  14 %}
  15
  16 /* this doesn't work with Linux lex, see the INSTALL file */
  17 %o 5000
  18 %a 4000
  19
  20 %%
  21
  22 set             { return SET; }
  23 batchlimit      { return BATCHLIMIT; }
  24 fetchlimit      { return FETCHLIMIT; }
  25 logfile         { return LOGFILE; }
  26 daemon          { return DAEMON; }
  27 syslog          { return SYSLOG; }
  28
  29 defaults        { return DEFAULTS; }
  30 server          { return POLL; }
  31 poll            { return POLL; }
  32 skip            { return SKIP; }
  33 via             { return VIA; }
  34 aka             { return AKA; }
  35 local(domains)  { return LOCALDOMAINS; }
  36 proto(col)?     { return PROTOCOL; }
  37 port            { return PORT; }
  38 interval                { return INTERVAL; }
  39 auth(enticate)? { return AUTHENTICATE; }
  40 kerberos_v4     { return KERBEROS4; }
  41 kerberos        { return KERBEROS4; }
  42 timeout         { return TIMEOUT;}
  43 envelope        { return ENVELOPE; }
  44
  45 user(name)?     { return USERNAME; }
  46 pass(word)?     { return PASSWORD; }
  47 folder(s)?      { return FOLDER; }
  48 smtp(host)?     { return SMTPHOST; }
  49 mda             { return MDA; }
  50 pre(connect)?   { return PRECONNECT; }
  51 interface       { return INTERFACE; }
  52 monitor         { return MONITOR; }
  53
  54 is              { return IS; }
  55 here            { return HERE; }
  56 there           { return THERE; }
  57 to              { return TO; }
  58 =               { return MAP; }
  59 "*"             { return WILDCARD; }
  60
  61 no/[kfrsdu \t].*        { return NO;}
  62
  63 keep            { return KEEP; }
  64 flush           { return FLUSH; }
  65 fetchall        { return FETCHALL; }
  66 rewrite         { return REWRITE; }
  67 forcecr         { return FORCECR; }
  68 stripcr         { return STRIPCR; }
  69 pass8(bits)?    { return PASS8BITS; }
  70 dropstatus?     { return DROPSTATUS; }
  71 dns             { return DNS; }
  72 uidl            { return UIDL; }
  73
  74 limit           { return LIMIT; }
  75
  76 with            {/* EMPTY */}
  77 and             {/* EMPTY */}
  78 has             {/* EMPTY */}
  79 wants           {/* EMPTY */}
  80 options         {/* EMPTY */}
  81 [;:,]           {/* EMPTY */}
  82
  83 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
  84 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
  85 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
  86 (imap-k4)|(IMAP-K4)   { yylval.proto = P_IMAP_K4;  return PROTO; }
  87 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
  88 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
  89 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
  90 (kpop)|(KPOP)   { return KPOP; }
  91
  92 remote(folder)? {
  93                 fprintf(stderr,
  94                         "fetchmail: `remote' keyword is gone, use `folder'\n");
  95                 }
  96
  97
  98 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
  99
 100 [0-9]+          { yylval.number = atoi(yytext); return NUMBER; }
 101
 102 \"[^\"]*\"      {
 103                         char buf[POPBUFSIZE];
 104
 105                         yytext[strlen(yytext)-1] = '\0';
 106                         escapes(yytext+1, buf);
 107                         yylval.sval = (char *) xstrdup(buf);
 108                         return STRING;
 109                 }
 110 [^=;:, \t\r\n]+ {
 111                         char buf[POPBUFSIZE];
 112
 113                         escapes(yytext, buf);
 114                         yylval.sval = (char *) xstrdup(buf);
 115                         return STRING;
 116                 }
 117
 118 [ \t\r]+        ;       /* whitespace */
 119
 120 %%
 121 #include <string.h>
 122
 123 void escapes(cp, tp)
 124 /* process standard C-style escape sequences in a string */
 125 const char      *cp;    /* source string with escapes */
 126 char            *tp;    /* target buffer for digested string */
 127 {
 128     while (*cp)
 129     {
 130         int     cval = 0;
 131
 132         if (*cp == '\\' && strchr("0123456789xX", cp[1]))
 133         {
 134             char *dp, *hex = "00112233445566778899aAbBcCdDeEfF";
 135             int dcount = 0;
 136
 137             if (*++cp == 'x' || *cp == 'X')
 138                 for (++cp; (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 139                     cval = (cval * 16) + (dp - hex) / 2;
 140             else if (*cp == '0')
 141                 while (strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 142                     cval = (cval * 8) + (*cp++ - '0');
 143             else
 144                 while ((strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 145                     cval = (cval * 10) + (*cp++ - '0');
 146         }
 147         else if (*cp == '\\')           /* C-style character escapes */
 148         {
 149             switch (*++cp)
 150             {
 151             case '\\': cval = '\\'; break;
 152             case 'n': cval = '\n'; break;
 153             case 't': cval = '\t'; break;
 154             case 'b': cval = '\b'; break;
 155             case 'r': cval = '\r'; break;
 156             default: cval = *cp;
 157             }
 158             cp++;
 159         }
 160         else
 161             cval = *cp++;
 162         *tp++ = cval;
 163     }
 164     *tp = '\0';
 165 }
 166