Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8 #include <string.h>
   9
  10 #include "config.h"
  11 #include "fetchmail.h"
  12 #include "rcfile_y.h"
  13
  14 int prc_lineno = 1;
  15
  16 #ifdef LEXDEBUG
  17 #define SETSTATE(n)     do {BEGIN(n); if (yydebug) fprintf(stderr, "Entering lexer state %d\n", n);} while (0)
  18 #else
  19 #define SETSTATE(n)     BEGIN(n)
  20 #endif /* LEXDEBUG */
  21 %}
  22
  23 /* this doesn't work with Linux lex, see the INSTALL file */
  24 %o 7000
  25 %a 4000
  26 %p 3000
  27 %option nounput
  28
  29 %s NAME AUTH
  30
  31 %%
  32
  33 \"[^\"]*\"      {
  34                         char buf[MSGBUFSIZE];
  35
  36                         yytext[strlen(yytext)-1] = '\0';
  37                         escapes(yytext+1, buf);
  38                         yylval.sval = (char *) xstrdup(buf);
  39                         SETSTATE(0);
  40                         return STRING;
  41                 }
  42 \'[^\']*\'      {
  43                         char buf[MSGBUFSIZE];
  44
  45                         yytext[strlen(yytext)-1] = '\0';
  46                         escapes(yytext+1, buf);
  47                         yylval.sval = (char *) xstrdup(buf);
  48                         SETSTATE(0);
  49                         return STRING;
  50                 }
  51
  52 "*"             { BEGIN(0); return WILDCARD; }
  53
  54 <NAME>[^=;:, \t\r\n]+   {
  55                         char buf[MSGBUFSIZE];
  56
  57                         escapes(yytext, buf);
  58                         yylval.sval = (char *) xstrdup(buf);
  59                         SETSTATE(0);
  60                         return STRING;
  61                 }
  62
  63 set             { return SET; }
  64 logfile         { return LOGFILE; }
  65 idfile          { return IDFILE; }
  66 daemon          { return DAEMON; }
  67 syslog          { return SYSLOG; }
  68 invisible       { return INVISIBLE; }
  69 showdots        { return SHOWDOTS; }
  70 postmaster      { return POSTMASTER; }
  71 bouncemail      { return BOUNCEMAIL; }
  72 spambounce      { return SPAMBOUNCE; }
  73 warnings        { return WARNINGS; }
  74 tracepolls      { return TRACEPOLLS; }
  75
  76 defaults        { return DEFAULTS; }
  77 server          { return POLL; }
  78 poll            { return POLL; }
  79 skip            { return SKIP; }
  80 via             { return VIA; }
  81 aka             { return AKA; }
  82 local(domains)  { return LOCALDOMAINS; }
  83 proto(col)?     { return PROTOCOL; }
  84 service         { return SERVICE; }
  85 port            { return PORT; }
  86 interval        { return INTERVAL; }
  87 preauth(enticate)?      { SETSTATE(AUTH); return AUTHENTICATE; }
  88 auth(enticate)? { SETSTATE(AUTH); return AUTHENTICATE; }
  89 any             { SETSTATE(0); yylval.proto = A_ANY; return AUTHTYPE;}
  90 gssapi          { SETSTATE(0); yylval.proto = A_GSSAPI; return AUTHTYPE;}
  91 kerberos(_v)?4  { SETSTATE(0); yylval.proto = A_KERBEROS_V4; return AUTHTYPE;}
  92 kerberos(_v)?5  { SETSTATE(0); yylval.proto = A_KERBEROS_V5; return AUTHTYPE;}
  93 kerberos        { SETSTATE(0); yylval.proto = A_KERBEROS_V4; return AUTHTYPE;}
  94 ssh             { SETSTATE(0); yylval.proto = A_SSH; return AUTHTYPE;}
  95 cram(-md5)?     { SETSTATE(0); yylval.proto = A_CRAM_MD5; return AUTHTYPE;}
  96 ntlm            { SETSTATE(0); yylval.proto = A_NTLM; return AUTHTYPE;}
  97 <AUTH>password  { SETSTATE(0); yylval.proto = A_PASSWORD; return AUTHTYPE;}
  98 timeout         { return TIMEOUT;}
  99 envelope        { return ENVELOPE; }
 100 qvirtual        { return QVIRTUAL; }
 101 principal       { return PRINCIPAL; }
 102 esmtpname       { return ESMTPNAME; }
 103 esmtppassword   { return ESMTPPASSWORD; }
 104
 105
 106 user(name)?     {SETSTATE(NAME); return USERNAME; }
 107 <INITIAL,NAME>pass(word)?       {SETSTATE(NAME); return PASSWORD; }
 108 folder(s)?      { return FOLDER; }
 109 smtp(host)?     { return SMTPHOST; }
 110 fetchdomains    { return FETCHDOMAINS; }
 111 smtpaddress     { return SMTPADDRESS; }
 112 smtpname        { return SMTPNAME; }
 113 antispam        { return SPAMRESPONSE; }
 114 mda             { return MDA; }
 115 bsmtp           { return BSMTP; }
 116 lmtp            { return LMTP; }
 117 pre(connect)?   { return PRECONNECT; }
 118 post(connect)?  { return POSTCONNECT; }
 119 netsec          { return NETSEC; }
 120 interface       { return INTERFACE; }
 121 monitor         { return MONITOR; }
 122 plugin          { return PLUGIN; }
 123 plugout         { return PLUGOUT; }
 124 batchlimit      { return BATCHLIMIT; }
 125 fetchlimit      { return FETCHLIMIT; }
 126 expunge         { return EXPUNGE; }
 127 properties      { return PROPERTIES; }
 128
 129 is              { SETSTATE(NAME); return IS; }
 130 here            { return HERE; }
 131 there           { return THERE; }
 132 to              { SETSTATE(NAME); return TO; }
 133 =               { SETSTATE(NAME); return MAP; }
 134
 135 nobouncemail    |
 136 nouidl          |
 137 nocheckalias    |
 138 nodns           |
 139 noenvelope      |
 140 nokeep          |
 141 noflush         |
 142 nofetchall      |
 143 norewrite       |
 144 noforcecr       |
 145 nostripcr       |
 146 nopass8(bits)?  |
 147 nodropstatus    |
 148 nodropdelivered |
 149 nomimedec(ode)? |
 150 nospambounce    |
 151 noidle          {
 152                    yyless(2);
 153                    return NO;
 154                 }
 155
 156 no              {return NO;}
 157
 158 keep            { return KEEP; }
 159 flush           { return FLUSH; }
 160 fetchall        { return FETCHALL; }
 161 rewrite         { return REWRITE; }
 162 forcecr         { return FORCECR; }
 163 stripcr         { return STRIPCR; }
 164 pass8(bits)?    { return PASS8BITS; }
 165 dropstatus      { return DROPSTATUS; }
 166 dropdelivered   { return DROPDELIVERED; }
 167 mimedec(ode)?   { return MIMEDECODE; }
 168 idle            { return IDLE; }
 169 dns             { return DNS; }
 170 uidl            { return UIDL; }
 171 ssl             { return SSL; }
 172 sslkey          { return SSLKEY; }
 173 sslcert         { return SSLCERT; }
 174 sslproto        { return SSLPROTO; }
 175 sslcertck       { return SSLCERTCK; }
 176 sslcertpath     { return SSLCERTPATH; }
 177 sslfingerprint  { return SSLFINGERPRINT; }
 178 checkalias      { return CHECKALIAS; }
 179
 180 limit           { return LIMIT; }
 181
 182 with            {/* EMPTY */}
 183 and             {/* EMPTY */}
 184 has             {/* EMPTY */}
 185 wants           {/* EMPTY */}
 186 options         {/* EMPTY */}
 187 [;:,]           {/* EMPTY */}
 188
 189 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
 190 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
 191 (sdps)|(SDPS)   { return SDPS; }
 192 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
 193 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
 194 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
 195 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
 196 (odmr)|(ODMR)   { yylval.proto = P_ODMR;  return PROTO; }
 197 (kpop)|(KPOP)   { return KPOP; }
 198
 199 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 200
 201 -?[0-9]+/[^a-zA-Z]      { yylval.number = atoi(yytext); return NUMBER; }
 202
 203 [^=;:, \t\r\n]+ {
 204                         char buf[MSGBUFSIZE];
 205
 206                         escapes(yytext, buf);
 207                         yylval.sval = (char *) xstrdup(buf);
 208                         return STRING;
 209                 }
 210
 211 [ \t\r]+        ;       /* whitespace */
 212
 213 %%
 214
 215 void escapes(cp, tp)
 216 /* process standard C-style escape sequences in a string */
 217 const char      *cp;    /* source string with escapes */
 218 char            *tp;    /* target buffer for digested string */
 219 {
 220     while (*cp)
 221     {
 222         int     cval = 0;
 223
 224         if (*cp == '\\' && strchr("0123456789xX", cp[1]))
 225         {
 226             char *dp;
 227             const char *hex = "00112233445566778899aAbBcCdDeEfF";
 228             int dcount = 0;
 229
 230             if (*++cp == 'x' || *cp == 'X')
 231                 for (++cp; (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 232                     cval = (cval * 16) + (dp - hex) / 2;
 233             else if (*cp == '0')
 234                 while (strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 235                     cval = (cval * 8) + (*cp++ - '0');
 236             else
 237                 while ((strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 238                     cval = (cval * 10) + (*cp++ - '0');
 239         }
 240         else if (*cp == '\\')           /* C-style character escapes */
 241         {
 242             switch (*++cp)
 243             {
 244             case '\\': cval = '\\'; break;
 245             case 'n': cval = '\n'; break;
 246             case 't': cval = '\t'; break;
 247             case 'b': cval = '\b'; break;
 248             case 'r': cval = '\r'; break;
 249             default: cval = *cp;
 250             }
 251             cp++;
 252         }
 253         else
 254             cval = *cp++;
 255         *tp++ = cval;
 256     }
 257     *tp = '\0';
 258 }
 259