Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8 #include <string.h>
   9
  10 #include "config.h"
  11 #include "fetchmail.h"
  12 #include "rcfile_y.h"
  13
  14 int prc_lineno = 1;
  15 %}
  16
  17 /* this doesn't work with Linux lex, see the INSTALL file */
  18 %o 7000
  19 %a 4000
  20 %p 3000
  21
  22 %%
  23
  24 set             { return SET; }
  25 logfile         { return LOGFILE; }
  26 daemon          { return DAEMON; }
  27 syslog          { return SYSLOG; }
  28 invisible       { return INVISIBLE; }
  29
  30 defaults        { return DEFAULTS; }
  31 server          { return POLL; }
  32 poll            { return POLL; }
  33 skip            { return SKIP; }
  34 via             { return VIA; }
  35 aka             { return AKA; }
  36 local(domains)  { return LOCALDOMAINS; }
  37 proto(col)?     { return PROTOCOL; }
  38 service         { return SERVICE; }
  39 port            { return PORT; }
  40 interval        { return INTERVAL; }
  41 auth(enticate)? { return AUTHENTICATE; }
  42 kerberos_v4     { return KERBEROS4; }
  43 kerberos        { return KERBEROS4; }
  44 timeout         { return TIMEOUT;}
  45 envelope        { return ENVELOPE; }
  46 qvirtual        { return QVIRTUAL; }
  47
  48 user(name)?     { return USERNAME; }
  49 pass(word)?     { return PASSWORD; }
  50 folder(s)?      { return FOLDER; }
  51 smtp(host)?     { return SMTPHOST; }
  52 smtpaddress     { return SMTPADDRESS; }
  53 mda             { return MDA; }
  54 pre(connect)?   { return PRECONNECT; }
  55 post(connect)?  { return POSTCONNECT; }
  56 netsec          { return NETSEC; }
  57 interface       { return INTERFACE; }
  58 monitor         { return MONITOR; }
  59 batchlimit      { return BATCHLIMIT; }
  60 fetchlimit      { return FETCHLIMIT; }
  61 expunge         { return EXPUNGE; }
  62
  63 is              { return IS; }
  64 here            { return HERE; }
  65 there           { return THERE; }
  66 to              { return TO; }
  67 =               { return MAP; }
  68 "*"             { return WILDCARD; }
  69
  70 no/[kfrsdu \t].*        { return NO;}
  71
  72 keep            { return KEEP; }
  73 flush           { return FLUSH; }
  74 fetchall        { return FETCHALL; }
  75 rewrite         { return REWRITE; }
  76 forcecr         { return FORCECR; }
  77 stripcr         { return STRIPCR; }
  78 pass8(bits)?    { return PASS8BITS; }
  79 dropstatus?     { return DROPSTATUS; }
  80 dns             { return DNS; }
  81 uidl            { return UIDL; }
  82
  83 limit           { return LIMIT; }
  84
  85 with            {/* EMPTY */}
  86 and             {/* EMPTY */}
  87 has             {/* EMPTY */}
  88 wants           {/* EMPTY */}
  89 options         {/* EMPTY */}
  90 [;:,]           {/* EMPTY */}
  91
  92 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
  93 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
  94 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
  95 (imap-k4)|(IMAP-K4)   { yylval.proto = P_IMAP_K4;  return PROTO; }
  96 (imap-gss)|(IMAP-GSS) { yylval.proto = P_IMAP_GSS;  return PROTO; }
  97 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
  98 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
  99 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
 100 (kpop)|(KPOP)   { return KPOP; }
 101
 102 remote(folder)? {
 103                 fprintf(stderr,
 104                         "fetchmail: `remote' keyword is gone, use `folder'\n");
 105                 }
 106
 107
 108 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 109
 110 [0-9]+          { yylval.number = atoi(yytext); return NUMBER; }
 111
 112 \"[^\"]*\"      {
 113                         char buf[MSGBUFSIZE];
 114
 115                         yytext[strlen(yytext)-1] = '\0';
 116                         escapes(yytext+1, buf);
 117                         yylval.sval = (char *) xstrdup(buf);
 118                         return STRING;
 119                 }
 120 [^=;:, \t\r\n]+ {
 121                         char buf[MSGBUFSIZE];
 122
 123                         escapes(yytext, buf);
 124                         yylval.sval = (char *) xstrdup(buf);
 125                         return STRING;
 126                 }
 127
 128 [ \t\r]+        ;       /* whitespace */
 129
 130 %%
 131
 132 void escapes(cp, tp)
 133 /* process standard C-style escape sequences in a string */
 134 const char      *cp;    /* source string with escapes */
 135 char            *tp;    /* target buffer for digested string */
 136 {
 137     while (*cp)
 138     {
 139         int     cval = 0;
 140
 141         if (*cp == '\\' && strchr("0123456789xX", cp[1]))
 142         {
 143             char *dp, *hex = "00112233445566778899aAbBcCdDeEfF";
 144             int dcount = 0;
 145
 146             if (*++cp == 'x' || *cp == 'X')
 147                 for (++cp; (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 148                     cval = (cval * 16) + (dp - hex) / 2;
 149             else if (*cp == '0')
 150                 while (strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 151                     cval = (cval * 8) + (*cp++ - '0');
 152             else
 153                 while ((strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 154                     cval = (cval * 10) + (*cp++ - '0');
 155         }
 156         else if (*cp == '\\')           /* C-style character escapes */
 157         {
 158             switch (*++cp)
 159             {
 160             case '\\': cval = '\\'; break;
 161             case 'n': cval = '\n'; break;
 162             case 't': cval = '\t'; break;
 163             case 'b': cval = '\b'; break;
 164             case 'r': cval = '\r'; break;
 165             default: cval = *cp;
 166             }
 167             cp++;
 168         }
 169         else
 170             cval = *cp++;
 171         *tp++ = cval;
 172     }
 173     *tp = '\0';
 174 }
 175