Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file, to be used with GNU flex.
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8 #include <string.h>
   9
  10 #include "config.h"
  11 #include "fetchmail.h"
  12 #include "xmalloc.h"
  13 #include "rcfile_y.h"
  14
  15 int prc_lineno = 1;
  16
  17 #ifdef LEXDEBUG
  18 #define SETSTATE(n)     do {BEGIN(n); if (yydebug) fprintf(stderr, "Entering lexer state %d\n", n);} while (0)
  19 #else
  20 #define SETSTATE(n)     BEGIN(n)
  21 #endif /* LEXDEBUG */
  22
  23 #define YY_NO_INPUT
  24
  25 %}
  26
  27 %option nounput noyywrap
  28 %option warn nodefault
  29 %option 8bit batch
  30
  31 %s NAME AUTH
  32
  33 %%
  34
  35 \"[^\"]*\"      |
  36 \'[^\']*\'      {
  37                         char *in = xstrndup(yytext+1, yyleng-2);
  38                         escapes(in, in);
  39                         yylval.sval = in;
  40                         SETSTATE(0);
  41                         return STRING;
  42                 }
  43
  44 "*"             {
  45                         SETSTATE(0);
  46                         return WILDCARD;
  47                 }
  48
  49 <NAME>[^=;:, \t\r\n]+   {
  50                         char *in = xstrdup(yytext);
  51                         escapes(in, in);
  52                         yylval.sval = in;
  53                         SETSTATE(0);
  54                         return STRING;
  55                 }
  56
  57 set             { return SET; }
  58 logfile         { return LOGFILE; }
  59 idfile          { return IDFILE; }
  60 pidfile         { return PIDFILE; }
  61 daemon          { return DAEMON; }
  62 syslog          { return SYSLOG; }
  63 invisible       { return INVISIBLE; }
  64 showdots        { return SHOWDOTS; }
  65 postmaster      { return POSTMASTER; }
  66 bouncemail      { return BOUNCEMAIL; }
  67 spambounce      { return SPAMBOUNCE; }
  68 softbounce      { return SOFTBOUNCE; }
  69 warnings        { return WARNINGS; }
  70 tracepolls      { return TRACEPOLLS; }
  71
  72 defaults        { return DEFAULTS; }
  73 server          { return POLL; }
  74 poll            { return POLL; }
  75 skip            { return SKIP; }
  76 via             { return VIA; }
  77 aka             { return AKA; }
  78 local(domains)? { return LOCALDOMAINS; }
  79 proto(col)?     { return PROTOCOL; }
  80 service         { return SERVICE; }
  81 port            { return PORT; }
  82 interval        { return INTERVAL; }
  83 preauth(enticate)?      { SETSTATE(AUTH); return AUTHENTICATE; }
  84 auth(enticate)? { SETSTATE(AUTH); return AUTHENTICATE; }
  85 any             { SETSTATE(0); yylval.proto = A_ANY; return AUTHTYPE;}
  86 gssapi          { SETSTATE(0); yylval.proto = A_GSSAPI; return AUTHTYPE;}
  87 kerberos(_v)?4  { SETSTATE(0); yylval.proto = A_KERBEROS_V4; return AUTHTYPE;}
  88 kerberos(_v)?5  { SETSTATE(0); yylval.proto = A_KERBEROS_V5; return AUTHTYPE;}
  89 kerberos        { SETSTATE(0); yylval.proto = A_KERBEROS_V4; return AUTHTYPE;}
  90 ssh             { SETSTATE(0); yylval.proto = A_SSH; return AUTHTYPE;}
  91 external        { SETSTATE(0); yylval.proto = A_EXTERNAL; return AUTHTYPE;}
  92 (otp|opie)      { SETSTATE(0); yylval.proto = A_OTP; return AUTHTYPE;}
  93 cram(-md5)?     { SETSTATE(0); yylval.proto = A_CRAM_MD5; return AUTHTYPE;}
  94 msn             { SETSTATE(0); yylval.proto = A_MSN; return AUTHTYPE;}
  95 ntlm            { SETSTATE(0); yylval.proto = A_NTLM; return AUTHTYPE;}
  96 <AUTH>password  { SETSTATE(0); yylval.proto = A_PASSWORD; return AUTHTYPE;}
  97 timeout         { return TIMEOUT;}
  98 envelope        { return ENVELOPE; }
  99 qvirtual        { return QVIRTUAL; }
 100 principal       { return PRINCIPAL; }
 101 esmtpname       { return ESMTPNAME; }
 102 esmtppassword   { return ESMTPPASSWORD; }
 103 bad-header      { return BADHEADER; }
 104 accept          { return ACCEPT; }
 105 reject          { return REJECT_; }
 106
 107 user(name)?     {SETSTATE(NAME); return USERNAME; }
 108 <INITIAL,NAME>pass(word)?       {SETSTATE(NAME); return PASSWORD; }
 109 folder(s)?      { return FOLDER; }
 110 smtp(host)?     { return SMTPHOST; }
 111 fetchdomains    { return FETCHDOMAINS; }
 112 smtpaddress     { return SMTPADDRESS; }
 113 smtpname        { return SMTPNAME; }
 114 antispam        { return SPAMRESPONSE; }
 115 mda             { return MDA; }
 116 bsmtp           { return BSMTP; }
 117 lmtp            { return LMTP; }
 118 pre(connect)?   { return PRECONNECT; }
 119 post(connect)?  { return POSTCONNECT; }
 120 interface       { return INTERFACE; }
 121 monitor         { return MONITOR; }
 122 plugin          { return PLUGIN; }
 123 plugout         { return PLUGOUT; }
 124 batchlimit      { return BATCHLIMIT; }
 125 fetchlimit      { return FETCHLIMIT; }
 126 fetchsizelimit  { return FETCHSIZELIMIT; }
 127 fastuidl        { return FASTUIDL; }
 128 expunge         { return EXPUNGE; }
 129 properties      { return PROPERTIES; }
 130
 131 is              { SETSTATE(NAME); return IS; }
 132 here            { return HERE; }
 133 there           { return THERE; }
 134 to              { SETSTATE(NAME); return TO; }
 135 =               { SETSTATE(NAME); return MAP; }
 136
 137 nobouncemail    |
 138 nouidl          |
 139 nocheckalias    |
 140 nodns           |
 141 noenvelope      |
 142 nokeep          |
 143 noflush         |
 144 nolimitflush    |
 145 nofetchall      |
 146 norewrite       |
 147 noforcecr       |
 148 nostripcr       |
 149 nopass8(bits)?  |
 150 nodropstatus    |
 151 nodropdelivered |
 152 nomimedec(ode)? |
 153 nospambounce    |
 154 noidle          {
 155                    yyless(2);
 156                    return NO;
 157                 }
 158
 159 no              {return NO;}
 160
 161 keep            { return KEEP; }
 162 flush           { return FLUSH; }
 163 limitflush      { return LIMITFLUSH; }
 164 fetchall        { return FETCHALL; }
 165 rewrite         { return REWRITE; }
 166 forcecr         { return FORCECR; }
 167 stripcr         { return STRIPCR; }
 168 pass8(bits)?    { return PASS8BITS; }
 169 dropstatus      { return DROPSTATUS; }
 170 dropdelivered   { return DROPDELIVERED; }
 171 mimedec(ode)?   { return MIMEDECODE; }
 172 idle            { return IDLE; }
 173 dns             { return DNS; }
 174 uidl            { return UIDL; }
 175 ssl             { return SSL; }
 176 sslkey          { return SSLKEY; }
 177 sslcert         { return SSLCERT; }
 178 sslproto        { return SSLPROTO; }
 179 sslcertck       { return SSLCERTCK; }
 180 sslcertfile     { return SSLCERTFILE; }
 181 sslcertpath     { return SSLCERTPATH; }
 182 sslcommonname   { return SSLCOMMONNAME; }
 183 sslfingerprint  { return SSLFINGERPRINT; }
 184 checkalias      { return CHECKALIAS; }
 185
 186 limit           { return LIMIT; }
 187
 188 with            {/* EMPTY */}
 189 and             {/* EMPTY */}
 190 has             {/* EMPTY */}
 191 wants           {/* EMPTY */}
 192 options         {/* EMPTY */}
 193 [;:,]           {/* EMPTY */}
 194
 195 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
 196 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
 197 (sdps)|(SDPS)   { return SDPS; }
 198 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
 199 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
 200 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
 201 (rpop)|(RPOP)   { yylval.proto = P_RPOP;  return PROTO; }
 202 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
 203 (odmr)|(ODMR)   { yylval.proto = P_ODMR;  return PROTO; }
 204 (kpop)|(KPOP)   { return KPOP; }
 205
 206 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 207
 208 -?[0-9]+        { yylval.number = atoi(yytext); return NUMBER; }
 209
 210 [^=;:, \t\r\n]+ {
 211                         char *in = xstrdup(yytext);
 212                         escapes(in, in);
 213                         yylval.sval = in;
 214                         return STRING;
 215                 }
 216
 217 [ \t\r]+        ;       /* whitespace */
 218
 219 %%
 220
 221 /** process standard C-style escape sequences in a string,
 222  * this can never lengthen the output, so cp and tp may overlap as long
 223  * as cp >= tp. */
 224 void escapes(const char *cp /** source string with escapes */,
 225              char       *tp /** target buffer for digested string */)
 226 {
 227     while (*cp)
 228     {
 229         int     cval = 0;
 230
 231         /* we MUST check for NUL explicitly, as strchr(string, 0) will
 232          * always succeed! */
 233         if (*cp == '\\' && cp[1] && strchr("0123456789xX", cp[1]))
 234         {
 235             const char *dp;
 236             const char *hex = "00112233445566778899aAbBcCdDeEfF";
 237             int dcount = 0;
 238
 239             if (*++cp == 'x' || *cp == 'X')
 240                 for (++cp; *cp && (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 241                     cval = (cval * 16) + (dp - hex) / 2;
 242             else if (*cp == '0')
 243                 while (*cp && strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 244                     cval = (cval * 8) + (*cp++ - '0');
 245             else
 246                 while (*cp && (strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 247                     cval = (cval * 10) + (*cp++ - '0');
 248         }
 249         else if (*cp == '\\')           /* C-style character escapes */
 250         {
 251             switch (*++cp)
 252             {
 253             case '\n': cp++; continue;  /* backslash before LF to join lines */
 254             case '\0': goto done;          /* ignore backslash at file end */
 255             case '\\': cval = '\\'; break;
 256             case 'n': cval = '\n'; break;
 257             case 't': cval = '\t'; break;
 258             case 'b': cval = '\b'; break;
 259             case 'r': cval = '\r'; break;
 260             default: cval = *cp;
 261             }
 262             cp++;
 263         }
 264         else
 265             cval = *cp++;
 266         *tp++ = cval;
 267     }
 268 done:
 269     *tp = '\0';
 270 }