Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8 #include <string.h>
   9
  10 #include "config.h"
  11 #include "fetchmail.h"
  12 #include "rcfile_y.h"
  13
  14 int prc_lineno = 1;
  15
  16 #ifdef LEXDEBUG
  17 #define SETSTATE(n)     if (yydebug) do {BEGIN(n); fprintf(stderr, "Entering lexer state %d\n", n);} while (0)
  18 #else
  19 #define SETSTATE(n)     BEGIN(n)
  20 #endif /* LEXDEBUG */
  21 %}
  22
  23 /* this doesn't work with Linux lex, see the INSTALL file */
  24 %o 7000
  25 %a 4000
  26 %p 3000
  27
  28 %s NAME PREAUTH
  29
  30 %%
  31
  32 \"[^\"]*\"      {
  33                         char buf[MSGBUFSIZE];
  34
  35                         yytext[strlen(yytext)-1] = '\0';
  36                         escapes(yytext+1, buf);
  37                         yylval.sval = (char *) xstrdup(buf);
  38                         SETSTATE(0);
  39                         return STRING;
  40                 }
  41 \'[^\']*\'      {
  42                         char buf[MSGBUFSIZE];
  43
  44                         yytext[strlen(yytext)-1] = '\0';
  45                         escapes(yytext+1, buf);
  46                         yylval.sval = (char *) xstrdup(buf);
  47                         SETSTATE(0);
  48                         return STRING;
  49                 }
  50
  51 "*"             { BEGIN(0); return WILDCARD; }
  52
  53 <NAME>[^=;:, \t\r\n]+   {
  54                         char buf[MSGBUFSIZE];
  55
  56                         escapes(yytext, buf);
  57                         yylval.sval = (char *) xstrdup(buf);
  58                         SETSTATE(0);
  59                         return STRING;
  60                 }
  61
  62 set             { return SET; }
  63 logfile         { return LOGFILE; }
  64 idfile          { return IDFILE; }
  65 daemon          { return DAEMON; }
  66 syslog          { return SYSLOG; }
  67 invisible       { return INVISIBLE; }
  68 postmaster      { return POSTMASTER; }
  69 bouncemail      { return BOUNCEMAIL; }
  70 warnings        { return WARNINGS; }
  71
  72 defaults        { return DEFAULTS; }
  73 server          { return POLL; }
  74 poll            { return POLL; }
  75 skip            { return SKIP; }
  76 via             { return VIA; }
  77 aka             { return AKA; }
  78 local(domains)  { return LOCALDOMAINS; }
  79 proto(col)?     { return PROTOCOL; }
  80 service         { return SERVICE; }
  81 port            { return PORT; }
  82 interval        { return INTERVAL; }
  83 preauth(enticate)?      { SETSTATE(PREAUTH); return PREAUTHENTICATE; }
  84 kerberos(_v)?4  { SETSTATE(0); return KERBEROS4; }
  85 kerberos(_v)?5  { SETSTATE(0); return KERBEROS5; }
  86 kerberos        { SETSTATE(0); return KERBEROS; }
  87 ssh             { SETSTATE(0); return SSH; }
  88 <PREAUTH>password { SETSTATE(0); return PASSWORD; }
  89 timeout         { return TIMEOUT;}
  90 envelope        { return ENVELOPE; }
  91 qvirtual        { return QVIRTUAL; }
  92
  93 user(name)?     {SETSTATE(NAME); return USERNAME; }
  94 pass(word)?     {SETSTATE(NAME); return PASSWORD; }
  95 folder(s)?      { return FOLDER; }
  96 smtp(host)?     { return SMTPHOST; }
  97 smtpaddress     { return SMTPADDRESS; }
  98 antispam        { return SPAMRESPONSE; }
  99 mda             { return MDA; }
 100 bsmtp           { return BSMTP; }
 101 lmtp            { return LMTP; }
 102 pre(connect)?   { return PRECONNECT; }
 103 post(connect)?  { return POSTCONNECT; }
 104 netsec          { return NETSEC; }
 105 interface       { return INTERFACE; }
 106 monitor         { return MONITOR; }
 107 plugin          { return PLUGIN; }
 108 plugout         { return PLUGOUT; }
 109 batchlimit      { return BATCHLIMIT; }
 110 fetchlimit      { return FETCHLIMIT; }
 111 expunge         { return EXPUNGE; }
 112 properties      { return PROPERTIES; }
 113
 114 is              { SETSTATE(NAME); return IS; }
 115 here            { return HERE; }
 116 there           { return THERE; }
 117 to              { SETSTATE(NAME); return TO; }
 118 =               { SETSTATE(NAME); return MAP; }
 119
 120 nobouncemail    |
 121 nouidl          |
 122 nocheckalias    |
 123 nodns           |
 124 noenvelope      |
 125 nokeep          |
 126 noflush         |
 127 nofetchall      |
 128 norewrite       |
 129 noforcecr       |
 130 nostripcr       |
 131 nopass8(bits)?  |
 132 nodropstatus    |
 133 nomimedec(ode)? {
 134                    yyless(2);
 135                    return NO;
 136                 }
 137
 138 no              {return NO;}
 139
 140 keep            { return KEEP; }
 141 flush           { return FLUSH; }
 142 fetchall        { return FETCHALL; }
 143 rewrite         { return REWRITE; }
 144 forcecr         { return FORCECR; }
 145 stripcr         { return STRIPCR; }
 146 pass8(bits)?    { return PASS8BITS; }
 147 dropstatus      { return DROPSTATUS; }
 148 mimedec(ode)?   { return MIMEDECODE; }
 149 dns             { return DNS; }
 150 uidl            { return UIDL; }
 151 ssl             { return SSL; }
 152 sslkey          { return SSLKEY; }
 153 sslcert         { return SSLCERT; }
 154 checkalias      { return CHECKALIAS; }
 155
 156 limit           { return LIMIT; }
 157
 158 with            {/* EMPTY */}
 159 and             {/* EMPTY */}
 160 has             {/* EMPTY */}
 161 wants           {/* EMPTY */}
 162 options         {/* EMPTY */}
 163 [;:,]           {/* EMPTY */}
 164
 165 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
 166 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
 167 (sdps)|(SDPS)   { return SDPS; }
 168 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
 169 (imap-k4)|(IMAP-K4)   { yylval.proto = P_IMAP_K4;  return PROTO; }
 170 (imap-gss)|(IMAP-GSS) { yylval.proto = P_IMAP_GSS;  return PROTO; }
 171 (imap-crammd5)|(IMAP-CRAMMD5) { yylval.proto = P_IMAP_CRAM_MD5;  return PROTO; }
 172 (imap-login)|(IMAP-LOGIN) { yylval.proto = P_IMAP_LOGIN;  return PROTO; }
 173 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
 174 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
 175 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
 176 (kpop)|(KPOP)   { return KPOP; }
 177
 178 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 179
 180 -?[0-9]+/[^a-zA-Z]      { yylval.number = atoi(yytext); return NUMBER; }
 181
 182 [^=;:, \t\r\n]+ {
 183                         char buf[MSGBUFSIZE];
 184
 185                         escapes(yytext, buf);
 186                         yylval.sval = (char *) xstrdup(buf);
 187                         return STRING;
 188                 }
 189
 190 [ \t\r]+        ;       /* whitespace */
 191
 192 %%
 193
 194 void escapes(cp, tp)
 195 /* process standard C-style escape sequences in a string */
 196 const char      *cp;    /* source string with escapes */
 197 char            *tp;    /* target buffer for digested string */
 198 {
 199     while (*cp)
 200     {
 201         int     cval = 0;
 202
 203         if (*cp == '\\' && strchr("0123456789xX", cp[1]))
 204         {
 205             char *dp;
 206             const char *hex = "00112233445566778899aAbBcCdDeEfF";
 207             int dcount = 0;
 208
 209             if (*++cp == 'x' || *cp == 'X')
 210                 for (++cp; (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 211                     cval = (cval * 16) + (dp - hex) / 2;
 212             else if (*cp == '0')
 213                 while (strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 214                     cval = (cval * 8) + (*cp++ - '0');
 215             else
 216                 while ((strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 217                     cval = (cval * 10) + (*cp++ - '0');
 218         }
 219         else if (*cp == '\\')           /* C-style character escapes */
 220         {
 221             switch (*++cp)
 222             {
 223             case '\\': cval = '\\'; break;
 224             case 'n': cval = '\n'; break;
 225             case 't': cval = '\t'; break;
 226             case 'b': cval = '\b'; break;
 227             case 'r': cval = '\r'; break;
 228             default: cval = *cp;
 229             }
 230             cp++;
 231         }
 232         else
 233             cval = *cp++;
 234         *tp++ = cval;
 235     }
 236     *tp = '\0';
 237 }
 238