Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8 #include <string.h>
   9
  10 #include "config.h"
  11 #include "fetchmail.h"
  12 #include "rcfile_y.h"
  13
  14 int prc_lineno = 1;
  15 %}
  16
  17 /* this doesn't work with Linux lex, see the INSTALL file */
  18 %o 6000
  19 %a 4000
  20 %p 3000
  21
  22 %%
  23
  24 set             { return SET; }
  25 logfile         { return LOGFILE; }
  26 daemon          { return DAEMON; }
  27 syslog          { return SYSLOG; }
  28 invisible       { return INVISIBLE; }
  29
  30 defaults        { return DEFAULTS; }
  31 server          { return POLL; }
  32 poll            { return POLL; }
  33 skip            { return SKIP; }
  34 via             { return VIA; }
  35 aka             { return AKA; }
  36 local(domains)  { return LOCALDOMAINS; }
  37 proto(col)?     { return PROTOCOL; }
  38 port            { return PORT; }
  39 interval        { return INTERVAL; }
  40 auth(enticate)? { return AUTHENTICATE; }
  41 kerberos_v4     { return KERBEROS4; }
  42 kerberos        { return KERBEROS4; }
  43 timeout         { return TIMEOUT;}
  44 envelope        { return ENVELOPE; }
  45 qvirtual        { return QVIRTUAL; }
  46
  47 user(name)?     { return USERNAME; }
  48 pass(word)?     { return PASSWORD; }
  49 folder(s)?      { return FOLDER; }
  50 smtp(host)?     { return SMTPHOST; }
  51 mda             { return MDA; }
  52 pre(connect)?   { return PRECONNECT; }
  53 post(connect)?  { return POSTCONNECT; }
  54 interface       { return INTERFACE; }
  55 monitor         { return MONITOR; }
  56 batchlimit      { return BATCHLIMIT; }
  57 fetchlimit      { return FETCHLIMIT; }
  58 expunge         { return EXPUNGE; }
  59
  60 is              { return IS; }
  61 here            { return HERE; }
  62 there           { return THERE; }
  63 to              { return TO; }
  64 =               { return MAP; }
  65 "*"             { return WILDCARD; }
  66
  67 no/[kfrsdu \t].*        { return NO;}
  68
  69 keep            { return KEEP; }
  70 flush           { return FLUSH; }
  71 fetchall        { return FETCHALL; }
  72 rewrite         { return REWRITE; }
  73 forcecr         { return FORCECR; }
  74 stripcr         { return STRIPCR; }
  75 pass8(bits)?    { return PASS8BITS; }
  76 dropstatus?     { return DROPSTATUS; }
  77 dns             { return DNS; }
  78 uidl            { return UIDL; }
  79
  80 limit           { return LIMIT; }
  81
  82 with            {/* EMPTY */}
  83 and             {/* EMPTY */}
  84 has             {/* EMPTY */}
  85 wants           {/* EMPTY */}
  86 options         {/* EMPTY */}
  87 [;:,]           {/* EMPTY */}
  88
  89 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
  90 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
  91 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
  92 (imap-k4)|(IMAP-K4)   { yylval.proto = P_IMAP_K4;  return PROTO; }
  93 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
  94 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
  95 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
  96 (kpop)|(KPOP)   { return KPOP; }
  97
  98 remote(folder)? {
  99                 fprintf(stderr,
 100                         "fetchmail: `remote' keyword is gone, use `folder'\n");
 101                 }
 102
 103
 104 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 105
 106 [0-9]+          { yylval.number = atoi(yytext); return NUMBER; }
 107
 108 \"[^\"]*\"      {
 109                         char buf[POPBUFSIZE];
 110
 111                         yytext[strlen(yytext)-1] = '\0';
 112                         escapes(yytext+1, buf);
 113                         yylval.sval = (char *) xstrdup(buf);
 114                         return STRING;
 115                 }
 116 [^=;:, \t\r\n]+ {
 117                         char buf[POPBUFSIZE];
 118
 119                         escapes(yytext, buf);
 120                         yylval.sval = (char *) xstrdup(buf);
 121                         return STRING;
 122                 }
 123
 124 [ \t\r]+        ;       /* whitespace */
 125
 126 %%
 127
 128 void escapes(cp, tp)
 129 /* process standard C-style escape sequences in a string */
 130 const char      *cp;    /* source string with escapes */
 131 char            *tp;    /* target buffer for digested string */
 132 {
 133     while (*cp)
 134     {
 135         int     cval = 0;
 136
 137         if (*cp == '\\' && strchr("0123456789xX", cp[1]))
 138         {
 139             char *dp, *hex = "00112233445566778899aAbBcCdDeEfF";
 140             int dcount = 0;
 141
 142             if (*++cp == 'x' || *cp == 'X')
 143                 for (++cp; (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 144                     cval = (cval * 16) + (dp - hex) / 2;
 145             else if (*cp == '0')
 146                 while (strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 147                     cval = (cval * 8) + (*cp++ - '0');
 148             else
 149                 while ((strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 150                     cval = (cval * 10) + (*cp++ - '0');
 151         }
 152         else if (*cp == '\\')           /* C-style character escapes */
 153         {
 154             switch (*++cp)
 155             {
 156             case '\\': cval = '\\'; break;
 157             case 'n': cval = '\n'; break;
 158             case 't': cval = '\t'; break;
 159             case 'b': cval = '\b'; break;
 160             case 'r': cval = '\r'; break;
 161             default: cval = *cp;
 162             }
 163             cp++;
 164         }
 165         else
 166             cval = *cp++;
 167         *tp++ = cval;
 168     }
 169     *tp = '\0';
 170 }
 171