Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8 #include <string.h>
   9
  10 #include "config.h"
  11 #include "fetchmail.h"
  12 #include "rcfile_y.h"
  13
  14 int prc_lineno = 1;
  15 %}
  16
  17 /* this doesn't work with Linux lex, see the INSTALL file */
  18 %o 7000
  19 %a 4000
  20 %p 3000
  21
  22 %%
  23
  24 set             { return SET; }
  25 logfile         { return LOGFILE; }
  26 idfile          { return IDFILE; }
  27 daemon          { return DAEMON; }
  28 syslog          { return SYSLOG; }
  29 invisible       { return INVISIBLE; }
  30 postmaster      { return POSTMASTER; }
  31 warnings        { return WARNINGS; }
  32
  33 defaults        { return DEFAULTS; }
  34 server          { return POLL; }
  35 poll            { return POLL; }
  36 skip            { return SKIP; }
  37 via             { return VIA; }
  38 aka             { return AKA; }
  39 local(domains)  { return LOCALDOMAINS; }
  40 proto(col)?     { return PROTOCOL; }
  41 service         { return SERVICE; }
  42 port            { return PORT; }
  43 interval        { return INTERVAL; }
  44 auth(enticate)? { return AUTHENTICATE; }
  45 kerberos_v4     { return KERBEROS4; }
  46 kerberos        { return KERBEROS; }
  47 kerberos_v5     { return KERBEROS5; }
  48 timeout         { return TIMEOUT;}
  49 envelope        { return ENVELOPE; }
  50 qvirtual        { return QVIRTUAL; }
  51
  52 user(name)?     { return USERNAME; }
  53 pass(word)?     { return PASSWORD; }
  54 folder(s)?      { return FOLDER; }
  55 smtp(host)?     { return SMTPHOST; }
  56 smtpaddress     { return SMTPADDRESS; }
  57 antispam        { return SPAMRESPONSE; }
  58 mda             { return MDA; }
  59 pre(connect)?   { return PRECONNECT; }
  60 post(connect)?  { return POSTCONNECT; }
  61 netsec          { return NETSEC; }
  62 interface       { return INTERFACE; }
  63 monitor         { return MONITOR; }
  64 batchlimit      { return BATCHLIMIT; }
  65 fetchlimit      { return FETCHLIMIT; }
  66 expunge         { return EXPUNGE; }
  67 properties      { return PROPERTIES; }
  68
  69 is              { return IS; }
  70 here            { return HERE; }
  71 there           { return THERE; }
  72 to              { return TO; }
  73 =               { return MAP; }
  74 "*"             { return WILDCARD; }
  75
  76 no/[kfrsduc \t].*       { return NO;}
  77
  78 keep            { return KEEP; }
  79 flush           { return FLUSH; }
  80 fetchall        { return FETCHALL; }
  81 rewrite         { return REWRITE; }
  82 forcecr         { return FORCECR; }
  83 stripcr         { return STRIPCR; }
  84 pass8(bits)?    { return PASS8BITS; }
  85 dropstatus?     { return DROPSTATUS; }
  86 mimedec(ode)?   { return MIMEDECODE; }
  87 dns             { return DNS; }
  88 uidl            { return UIDL; }
  89 checkalias      { return CHECKALIAS; }
  90
  91 limit           { return LIMIT; }
  92
  93 with            {/* EMPTY */}
  94 and             {/* EMPTY */}
  95 has             {/* EMPTY */}
  96 wants           {/* EMPTY */}
  97 options         {/* EMPTY */}
  98 [;:,]           {/* EMPTY */}
  99
 100 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
 101 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
 102 (sdps)|(SDPS)   { return SDPS; }
 103 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
 104 (imap-k4)|(IMAP-K4)   { yylval.proto = P_IMAP_K4;  return PROTO; }
 105 (imap-gss)|(IMAP-GSS) { yylval.proto = P_IMAP_GSS;  return PROTO; }
 106 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
 107 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
 108 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
 109 (kpop)|(KPOP)   { return KPOP; }
 110
 111 remote(folder)? {
 112                 fprintf(stderr,
 113                         "fetchmail: `remote' keyword is gone, use `folder'\n");
 114                 }
 115
 116
 117 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 118
 119 [0-9]+          { yylval.number = atoi(yytext); return NUMBER; }
 120
 121 \"[^\"]*\"      {
 122                         char buf[MSGBUFSIZE];
 123
 124                         yytext[strlen(yytext)-1] = '\0';
 125                         escapes(yytext+1, buf);
 126                         yylval.sval = (char *) xstrdup(buf);
 127                         return STRING;
 128                 }
 129 [^=;:, \t\r\n]+ {
 130                         char buf[MSGBUFSIZE];
 131
 132                         escapes(yytext, buf);
 133                         yylval.sval = (char *) xstrdup(buf);
 134                         return STRING;
 135                 }
 136
 137 [ \t\r]+        ;       /* whitespace */
 138
 139 %%
 140
 141 void escapes(cp, tp)
 142 /* process standard C-style escape sequences in a string */
 143 const char      *cp;    /* source string with escapes */
 144 char            *tp;    /* target buffer for digested string */
 145 {
 146     while (*cp)
 147     {
 148         int     cval = 0;
 149
 150         if (*cp == '\\' && strchr("0123456789xX", cp[1]))
 151         {
 152             char *dp, *hex = "00112233445566778899aAbBcCdDeEfF";
 153             int dcount = 0;
 154
 155             if (*++cp == 'x' || *cp == 'X')
 156                 for (++cp; (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 157                     cval = (cval * 16) + (dp - hex) / 2;
 158             else if (*cp == '0')
 159                 while (strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 160                     cval = (cval * 8) + (*cp++ - '0');
 161             else
 162                 while ((strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 163                     cval = (cval * 10) + (*cp++ - '0');
 164         }
 165         else if (*cp == '\\')           /* C-style character escapes */
 166         {
 167             switch (*++cp)
 168             {
 169             case '\\': cval = '\\'; break;
 170             case 'n': cval = '\n'; break;
 171             case 't': cval = '\t'; break;
 172             case 'b': cval = '\b'; break;
 173             case 'r': cval = '\r'; break;
 174             default: cval = *cp;
 175             }
 176             cp++;
 177         }
 178         else
 179             cval = *cp++;
 180         *tp++ = cval;
 181     }
 182     *tp = '\0';
 183 }
 184