Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8 #include <string.h>
   9
  10 #include "config.h"
  11 #include "fetchmail.h"
  12 #include "rcfile_y.h"
  13
  14 int prc_lineno = 1;
  15 %}
  16
  17 /* this doesn't work with Linux lex, see the INSTALL file */
  18 %o 7000
  19 %a 4000
  20 %p 3000
  21
  22 %s NAME
  23
  24 %%
  25
  26 \"[^\"]*\"      {
  27                         char buf[MSGBUFSIZE];
  28
  29                         yytext[strlen(yytext)-1] = '\0';
  30                         escapes(yytext+1, buf);
  31                         yylval.sval = (char *) xstrdup(buf);
  32                         BEGIN(0);
  33                         return STRING;
  34                 }
  35 \'[^\']*\'      {
  36                         char buf[MSGBUFSIZE];
  37
  38                         yytext[strlen(yytext)-1] = '\0';
  39                         escapes(yytext+1, buf);
  40                         yylval.sval = (char *) xstrdup(buf);
  41                         BEGIN(0);
  42                         return STRING;
  43                 }
  44
  45 "*"             { BEGIN(0); return WILDCARD; }
  46
  47 <NAME>[^=;:, \t\r\n]+   {
  48                         char buf[MSGBUFSIZE];
  49
  50                         escapes(yytext, buf);
  51                         yylval.sval = (char *) xstrdup(buf);
  52                         BEGIN(0);
  53                         return STRING;
  54                 }
  55
  56 set             { return SET; }
  57 logfile         { return LOGFILE; }
  58 idfile          { return IDFILE; }
  59 daemon          { return DAEMON; }
  60 syslog          { return SYSLOG; }
  61 invisible       { return INVISIBLE; }
  62 postmaster      { return POSTMASTER; }
  63 bouncemail      { return BOUNCEMAIL; }
  64 warnings        { return WARNINGS; }
  65
  66 defaults        { return DEFAULTS; }
  67 server          { return POLL; }
  68 poll            { return POLL; }
  69 skip            { return SKIP; }
  70 via             { return VIA; }
  71 aka             { return AKA; }
  72 local(domains)  { return LOCALDOMAINS; }
  73 proto(col)?     { return PROTOCOL; }
  74 service         { return SERVICE; }
  75 port            { return PORT; }
  76 interval        { return INTERVAL; }
  77 auth(enticate)? { return AUTHENTICATE; }
  78 kerberos(_v)?4  { return KERBEROS4; }
  79 kerberos(_v)?5  { return KERBEROS5; }
  80 kerberos        { return KERBEROS; }
  81 timeout         { return TIMEOUT;}
  82 envelope        { return ENVELOPE; }
  83 qvirtual        { return QVIRTUAL; }
  84
  85 user(name)?     {BEGIN(NAME); return USERNAME; }
  86 pass(word)?     {BEGIN(NAME); return PASSWORD; }
  87 folder(s)?      { return FOLDER; }
  88 smtp(host)?     { return SMTPHOST; }
  89 smtpaddress     { return SMTPADDRESS; }
  90 antispam        { return SPAMRESPONSE; }
  91 mda             { return MDA; }
  92 bsmtp           { return BSMTP; }
  93 lmtp            { return LMTP; }
  94 pre(connect)?   { return PRECONNECT; }
  95 post(connect)?  { return POSTCONNECT; }
  96 netsec          { return NETSEC; }
  97 interface       { return INTERFACE; }
  98 monitor         { return MONITOR; }
  99 plugin          { return PLUGIN; }
 100 plugout         { return PLUGIN; }
 101 batchlimit      { return BATCHLIMIT; }
 102 fetchlimit      { return FETCHLIMIT; }
 103 expunge         { return EXPUNGE; }
 104 properties      { return PROPERTIES; }
 105
 106 is              { BEGIN(NAME); return IS; }
 107 here            { return HERE; }
 108 there           { return THERE; }
 109 to              { BEGIN(NAME); return TO; }
 110 =               { BEGIN(NAME); return MAP; }
 111
 112 nobouncemail    |
 113 nouidl          |
 114 nocheckalias    |
 115 nodns           |
 116 noenvelope      |
 117 nokeep          |
 118 noflush         |
 119 nofetchall      |
 120 norewrite       |
 121 noforcecr       |
 122 nostripcr       |
 123 nopass8(bits)?  |
 124 nodropstatus    |
 125 nomimedec(ode)? {
 126                    yyless(2);
 127                    return NO;
 128                 }
 129
 130 no              {return NO;}
 131
 132 keep            { return KEEP; }
 133 flush           { return FLUSH; }
 134 fetchall        { return FETCHALL; }
 135 rewrite         { return REWRITE; }
 136 forcecr         { return FORCECR; }
 137 stripcr         { return STRIPCR; }
 138 pass8(bits)?    { return PASS8BITS; }
 139 dropstatus      { return DROPSTATUS; }
 140 mimedec(ode)?   { return MIMEDECODE; }
 141 dns             { return DNS; }
 142 uidl            { return UIDL; }
 143 checkalias      { return CHECKALIAS; }
 144
 145 limit           { return LIMIT; }
 146
 147 with            {/* EMPTY */}
 148 and             {/* EMPTY */}
 149 has             {/* EMPTY */}
 150 wants           {/* EMPTY */}
 151 options         {/* EMPTY */}
 152 [;:,]           {/* EMPTY */}
 153
 154 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
 155 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
 156 (sdps)|(SDPS)   { return SDPS; }
 157 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
 158 (imap-k4)|(IMAP-K4)   { yylval.proto = P_IMAP_K4;  return PROTO; }
 159 (imap-gss)|(IMAP-GSS) { yylval.proto = P_IMAP_GSS;  return PROTO; }
 160 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
 161 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
 162 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
 163 (kpop)|(KPOP)   { return KPOP; }
 164
 165 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 166
 167 [0-9]+          { yylval.number = atoi(yytext); return NUMBER; }
 168
 169 [^=;:, \t\r\n]+ {
 170                         char buf[MSGBUFSIZE];
 171
 172                         escapes(yytext, buf);
 173                         yylval.sval = (char *) xstrdup(buf);
 174                         return STRING;
 175                 }
 176
 177 [ \t\r]+        ;       /* whitespace */
 178
 179 %%
 180
 181 void escapes(cp, tp)
 182 /* process standard C-style escape sequences in a string */
 183 const char      *cp;    /* source string with escapes */
 184 char            *tp;    /* target buffer for digested string */
 185 {
 186     while (*cp)
 187     {
 188         int     cval = 0;
 189
 190         if (*cp == '\\' && strchr("0123456789xX", cp[1]))
 191         {
 192             char *dp;
 193             const char *hex = "00112233445566778899aAbBcCdDeEfF";
 194             int dcount = 0;
 195
 196             if (*++cp == 'x' || *cp == 'X')
 197                 for (++cp; (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 198                     cval = (cval * 16) + (dp - hex) / 2;
 199             else if (*cp == '0')
 200                 while (strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 201                     cval = (cval * 8) + (*cp++ - '0');
 202             else
 203                 while ((strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 204                     cval = (cval * 10) + (*cp++ - '0');
 205         }
 206         else if (*cp == '\\')           /* C-style character escapes */
 207         {
 208             switch (*++cp)
 209             {
 210             case '\\': cval = '\\'; break;
 211             case 'n': cval = '\n'; break;
 212             case 't': cval = '\t'; break;
 213             case 'b': cval = '\b'; break;
 214             case 'r': cval = '\r'; break;
 215             default: cval = *cp;
 216             }
 217             cp++;
 218         }
 219         else
 220             cval = *cp++;
 221         *tp++ = cval;
 222     }
 223     *tp = '\0';
 224 }
 225