Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8 #include <string.h>
   9
  10 #include "config.h"
  11 #include "fetchmail.h"
  12 #include "rcfile_y.h"
  13
  14 int prc_lineno = 1;
  15
  16 #ifdef LEXDEBUG
  17 #define SETSTATE(n)     if (yydebug) do {BEGIN(n); fprintf(stderr, "Entering lexer state %d\n", n);} while (0)
  18 #else
  19 #define SETSTATE(n)     BEGIN(n)
  20 #endif /* LEXDEBUG */
  21 %}
  22
  23 /* this doesn't work with Linux lex, see the INSTALL file */
  24 %o 7000
  25 %a 4000
  26 %p 3000
  27
  28 %s NAME PREAUTH
  29
  30 %%
  31
  32 \"[^\"]*\"      {
  33                         char buf[MSGBUFSIZE];
  34
  35                         yytext[strlen(yytext)-1] = '\0';
  36                         escapes(yytext+1, buf);
  37                         yylval.sval = (char *) xstrdup(buf);
  38                         SETSTATE(0);
  39                         return STRING;
  40                 }
  41 \'[^\']*\'      {
  42                         char buf[MSGBUFSIZE];
  43
  44                         yytext[strlen(yytext)-1] = '\0';
  45                         escapes(yytext+1, buf);
  46                         yylval.sval = (char *) xstrdup(buf);
  47                         SETSTATE(0);
  48                         return STRING;
  49                 }
  50
  51 "*"             { BEGIN(0); return WILDCARD; }
  52
  53 <NAME>[^=;:, \t\r\n]+   {
  54                         char buf[MSGBUFSIZE];
  55
  56                         escapes(yytext, buf);
  57                         yylval.sval = (char *) xstrdup(buf);
  58                         SETSTATE(0);
  59                         return STRING;
  60                 }
  61
  62 set             { return SET; }
  63 logfile         { return LOGFILE; }
  64 idfile          { return IDFILE; }
  65 daemon          { return DAEMON; }
  66 syslog          { return SYSLOG; }
  67 invisible       { return INVISIBLE; }
  68 showdots        { return SHOWDOTS; }
  69 postmaster      { return POSTMASTER; }
  70 bouncemail      { return BOUNCEMAIL; }
  71 spambounce      { return SPAMBOUNCE; }
  72 warnings        { return WARNINGS; }
  73
  74 defaults        { return DEFAULTS; }
  75 server          { return POLL; }
  76 poll            { return POLL; }
  77 skip            { return SKIP; }
  78 via             { return VIA; }
  79 aka             { return AKA; }
  80 local(domains)  { return LOCALDOMAINS; }
  81 proto(col)?     { return PROTOCOL; }
  82 service         { return SERVICE; }
  83 port            { return PORT; }
  84 interval        { return INTERVAL; }
  85 preauth(enticate)?      { SETSTATE(PREAUTH); return PREAUTHENTICATE; }
  86 gssapi          { SETSTATE(0); return GSSAPI; }
  87 kerberos(_v)?4  { SETSTATE(0); return KERBEROS4; }
  88 kerberos(_v)?5  { SETSTATE(0); return KERBEROS5; }
  89 kerberos        { SETSTATE(0); return KERBEROS; }
  90 ssh             { SETSTATE(0); return SSH; }
  91 <PREAUTH>password { SETSTATE(0); return PASSWORD; }
  92 timeout         { return TIMEOUT;}
  93 envelope        { return ENVELOPE; }
  94 qvirtual        { return QVIRTUAL; }
  95 principal       { return PRINCIPAL; }
  96
  97 user(name)?     {SETSTATE(NAME); return USERNAME; }
  98 pass(word)?     {SETSTATE(NAME); return PASSWORD; }
  99 folder(s)?      { return FOLDER; }
 100 smtp(host)?     { return SMTPHOST; }
 101 smtpaddress     { return SMTPADDRESS; }
 102 smtpname        { return SMTPNAME; }
 103 antispam        { return SPAMRESPONSE; }
 104 mda             { return MDA; }
 105 bsmtp           { return BSMTP; }
 106 lmtp            { return LMTP; }
 107 pre(connect)?   { return PRECONNECT; }
 108 post(connect)?  { return POSTCONNECT; }
 109 netsec          { return NETSEC; }
 110 interface       { return INTERFACE; }
 111 monitor         { return MONITOR; }
 112 plugin          { return PLUGIN; }
 113 plugout         { return PLUGOUT; }
 114 batchlimit      { return BATCHLIMIT; }
 115 fetchlimit      { return FETCHLIMIT; }
 116 expunge         { return EXPUNGE; }
 117 properties      { return PROPERTIES; }
 118
 119 is              { SETSTATE(NAME); return IS; }
 120 here            { return HERE; }
 121 there           { return THERE; }
 122 to              { SETSTATE(NAME); return TO; }
 123 =               { SETSTATE(NAME); return MAP; }
 124
 125 nobouncemail    |
 126 nouidl          |
 127 nocheckalias    |
 128 nodns           |
 129 noenvelope      |
 130 nokeep          |
 131 noflush         |
 132 nofetchall      |
 133 norewrite       |
 134 noforcecr       |
 135 nostripcr       |
 136 nopass8(bits)?  |
 137 nodropstatus    |
 138 nodropdelivered |
 139 nomimedec(ode)? |
 140 noidle          {
 141                    yyless(2);
 142                    return NO;
 143                 }
 144
 145 no              {return NO;}
 146
 147 keep            { return KEEP; }
 148 flush           { return FLUSH; }
 149 fetchall        { return FETCHALL; }
 150 rewrite         { return REWRITE; }
 151 forcecr         { return FORCECR; }
 152 stripcr         { return STRIPCR; }
 153 pass8(bits)?    { return PASS8BITS; }
 154 dropstatus      { return DROPSTATUS; }
 155 dropdelivered   { return DROPDELIVERED; }
 156 mimedec(ode)?   { return MIMEDECODE; }
 157 idle            { return IDLE; }
 158 dns             { return DNS; }
 159 uidl            { return UIDL; }
 160 ssl             { return SSL; }
 161 sslkey          { return SSLKEY; }
 162 sslcert         { return SSLCERT; }
 163 checkalias      { return CHECKALIAS; }
 164
 165 limit           { return LIMIT; }
 166
 167 with            {/* EMPTY */}
 168 and             {/* EMPTY */}
 169 has             {/* EMPTY */}
 170 wants           {/* EMPTY */}
 171 options         {/* EMPTY */}
 172 [;:,]           {/* EMPTY */}
 173
 174 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
 175 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
 176 (sdps)|(SDPS)   { return SDPS; }
 177 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
 178 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
 179 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
 180 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
 181 (odmr)|(ODMR)   { yylval.proto = P_ODMR;  return PROTO; }
 182 (kpop)|(KPOP)   { return KPOP; }
 183
 184 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 185
 186 -?[0-9]+/[^a-zA-Z]      { yylval.number = atoi(yytext); return NUMBER; }
 187
 188 [^=;:, \t\r\n]+ {
 189                         char buf[MSGBUFSIZE];
 190
 191                         escapes(yytext, buf);
 192                         yylval.sval = (char *) xstrdup(buf);
 193                         return STRING;
 194                 }
 195
 196 [ \t\r]+        ;       /* whitespace */
 197
 198 %%
 199
 200 void escapes(cp, tp)
 201 /* process standard C-style escape sequences in a string */
 202 const char      *cp;    /* source string with escapes */
 203 char            *tp;    /* target buffer for digested string */
 204 {
 205     while (*cp)
 206     {
 207         int     cval = 0;
 208
 209         if (*cp == '\\' && strchr("0123456789xX", cp[1]))
 210         {
 211             char *dp;
 212             const char *hex = "00112233445566778899aAbBcCdDeEfF";
 213             int dcount = 0;
 214
 215             if (*++cp == 'x' || *cp == 'X')
 216                 for (++cp; (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 217                     cval = (cval * 16) + (dp - hex) / 2;
 218             else if (*cp == '0')
 219                 while (strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 220                     cval = (cval * 8) + (*cp++ - '0');
 221             else
 222                 while ((strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 223                     cval = (cval * 10) + (*cp++ - '0');
 224         }
 225         else if (*cp == '\\')           /* C-style character escapes */
 226         {
 227             switch (*++cp)
 228             {
 229             case '\\': cval = '\\'; break;
 230             case 'n': cval = '\n'; break;
 231             case 't': cval = '\t'; break;
 232             case 'b': cval = '\b'; break;
 233             case 'r': cval = '\r'; break;
 234             default: cval = *cp;
 235             }
 236             cp++;
 237         }
 238         else
 239             cval = *cp++;
 240         *tp++ = cval;
 241     }
 242     *tp = '\0';
 243 }
 244