Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8 #include <string.h>
   9
  10 #include "config.h"
  11 #include "fetchmail.h"
  12 #include "rcfile_y.h"
  13
  14 int prc_lineno = 1;
  15 %}
  16
  17 /* this doesn't work with Linux lex, see the INSTALL file */
  18 %o 7000
  19 %a 4000
  20 %p 3000
  21
  22 %%
  23
  24 set             { return SET; }
  25 logfile         { return LOGFILE; }
  26 daemon          { return DAEMON; }
  27 syslog          { return SYSLOG; }
  28 invisible       { return INVISIBLE; }
  29
  30 defaults        { return DEFAULTS; }
  31 server          { return POLL; }
  32 poll            { return POLL; }
  33 skip            { return SKIP; }
  34 via             { return VIA; }
  35 aka             { return AKA; }
  36 local(domains)  { return LOCALDOMAINS; }
  37 proto(col)?     { return PROTOCOL; }
  38 service         { return SERVICE; }
  39 port            { return PORT; }
  40 interval        { return INTERVAL; }
  41 auth(enticate)? { return AUTHENTICATE; }
  42 kerberos_v4     { return KERBEROS4; }
  43 kerberos        { return KERBEROS; }
  44 kerberos_v5     { return KERBEROS5; }
  45 timeout         { return TIMEOUT;}
  46 envelope        { return ENVELOPE; }
  47 qvirtual        { return QVIRTUAL; }
  48
  49 user(name)?     { return USERNAME; }
  50 pass(word)?     { return PASSWORD; }
  51 folder(s)?      { return FOLDER; }
  52 smtp(host)?     { return SMTPHOST; }
  53 smtpaddress     { return SMTPADDRESS; }
  54 antispam        { return SPAMRESPONSE; }
  55 mda             { return MDA; }
  56 pre(connect)?   { return PRECONNECT; }
  57 post(connect)?  { return POSTCONNECT; }
  58 netsec          { return NETSEC; }
  59 interface       { return INTERFACE; }
  60 monitor         { return MONITOR; }
  61 batchlimit      { return BATCHLIMIT; }
  62 fetchlimit      { return FETCHLIMIT; }
  63 expunge         { return EXPUNGE; }
  64
  65 is              { return IS; }
  66 here            { return HERE; }
  67 there           { return THERE; }
  68 to              { return TO; }
  69 =               { return MAP; }
  70 "*"             { return WILDCARD; }
  71
  72 no/[kfrsdu \t].*        { return NO;}
  73
  74 keep            { return KEEP; }
  75 flush           { return FLUSH; }
  76 fetchall        { return FETCHALL; }
  77 rewrite         { return REWRITE; }
  78 forcecr         { return FORCECR; }
  79 stripcr         { return STRIPCR; }
  80 pass8(bits)?    { return PASS8BITS; }
  81 dropstatus?     { return DROPSTATUS; }
  82 mimedec(ode)?   { return MIMEDECODE; }
  83 dns             { return DNS; }
  84 uidl            { return UIDL; }
  85
  86 limit           { return LIMIT; }
  87
  88 with            {/* EMPTY */}
  89 and             {/* EMPTY */}
  90 has             {/* EMPTY */}
  91 wants           {/* EMPTY */}
  92 options         {/* EMPTY */}
  93 [;:,]           {/* EMPTY */}
  94
  95 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
  96 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
  97 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
  98 (imap-k4)|(IMAP-K4)   { yylval.proto = P_IMAP_K4;  return PROTO; }
  99 (imap-gss)|(IMAP-GSS) { yylval.proto = P_IMAP_GSS;  return PROTO; }
 100 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
 101 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
 102 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
 103 (kpop)|(KPOP)   { return KPOP; }
 104
 105 remote(folder)? {
 106                 fprintf(stderr,
 107                         "fetchmail: `remote' keyword is gone, use `folder'\n");
 108                 }
 109
 110
 111 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 112
 113 [0-9]+          { yylval.number = atoi(yytext); return NUMBER; }
 114
 115 \"[^\"]*\"      {
 116                         char buf[MSGBUFSIZE];
 117
 118                         yytext[strlen(yytext)-1] = '\0';
 119                         escapes(yytext+1, buf);
 120                         yylval.sval = (char *) xstrdup(buf);
 121                         return STRING;
 122                 }
 123 [^=;:, \t\r\n]+ {
 124                         char buf[MSGBUFSIZE];
 125
 126                         escapes(yytext, buf);
 127                         yylval.sval = (char *) xstrdup(buf);
 128                         return STRING;
 129                 }
 130
 131 [ \t\r]+        ;       /* whitespace */
 132
 133 %%
 134
 135 void escapes(cp, tp)
 136 /* process standard C-style escape sequences in a string */
 137 const char      *cp;    /* source string with escapes */
 138 char            *tp;    /* target buffer for digested string */
 139 {
 140     while (*cp)
 141     {
 142         int     cval = 0;
 143
 144         if (*cp == '\\' && strchr("0123456789xX", cp[1]))
 145         {
 146             char *dp, *hex = "00112233445566778899aAbBcCdDeEfF";
 147             int dcount = 0;
 148
 149             if (*++cp == 'x' || *cp == 'X')
 150                 for (++cp; (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 151                     cval = (cval * 16) + (dp - hex) / 2;
 152             else if (*cp == '0')
 153                 while (strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 154                     cval = (cval * 8) + (*cp++ - '0');
 155             else
 156                 while ((strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 157                     cval = (cval * 10) + (*cp++ - '0');
 158         }
 159         else if (*cp == '\\')           /* C-style character escapes */
 160         {
 161             switch (*++cp)
 162             {
 163             case '\\': cval = '\\'; break;
 164             case 'n': cval = '\n'; break;
 165             case 't': cval = '\t'; break;
 166             case 'b': cval = '\b'; break;
 167             case 'r': cval = '\r'; break;
 168             default: cval = *cp;
 169             }
 170             cp++;
 171         }
 172         else
 173             cval = *cp++;
 174         *tp++ = cval;
 175     }
 176     *tp = '\0';
 177 }
 178