Pileus Git - ~andy/sunrise/blob - net-wireless/rt2x00-git/rt2x00-git-20070529.ebuild

   1 # Copyright 1999-2008 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 inherit linux-mod
   6
   7 MY_PN="rt2x00-git"
   8
   9 DESCRIPTION="Ralink drivers for rt2400, rt2500, rt61 and rt73 chips (experimental git branch)"
  10 HOMEPAGE="http://rt2x00.serialmonkey.com/"
  11 SRC_URI="http://dev.gentooexperimental.org/~jakub/distfiles/${MY_PN}-${PV}.tar.gz"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="~x86"
  16 IUSE=""
  17
  18 RT2X00_DEVICES="rt2400pci rt2500pci rt2500usb rt61pci rt73usb"
  19 for x in ${RT2X00_DEVICES} ; do
  20         IUSE="${IUSE} ${x}"
  21 done
  22
  23 DEPEND="net-wireless/mac80211
  24         !net-wireless/rt2x00"
  25 RDEPEND="${DEPEND}
  26         rt2400pci? ( net-wireless/eeprom_93cx6 )
  27         rt2500pci? ( net-wireless/eeprom_93cx6 )
  28         rt61pci? ( net-wireless/eeprom_93cx6 net-wireless/crc-itu-t )
  29         rt73usb? ( net-wireless/crc-itu-t )"
  30
  31 S="${WORKDIR}/drivers/net/wireless/mac80211/rt2x00/"
  32
  33 src_unpack() {
  34         unpack ${A}
  35         if use rt61pci || use rt73usb ; then
  36                 echo "CFLAGS += -I/usr/include/mac80211 -I/usr/include/crc-itu-t" \
  37                         "-I/usr/include/eeprom_93cx6 -D CONFIG_RT2X00_LIB_FIRMWARE" >> "${S}"/Makefile
  38         else
  39                 echo "CFLAGS += -I/usr/include/mac80211 -I/usr/include/crc-itu-t" \
  40                         "-I/usr/include/eeprom_93cx6" >> "${S}"/Makefile
  41         fi
  42 }
  43
  44 pkg_setup() {
  45         # check whether any drivers are set in USE
  46         local selected="n"
  47         for i in ${RT2X00_DEVICES} ; do
  48                 if use ${i} ; then
  49                         selected="y"
  50                         break
  51                 fi
  52         done
  53         if [[ ${selected} == "n" ]] ; then
  54                 eerror "You didn't choose any rt2x00 driver to build!"
  55                 die "Add one or more of ${RT2X00_DEVICES} to your USE flags and try again."
  56         fi
  57
  58         CONFIG_CHECK="WIRELESS_EXT"
  59         ERROR_WIRELESS_EXT="${P} requires support for Wireless LAN drivers (non-hamradio) & Wireless Extensions (CONFIG_NET_RADIO)."
  60
  61         MODULE_NAMES="rt2x00lib(net/wireless/mac80211/rt2x00/)"
  62         BUILD_PARAMS="CONFIG_RT2X00=m CONFIG_RT2X00_LIB=m"
  63
  64         for i in ${RT2X00_DEVICES} ; do
  65                 use ${i} && MODULE_NAMES="${MODULE_NAMES} ${i}(net/wireless/mac80211/rt2x00/)"
  66                 use ${i} && BUILD_PARAMS="${BUILD_PARAMS} CONFIG_$(echo -n ${i} | tr '[:lower:]' '[:upper:]')=m"
  67         done
  68
  69         if use rt2400pci || use rt2500pci || use rt61pci ; then
  70                 MODULE_NAMES="${MODULE_NAMES} rt2x00pci(net/wireless/mac80211/rt2x00/)"
  71                 BUILD_PARAMS="${BUILD_PARAMS} CONFIG_RT2X00_LIB_PCI=m"
  72                 CONFIG_CHECK="${CONFIG_CHECK} PCI"
  73         fi
  74
  75         if use rt2500usb || use rt73usb ; then
  76                 MODULE_NAMES="${MODULE_NAMES} rt2x00usb(net/wireless/mac80211/rt2x00/)"
  77                 BUILD_PARAMS="${BUILD_PARAMS} CONFIG_RT2X00_LIB_USB=m"
  78                 CONFIG_CHECK="${CONFIG_CHECK} USB"
  79         fi
  80
  81         if use rt61pci || use rt73usb ; then
  82                 BUILD_PARAMS="${BUILD_PARAMS} CONFIG_RT2X00_LIB_FIRMWARE=m"
  83                 CONFIG_CHECK="${CONFIG_CHECK} FW_LOADER"
  84                 ERROR_FW_LOADER="${P} requires support for Firmware module loading (CONFIG_FW_LOADER)."
  85         fi
  86
  87         linux-mod_pkg_setup
  88         BUILD_TARGETS="modules"
  89         BUILD_PARAMS="${BUILD_PARAMS} -C ${KV_DIR} M=${S} V=1"
  90 }