Pileus Git - ~andy/sunrise/blob - net-wireless/remuco/remuco-0.9.5.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=2
   6 PYTHON_DEPEND="2:2.6"
   7 SUPPORT_PYTHON_ABIS="1"
   8 JAVA_PKG_OPT_USE="client"
   9
  10 inherit distutils python java-pkg-opt-2 java-ant-2
  11
  12 MY_P=${PN}-source-${PV}
  13 DESCRIPTION="A server and J2ME client to control various media players"
  14 HOMEPAGE="http://code.google.com/p/remuco"
  15 SRC_URI="http://${PN}.googlecode.com/files/${MY_P}.tar.gz"
  16
  17 LICENSE="Apache-2.0 GPL-3 LGPL-2.1"
  18 SLOT="0"
  19 KEYWORDS="~amd64 ~x86"
  20 IUSE="amarok audacious banshee exaile gmusicbrowser mpd mplayer quodlibet rhythmbox totem tvtime vlc"
  21
  22 COMMON_DEPEND="dev-python/dbus-python
  23         dev-python/imaging
  24         dev-python/pybluez
  25         dev-python/pygobject:2
  26         dev-python/pyxdg"
  27 DEPEND="${COMMON_DEPEND}
  28         client? (
  29                 >=virtual/jdk-1.1
  30                 dev-java/ant-nodeps
  31                 dev-java/ant-apache-regexp
  32                 dev-java/proguard[ant]
  33         )"
  34 RDEPEND="${COMMON_DEPEND}
  35         amarok? ( >=media-sound/amarok-2.0 )
  36         audacious? ( >=media-sound/audacious-1.5.1 )
  37         banshee? ( >=media-sound/banshee-1.6 )
  38         exaile? ( >=media-sound/exaile-0.3 )
  39         gmusicbrowser? ( media-sound/gmusicbrowser )
  40         mpd? (
  41                 >=media-sound/mpd-0.13.2
  42                 >=dev-python/python-mpd-0.2
  43         )
  44         mplayer? ( || ( media-video/mplayer media-video/mplayer2 ) )
  45         quodlibet? ( >=media-sound/quodlibet-2.2 )
  46         rhythmbox? (
  47                 >=media-sound/rhythmbox-0.11.5
  48                 dev-python/gconf-python
  49         )
  50         totem? ( >=media-video/totem-2.22 )
  51         tvtime? ( >=media-tv/tvtime-0.9.11 )
  52         vlc? ( >=media-video/vlc-0.9[dbus] )"
  53
  54 RESTRICT_PYTHON_ABIS="3.*"
  55 S=${WORKDIR}/${MY_P}
  56
  57 DOCS="doc/AUTHORS doc/CHANGES doc/README doc/api.html"
  58
  59 src_compile() {
  60         local adapter
  61         export REMUCO_CLIENT_DEST="share/${P}/client"
  62         export REMUCO_COMPONENTS
  63
  64         for adapter in ${IUSE}; do
  65                 use ${adapter} && REMUCO_COMPONENTS+="${adapter},"
  66         done
  67         REMUCO_COMPONENTS=${REMUCO_COMPONENTS%,}
  68
  69         distutils_src_compile
  70
  71         if use client; then
  72                 ANT_TASKS="ant-nodeps ant-apache-regexp"
  73                 eant -f client/midp/libgen/build.xml \
  74                         -Dproguard.jar=$(java-pkg_getjars proguard) \
  75                         setup
  76
  77                 eant -f client/midp/build.xml dist
  78         fi
  79 }
  80
  81 pkg_postinst() {
  82         distutils_pkg_postinst
  83
  84         if use client; then
  85                 einfo "The JAR and JAD files for your mobile phone or other J2ME"
  86                 einfo "device can be found in /usr/share/${P}/client"
  87         else
  88                 einfo "Both MIDP and Android clients can be found in the official binary tarball:"
  89                 einfo "http://${PN}.googlecode.com/files/${P}.tar.gz"
  90         fi
  91         einfo
  92         einfo "For the usage info take a look at:"
  93         einfo "${HOMEPAGE}/wiki/GettingStarted#Usage"
  94 }