Pileus Git - ~andy/sunrise/blob - net-wireless/remuco/remuco-0.9.3.ebuild

   1 # Copyright 1999-2010 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=2
   6 PYTHON_DEPEND="2:2.5"
   7 SUPPORT_PYTHON_ABIS="1"
   8 RESTRICT_PYTHON_ABIS="3.*"
   9
  10 inherit distutils python
  11
  12 DESCRIPTION="A server and J2ME client to control various media players"
  13 HOMEPAGE="http://code.google.com/p/remuco"
  14 SRC_URI="http://${PN}.googlecode.com/files/${P}.tar.gz"
  15 LICENSE="GPL-3"
  16 SLOT="0"
  17 KEYWORDS="~amd64 ~x86"
  18 IUSE="amarok audacious banshee exaile mpd mplayer quodlibet rhythmbox totem tvtime vlc"
  19
  20 DEPEND="dev-python/dbus-python
  21         dev-python/imaging
  22         dev-python/pybluez
  23         dev-python/pygobject
  24         dev-python/pyxdg"
  25
  26 RDEPEND="${DEPEND}
  27         amarok? ( >=media-sound/amarok-2.0 )
  28         audacious? ( >=media-sound/audacious-1.5.1 )
  29         banshee? ( >=media-sound/banshee-1.4 )
  30         exaile? ( >=media-sound/exaile-0.3 )
  31         mpd? (
  32                 >=media-sound/mpd-0.13.2
  33                 >=dev-python/python-mpd-0.2
  34         )
  35         mplayer? ( media-video/mplayer )
  36         quodlibet? ( >=media-sound/quodlibet-2.2 )
  37         rhythmbox? (
  38                 >=media-sound/rhythmbox-0.11.5
  39                 dev-python/gconf-python
  40         )
  41         totem? ( >=media-video/totem-2.22 )
  42         tvtime? ( >=media-tv/tvtime-0.9.11 )
  43         vlc? ( >=media-video/vlc-0.9[dbus] )"
  44
  45 DOCS="doc/AUTHORS doc/CHANGES doc/README doc/api.html"
  46
  47 src_compile() {
  48         local adapter
  49         export REMUCO_CLIENT_DEST="share/${P}/client"
  50         export REMUCO_COMPONENTS="client"
  51
  52         for adapter in ${IUSE}; do
  53                 use ${adapter} && REMUCO_COMPONENTS="${REMUCO_COMPONENTS},${adapter}"
  54         done
  55
  56         distutils_src_compile
  57 }
  58
  59 pkg_postinst() {
  60         distutils_pkg_postinst
  61
  62         einfo "The JAR and JAD files for your mobile phone or other J2ME device can"
  63         einfo "be found in /usr/share/${P}/client."
  64         einfo
  65         einfo "For the usage info take a look at:"
  66         einfo "${HOMEPAGE}/wiki/GettingStarted#Usage"
  67 }