Pileus Git - ~andy/sunrise/blob - net-wireless/remuco/remuco-0.9.3.1.ebuild

   1 # Copyright 1999-2010 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=2
   6 PYTHON_DEPEND="2:2.6"
   7 SUPPORT_PYTHON_ABIS="1"
   8 JAVA_PKG_OPT_USE="client"
   9
  10 inherit distutils python java-pkg-opt-2 java-ant-2
  11
  12 MY_P=${PN}-source-${PV}
  13 DESCRIPTION="A server and J2ME client to control various media players"
  14 HOMEPAGE="http://code.google.com/p/remuco"
  15 SRC_URI="http://${PN}.googlecode.com/files/${MY_P}.tar.gz"
  16
  17 LICENSE="Apache-2.0 GPL-3 LGPL-2.1"
  18 SLOT="0"
  19 KEYWORDS="~amd64 ~x86"
  20 IUSE="amarok audacious banshee exaile mpd mplayer quodlibet rhythmbox totem tvtime vlc"
  21
  22 COMMON_DEPEND="dev-python/dbus-python
  23         dev-python/imaging
  24         dev-python/pybluez
  25         dev-python/pygobject
  26         dev-python/pyxdg"
  27 DEPEND="${COMMON_DEPEND}
  28         client? (
  29                 >=virtual/jdk-1.1
  30                 dev-java/ant-nodeps
  31                 dev-java/ant-apache-regexp
  32                 dev-java/proguard[ant]
  33         )"
  34 RDEPEND="${COMMON_DEPEND}
  35         amarok? ( >=media-sound/amarok-2.0 )
  36         audacious? ( >=media-sound/audacious-1.5.1 )
  37         banshee? ( >=media-sound/banshee-1.4 )
  38         exaile? ( >=media-sound/exaile-0.3 )
  39         mpd? (
  40                 >=media-sound/mpd-0.13.2
  41                 >=dev-python/python-mpd-0.2
  42         )
  43         mplayer? ( media-video/mplayer )
  44         quodlibet? ( >=media-sound/quodlibet-2.2 )
  45         rhythmbox? (
  46                 >=media-sound/rhythmbox-0.11.5
  47                 dev-python/gconf-python
  48         )
  49         totem? ( >=media-video/totem-2.22 )
  50         tvtime? ( >=media-tv/tvtime-0.9.11 )
  51         vlc? ( >=media-video/vlc-0.9[dbus] )"
  52
  53 RESTRICT_PYTHON_ABIS="3.*"
  54 S=${WORKDIR}/${MY_P}
  55
  56 DOCS="doc/AUTHORS doc/CHANGES doc/README doc/api.html"
  57
  58 src_compile() {
  59         local adapter
  60         export REMUCO_CLIENT_DEST="share/${P}/client"
  61         export REMUCO_COMPONENTS
  62
  63         for adapter in ${IUSE}; do
  64                 use ${adapter} && REMUCO_COMPONENTS+="${adapter},"
  65         done
  66         REMUCO_COMPONENTS=${REMUCO_COMPONENTS%,}
  67
  68         distutils_src_compile
  69
  70         if use client; then
  71                 ANT_TASKS="ant-nodeps ant-apache-regexp"
  72                 eant -f client/midp/libgen/build.xml \
  73                         -Dproguard.jar=$(java-pkg_getjars proguard) \
  74                         setup
  75
  76                 eant -f client/midp/build.xml dist
  77         fi
  78 }
  79
  80 pkg_postinst() {
  81         distutils_pkg_postinst
  82
  83         if use client; then
  84                 einfo "The JAR and JAD files for your mobile phone or other J2ME"
  85                 einfo "device can be found in /usr/share/${P}/client"
  86         else
  87                 einfo "Both MIDP and Android clients can be found in the official binary tarball:"
  88                 einfo "http://${PN}.googlecode.com/files/${P}.tar.gz"
  89         fi
  90         einfo
  91         einfo "For the usage info take a look at:"
  92         einfo "${HOMEPAGE}/wiki/GettingStarted#Usage"
  93 }