Pileus Git - ~andy/sunrise/blob - media-video/ekd/ekd-2.0.1.20100530.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=2
   6 PYTHON_DEPEND="2:2.5"
   7
   8 inherit eutils python versionator
   9
  10 MY_P=$(version_format_string '${PN}_linux_source_${1}_${2}-${3}_${4}')
  11 DESCRIPTION="Post-production video editing"
  12 HOMEPAGE="http://ekd.tuxfamily.org/"
  13 SRC_URI="http://download.tuxfamily.org/${PN}forum/${PN}/appli/linux/sources/${MY_P}.tar.gz"
  14
  15 LICENSE="GPL-3"
  16 SLOT="0"
  17 KEYWORDS="~amd64"
  18 IUSE=""
  19
  20 RDEPEND="virtual/libintl
  21         dev-python/imaging
  22         dev-python/numpy
  23         dev-python/PyQt4[X]
  24         media-gfx/imagemagick
  25         media-video/ffmpeg2theora
  26         media-video/mjpegtools
  27         media-video/mplayer
  28         media-sound/lame
  29         media-sound/sox"
  30
  31 S=${WORKDIR}/${MY_P}
  32
  33 src_prepare() {
  34         python_convert_shebangs 2 ekd_gui.py
  35
  36         # Upstream's configure/Makefile just mindlessly copies the files over
  37         # and using it requires much more effort than doing that by hand.
  38         rm -f configure.in Makefile.in || die
  39 }
  40
  41 src_install() {
  42         insinto /usr/share/${PN}
  43         doins -r * || die
  44
  45         fperms +x /usr/share/${PN}/ekd_gui.py || die
  46         make_wrapper ${PN} ./ekd_gui.py /usr/share/${PN}
  47
  48         dodoc README_LISEZMOI.txt || die
  49
  50         doicon icone_${PN}.png || die
  51         make_desktop_entry ${PN} EKD icone_${PN}
  52 }