Pileus Git - ~andy/sunrise/blob - media-video/ekd/ekd-2.0.1.20100530.ebuild

   1 # Copyright 1999-2010 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=2
   6 PYTHON_DEPEND="2:2.5"
   7
   8 inherit eutils python versionator
   9
  10 format_version_string() {
  11         local fstr=$1
  12         set -- $(get_version_components)
  13         eval echo "${fstr}"
  14 }
  15
  16 MY_P=$(format_version_string '${PN}_linux_source_${1}_${2}-${3}_${4}')
  17 DESCRIPTION="Post-production video editing"
  18 HOMEPAGE="http://ekd.tuxfamily.org/"
  19 SRC_URI="http://download.tuxfamily.org/${PN}forum/${PN}/appli/linux/sources/${MY_P}.tar.gz"
  20
  21 LICENSE="GPL-3"
  22 SLOT="0"
  23 KEYWORDS="~amd64"
  24 IUSE=""
  25
  26 RDEPEND="virtual/libintl
  27         dev-python/imaging
  28         dev-python/numpy
  29         dev-python/PyQt4[X]
  30         media-gfx/imagemagick
  31         media-video/ffmpeg2theora
  32         media-video/mjpegtools
  33         media-video/mplayer
  34         media-sound/lame
  35         media-sound/sox"
  36
  37 S=${WORKDIR}/${MY_P}
  38
  39 src_prepare() {
  40         python_convert_shebangs 2 ekd_gui.py
  41
  42         # Upstream's configure/Makefile just mindlessly copies the files over
  43         # and using it requires much more effort than doing that by hand.
  44         rm -f configure.in Makefile.in || die
  45 }
  46
  47 src_install() {
  48         insinto /usr/share/${PN}
  49         doins -r * || die
  50
  51         fperms +x /usr/share/${PN}/ekd_gui.py || die
  52         make_wrapper ${PN} ./ekd_gui.py /usr/share/${PN}
  53
  54         dodoc README_LISEZMOI.txt || die
  55
  56         doicon icone_${PN}.png || die
  57         make_desktop_entry ${PN} EKD icone_${PN}
  58 }