Pileus Git - ~andy/sunrise/blob - media-sound/gnormalize/gnormalize-0.63-r1.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI="4"
   6
   7 inherit eutils
   8
   9 DESCRIPTION="Audio converter/ripper featuring normalization and metadata editing"
  10 HOMEPAGE="http://gnormalize.sourceforge.net/"
  11 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE="aac cddb flac mp3 musepack normalize vorbis"
  17
  18 RDEPEND="
  19         x11-libs/gtk+:2
  20         >=dev-perl/gtk2-perl-1.040
  21         aac? (
  22                 media-libs/faac
  23                 media-libs/faad2 )
  24         cddb? (
  25                 dev-perl/CDDB_get
  26                 media-sound/cdcd
  27                 || (
  28                         media-sound/cdparanoia
  29                         virtual/cdrtools ) )
  30         flac? (
  31                 media-libs/flac
  32                 !vorbis? ( media-sound/flac123 ) )
  33         mp3? (
  34                 media-sound/lame
  35                 dev-perl/MP3-Info
  36                 || (
  37                         media-sound/madplay
  38                         media-sound/mpg321
  39                         media-sound/mpg123 ) )
  40         musepack? ( media-sound/musepack-tools )
  41         normalize? ( media-sound/wavegain )
  42         vorbis? ( media-sound/vorbis-tools )"
  43 DEPEND="${RDEPEND}"
  44
  45 src_unpack() {
  46         unpack ${A}
  47         cd "${S}"
  48         unpack ./${PN}.1.lzma
  49 }
  50
  51 src_install() {
  52         dobin ${PN} || die "dobin failed"
  53
  54         insinto /usr/share/${PN}
  55         doins -r animations || die "doins failed"
  56
  57         doicon icons/${PN}.png || die "doicon failed"
  58         make_desktop_entry ${PN} ${PN} /usr/share/pixmaps/${PN}.png "AudioVideo;Audio;AudioVideoEditing"
  59
  60         doman ${PN}.1 || die "doman failed"
  61         dodoc README || die "dodoc failed"
  62 }
  63
  64 pkg_postinst() {
  65         einfo "This package supports MAC (Monkey's Audio Codec) but due to licensing"
  66         einfo "issues MAC cannot be included in Portage at this time. If you need MAC"
  67         einfo "functionality, build and install the packages 'mac' and 'xmms-mac' from:"
  68         einfo
  69         einfo "    http://sourceforge.net/project/showfiles.php?group_id=123827"
  70 }