Pileus Git - ~andy/sunrise/blob - media-radio/xastir/xastir-1.9.4.ebuild

   1 # Copyright 1999-2009 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 inherit autotools eutils
   6
   7 DESCRIPTION="X Amateur Station Tracking and Information Reporting"
   8 HOMEPAGE="http://xastir.sourceforge.net/"
   9 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~x86"
  14 IUSE="festival gdal geotiff imagemagick"
  15
  16 DEPEND="x11-libs/openmotif
  17         x11-libs/libXpm
  18         x11-apps/xfontsel
  19         dev-libs/libpcre
  20         net-misc/curl
  21         sys-libs/db
  22         sci-libs/shapelib
  23         geotiff? ( sci-libs/proj
  24                 sci-libs/libgeotiff
  25                 media-libs/tiff )
  26         gdal? ( sci-libs/gdal )
  27         imagemagick? ( >=media-gfx/imagemagick-6.4 )
  28         festival? ( app-accessibility/festival )"
  29 RDEPEND="${DEPEND}"
  30
  31 src_unpack() {
  32         unpack ${A}
  33         cd "${S}"
  34         # fix some scripts with DOS line endings
  35         edos2unix scripts/toporama*
  36         # fix for different install directory in scripts
  37         epatch "${FILESDIR}/${P}-scripts.diff" \
  38             "${FILESDIR}/${P}-config.diff"
  39         eautoreconf
  40 }
  41
  42 src_compile() {
  43         econf --without-graphicsmagick \
  44                 --with-pcre \
  45                 --with-shapelib \
  46                 --with-dbfawk \
  47                 --without-ax25 \
  48                 --without-gpsman \
  49                 $(use_with geotiff libproj) \
  50                 $(use_with geotiff) \
  51                 $(use_with gdal) \
  52                 $(use_with imagemagick) \
  53                 $(use_with festival)
  54         emake || die "emake failed"
  55 }
  56
  57 src_install() {
  58         emake DESTDIR="${D}" install || die "emake install failed"
  59         # make doc more Gentoo like
  60         rm -rf "${D}/usr/share/doc/xastir"
  61         dodoc AUTHORS ChangeLog FAQ README README.Contributing \
  62                 README.Getting-Started README.MAPS || die "dodoc failed"
  63 }
  64
  65 pkg_postinst() {
  66         elog "Kernel mode AX.25 not supported."
  67         elog "GPSman library not supported."
  68         elog
  69         elog "Remember you have to be root to add addditional scripts,"
  70         elog "maps and other configuration data under /usr/share/xastir"
  71         elog "/usr/lib/xastir."
  72 }