Pileus Git - ~andy/sunrise/blob - media-plugins/gimp-normalmap/gimp-normalmap-1.2.2-r1.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=2
   6
   7 inherit toolchain-funcs
   8
   9 DESCRIPTION="Gimp plug-in for converting images into RGB normal maps"
  10 HOMEPAGE="http://code.google.com/p/gimp-normalmap/"
  11 SRC_URI="http://gimp-normalmap.googlecode.com/files/${P}.tar.bz2"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE=""
  17
  18 RDEPEND="media-gfx/gimp
  19         media-libs/glew
  20         x11-libs/gtkglext"
  21 DEPEND="${RDEPEND}
  22         virtual/pkgconfig"
  23
  24 src_prepare() {
  25         sed -e 's:\(CFLAGS\)=-O3:\1+=:' \
  26                 -e 's:-L/usr/X11R6/lib::' \
  27                 -i Makefile.linux || die
  28 }
  29
  30 src_compile() {
  31         local cc=$(tc-getCC)
  32         emake CC="${cc}" LD="${cc}" LDFLAGS="${LDFLAGS}" || die "emake failed"
  33 }
  34
  35 src_install() {
  36         exeinto $(pkg-config --variable=gimplibdir gimp-2.0)/plug-ins
  37         doexe normalmap || die "Installation failed"
  38         dodoc README || die
  39 }
  40
  41 pkg_postinst() {
  42         elog "The GIMP normalmap plugin is accessible from the menu:"
  43         elog "Filters -> Map -> Normalmap"
  44 }