Pileus Git - ~andy/sunrise/blob - media-libs/oyranos/oyranos-0.1.9.ebuild

   1 # Copyright 1999-2010 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=2
   6
   7 inherit toolchain-funcs
   8
   9 DESCRIPTION="Color Management System (CMS) on the operating system level"
  10 HOMEPAGE="http://www.oyranos.org/"
  11 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE="debug doc X xinerama"
  17
  18 RDEPEND="app-admin/elektra
  19         dev-libs/libxml2
  20         media-libs/jpeg
  21         media-libs/lcms
  22         media-libs/libpng
  23         sys-devel/gettext
  24         sys-devel/libtool
  25         sys-libs/zlib
  26         virtual/opengl
  27         X? (
  28                 x11-libs/libX11
  29                 x11-libs/libXext
  30                 x11-libs/libXxf86vm
  31                 x11-libs/fltk:1.1
  32                 xinerama? ( x11-libs/libXinerama )
  33         )"
  34 DEPEND="${RDEPEND}
  35         doc? ( app-doc/doxygen )
  36         X? ( x11-proto/xf86vidmodeproto
  37                 xinerama? ( x11-proto/xineramaproto )
  38         )"
  39
  40 src_prepare() {
  41         # remove X11R6/g++ from include/lib paths
  42         sed -i -e 's:/X11R6::' configure{,.sh} {,fl_i18n/}makefile.in || die
  43         sed -i -e 's: -I/usr/include/g++ : :' fl_i18n/makefile.in || die
  44
  45         # leave custom flags untouched, do not remove -O1 from LDFLAGS=-Wl,-O1
  46         sed -i -e 's:STRIPOPT="sed s/-O.//":STRIPOPT="cat":' configure || die
  47         sed -i -e 's:s/-O.// ;::' configure.sh || die
  48
  49         # ${S}/oyranos-config is not in PATH
  50         sed -i -e 's:oyranos-config :./\0:' configure.sh makefile.in || die
  51
  52         # force version number at /usr/share/doc
  53         sed -i -e 's:$(datadir)/doc/$(TARGET):\0-$(VERSION):' makefile.in || die
  54
  55         # configure.sh calls doxygen --help which is not needed w/o USE=doc, silence QA
  56         use doc || { sed -i -e 's:doxygen:#\0:' configure.sh || die ; }
  57 }
  58
  59 src_configure() {
  60         tc-export CC CXX
  61         econf $(use_enable debug) \
  62                 $(use_enable X libX11) \
  63                 $(use_enable X libXext) \
  64                 $(use_enable X libXxf86vm) \
  65                 $(use_enable xinerama libXinerama)
  66 }
  67
  68 src_compile() {
  69         emake lib${PN}.so.${PV} || die
  70         emake || die
  71 }
  72
  73 src_install() {
  74         emake DESTDIR="${D}" install_bin || die
  75         emake DESTDIR="${D}" install_linguas || die
  76         emake DESTDIR="${D}" install-icc || die
  77         if use doc ; then
  78                 emake DESTDIR="${D}" install_docu || die
  79                 rm "${D}/usr/share/doc/${P}/COPYING" || die
  80         fi
  81         dodoc AUTHORS ChangeLog README || die
  82 }