Pileus Git - ~andy/gtk/blob - gtk.m4

   1 # Configure paths for GTK+
   2 # Owen Taylor     97-11-3
   3
   4 dnl AM_PATH_GTK([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
   5 dnl Test for GTK, and define GTK_CFLAGS and GTK_LIBS
   6 dnl
   7 AC_DEFUN(AM_PATH_GTK,
   8 [dnl
   9 dnl Get the cflags and libraries from the gtk-config script
  10 dnl
  11 AC_ARG_WITH(gtk-prefix,[  --with-gtk-prefix=PFX   Prefix where GTK is installed (optional)],
  12             gtk_config_prefix="$withval", gtk_config_prefix="")
  13 AC_ARG_WITH(gtk-exec-prefix,[  --with-gtk-exec-prefix=PFX Exec prefix where GTK is installed (optional)],
  14             gtk_config_exec_prefix="$withval", gtk_config_exec_prefix="")
  15 AC_ARG_ENABLE(gtktest, [  --disable-gtktest       Do not try to compile and run a test GTK program],
  16                     , enable_gtktest=yes)
  17
  18   if test x$gtk_config_exec_prefix != x ; then
  19      gtk_config_args="$gtk_config_args --exec-prefix=$gtk_config_exec_prefix"
  20      if test x${GTK_CONFIG+set} != xset ; then
  21         GTK_CONFIG=$gtk_config_exec_prefix/bin/gtk-config
  22      fi
  23   fi
  24   if test x$gtk_config_prefix != x ; then
  25      gtk_config_args="$gtk_config_args --prefix=$gtk_config_prefix"
  26      if test x${GTK_CONFIG+set} != xset ; then
  27         GTK_CONFIG=$gtk_config_prefix/bin/gtk-config
  28      fi
  29   fi
  30
  31   AC_PATH_PROG(GTK_CONFIG, gtk-config, no)
  32   min_gtk_version=ifelse([$1], ,0.99.7,$1)
  33   AC_MSG_CHECKING(for GTK - version >= $min_gtk_version)
  34   no_gtk=""
  35   if test "$GTK_CONFIG" = "no" ; then
  36     no_gtk=yes
  37   else
  38     GTK_CFLAGS=`$GTK_CONFIG $gtk_config_args --cflags`
  39     GTK_LIBS=`$GTK_CONFIG $gtk_config_args --libs`
  40     gtk_config_major_version=`$GTK_CONFIG $gtk_config_args --version | \
  41            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
  42     gtk_config_minor_version=`$GTK_CONFIG $gtk_config_args --version | \
  43            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
  44     gtk_config_micro_version=`$GTK_CONFIG $gtk_config_args --version | \
  45            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
  46     if test "x$enable_gtktest" = "xyes" ; then
  47       ac_save_CFLAGS="$CFLAGS"
  48       ac_save_LIBS="$LIBS"
  49       CFLAGS="$CFLAGS $GTK_CFLAGS"
  50       LIBS="$LIBS $GTK_LIBS"
  51 dnl
  52 dnl Now check if the installed GTK is sufficiently new. (Also sanity
  53 dnl checks the results of gtk-config to some extent
  54 dnl
  55       rm -f conf.gtktest
  56       AC_TRY_RUN([
  57 #include <gtk/gtk.h>
  58 #include <stdio.h>
  59
  60 int
  61 main ()
  62 {
  63   int major, minor, micro;
  64   char *tmp_version;
  65
  66   system ("touch conf.gtktest");
  67
  68   /* HP/UX 9 (%@#!) writes to sscanf strings */
  69   tmp_version = g_strdup("$min_gtk_version");
  70   if (sscanf(tmp_version, "%d.%d.%d", &major, &minor, &micro) != 3) {
  71      printf("%s, bad version string\n", "$min_gtk_version");
  72      exit(1);
  73    }
  74
  75   if ((gtk_major_version != $gtk_config_major_version) ||
  76       (gtk_minor_version != $gtk_config_minor_version) ||
  77       (gtk_micro_version != $gtk_config_micro_version))
  78     {
  79       printf("\n*** 'gtk-config --version' returned %d.%d.%d, but GTK+ (%d.%d.%d)\n",
  80              $gtk_config_major_version, $gtk_config_minor_version, $gtk_config_micro_version,
  81              gtk_major_version, gtk_minor_version, gtk_micro_version);
  82       printf ("*** was found! If gtk-config was correct, then it is best\n");
  83       printf ("*** to remove the old version of GTK+. You may also be able to fix the error\n");
  84       printf("*** by modifying your LD_LIBRARY_PATH enviroment variable, or by editing\n");
  85       printf("*** /etc/ld.so.conf. Make sure you have run ldconfig if that is\n");
  86       printf("*** required on your system.\n");
  87       printf("*** If gtk-config was wrong, set the environment variable GTK_CONFIG\n");
  88       printf("*** to point to the correct copy of gtk-config, and remove the file config.cache\n");
  89       printf("*** before re-running configure\n");
  90     }
  91   else
  92     {
  93       if ((gtk_major_version > major) ||
  94         ((gtk_major_version == major) && (gtk_minor_version > minor)) ||
  95         ((gtk_major_version == major) && (gtk_minor_version == minor) && (gtk_micro_version >= micro)))
  96       {
  97         return 0;
  98        }
  99      else
 100       {
 101         printf("\n*** An old version of GTK+ (%d.%d.%d) was found.\n",
 102                gtk_major_version, gtk_minor_version, gtk_micro_version);
 103         printf("*** You need a version of GTK+ newer than %d.%d.%d. The latest version of\n",
 104                major, minor, micro);
 105         printf("*** GTK+ is always available from ftp://ftp.gtk.org.\n");
 106         printf("***\n");
 107         printf("*** If you have already installed a sufficiently new version, this error\n");
 108         printf("*** probably means that the wrong copy of the gtk-config shell script is\n");
 109         printf("*** being found. The easiest way to fix this is to remove the old version\n");
 110         printf("*** of GTK+, but you can also set the GTK_CONFIG environment to point to the\n");
 111         printf("*** correct copy of gtk-config. (In this case, you will have to\n");
 112         printf("*** modify your LD_LIBRARY_PATH enviroment variable, or edit /etc/ld.so.conf\n");
 113         printf("*** so that the correct libraries are found at run-time))\n");
 114       }
 115     }
 116   return 1;
 117 }
 118 ],, no_gtk=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 119        CFLAGS="$ac_save_CFLAGS"
 120        LIBS="$ac_save_LIBS"
 121      fi
 122   fi
 123   if test "x$no_gtk" = x ; then
 124      AC_MSG_RESULT(yes)
 125      ifelse([$2], , :, [$2])
 126   else
 127      AC_MSG_RESULT(no)
 128      if test "$GTK_CONFIG" = "no" ; then
 129        echo "*** The gtk-config script installed by GTK could not be found"
 130        echo "*** If GTK was installed in PREFIX, make sure PREFIX/bin is in"
 131        echo "*** your path, or set the GTK_CONFIG environment variable to the"
 132        echo "*** full path to gtk-config."
 133      else
 134        if test -f conf.gtktest ; then
 135         :
 136        else
 137           echo "*** Could not run GTK test program, checking why..."
 138           CFLAGS="$CFLAGS $GTK_CFLAGS"
 139           LIBS="$LIBS $GTK_LIBS"
 140           AC_TRY_LINK([
 141 #include <gtk/gtk.h>
 142 #include <stdio.h>
 143 ],      [ return ((gtk_major_version) || (gtk_minor_version) || (gtk_micro_version)); ],
 144         [ echo "*** The test program compiled, but did not run. This usually means"
 145           echo "*** that the run-time linker is not finding GTK or finding the wrong"
 146           echo "*** version of GTK. If it is not finding GTK, you'll need to set your"
 147           echo "*** LD_LIBRARY_PATH environment variable, or edit /etc/ld.so.conf to point"
 148           echo "*** to the installed location  Also, make sure you have run ldconfig if that"
 149           echo "*** is required on your system"
 150           echo "***"
 151           echo "*** If you have an old version installed, it is best to remove it, although"
 152           echo "*** you may also be able to get things to work by modifying LD_LIBRARY_PATH"
 153           echo "***"
 154           echo "*** If you have a RedHat 5.0 system, you should remove the GTK package that"
 155           echo "*** came with the system with the command"
 156           echo "***"
 157           echo "***    rpm --erase --nodeps gtk gtk-devel" ],
 158         [ echo "*** The test program failed to compile or link. See the file config.log for the"
 159           echo "*** exact error that occured. This usually means GTK was incorrectly installed"
 160           echo "*** or that you have moved GTK since it was installed. In the latter case, you"
 161           echo "*** may want to edit the gtk-config script: $GTK_CONFIG" ])
 162           CFLAGS="$ac_save_CFLAGS"
 163           LIBS="$ac_save_LIBS"
 164        fi
 165      fi
 166      GTK_CFLAGS=""
 167      GTK_LIBS=""
 168      ifelse([$3], , :, [$3])
 169   fi
 170   AC_SUBST(GTK_CFLAGS)
 171   AC_SUBST(GTK_LIBS)
 172   rm -f conf.gtktest
 173 ])