Pileus Git - ~andy/sunrise/blob - gnome-extra/desktop-effects/desktop-effects-0.8.6.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=2
   6
   7 inherit autotools eutils gnome2
   8
   9 DESCRIPTION="Switch GNOME window management and effects between metacity, gnome-shell, compiz"
  10 HOMEPAGE="http://git.fedoraproject.org/git/desktop-effects.git"
  11 SRC_URI="https://fedorahosted.org/released/${PN}/${P}.tar.bz2"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE=""
  17
  18 COMMON_DEPEND="gnome-base/gconf
  19         gnome-base/libglade
  20         media-libs/mesa
  21         x11-libs/gtk+:2
  22         x11-libs/libXcomposite"
  23 DEPEND="${COMMON_DEPEND}
  24         dev-libs/glib:2
  25         dev-util/desktop-file-utils
  26         dev-util/intltool"
  27 RDEPEND="${COMMON_DEPEND}
  28         gnome-base/gnome-session"
  29
  30 DOCS=( ChangeLog )
  31
  32 pkg_setup() {
  33         if has_version x11-wm/compiz && ! has_version x11-libs/compizconfig-backend-gconf ; then
  34                 ewarn "You should install and activate x11-libs/compizconfig-backend-gconf"
  35                 ewarn "for x11-wm/compiz to get CCSM changes and compiz option from ${PN} saved."
  36                 ewarn "Please see https://bugzilla.redhat.com/show_bug.cgi?id=532229 for details"
  37         fi
  38 }
  39
  40 src_prepare() {
  41         # adds the format string to gtk_message_dialog_new
  42         epatch "${FILESDIR}/${P}-gtk-2.20-fix.patch"
  43
  44         #Gentoo doesn't have compiz-gtk, replace it and add gconf to start string
  45         sed -i -e 's/compiz-gtk/compiz/' desktop-effects.c || die
  46         sed -i -e 's/compiz --replace/compiz gconf --replace/' desktop-effects.c || die
  47
  48         glib-gettextize || die
  49         intltoolize --copy --force --automake || die
  50         eautoreconf
  51 }
  52
  53 src_install() {
  54         gnome2_src_install
  55         desktop-file-validate "${D}/usr/share/applications/${PN}.desktop" || die
  56 }