Pileus Git - ~andy/gtk/blob - glib/configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT(glist.c)
   3
   4 # Save this value here, since automake will set cflags later
   5 cflags_set=${CFLAGS+set}
   6
   7 dnl Initialize automake stuff
   8 AM_INIT_AUTOMAKE(glib, 0.99.3)
   9
  10 # Specify a configuration file
  11 AM_CONFIG_HEADER(glibconfig.h)
  12
  13 dnl Initialize libtool
  14 AM_PROG_LIBTOOL
  15
  16 dnl Initialize maintainer mode
  17 AM_MAINTAINER_MODE
  18
  19 AC_CANONICAL_HOST
  20
  21 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=minimum]],,enable_debug=minimum)
  22
  23 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
  24                     , enable_ansi=no)
  25
  26 if test "x$enable_debug" = "xyes"; then
  27   test "$cflags_set" = set || CFLAGS="-g"
  28   CFLAGS="$CFLAGS -DG_ENABLE_DEBUG"
  29 else
  30   if test "x$enable_debug" = "xno"; then
  31     CFLAGS="$CFLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
  32   fi
  33 fi
  34
  35 # Checks for programs.
  36 AC_PROG_CC
  37 AM_PROG_CC_STDC
  38 AC_PROG_INSTALL
  39
  40 if eval "test x$GCC = xyes"; then
  41   if eval test -z \"`echo "$CFLAGS" | grep "\-Wall" 2> /dev/null`\" ; then
  42     CFLAGS="$CFLAGS -Wall"
  43   fi
  44
  45   if eval "test x$enable_ansi = xyes"; then
  46     if eval test -z \"`echo "$CFLAGS" | grep "\-ansi" 2> /dev/null`\" ; then
  47       CFLAGS="$CFLAGS -ansi"
  48     fi
  49
  50     if eval test -z \"`echo "$CFLAGS" | grep "\-pedantic" 2> /dev/null`\" ; then
  51       CFLAGS="$CFLAGS -pedantic"
  52     fi
  53   fi
  54 fi
  55
  56 # Checks for header files.
  57 AC_HEADER_STDC
  58
  59 # Checks for library functions.
  60 AC_FUNC_VPRINTF
  61
  62 AC_CHECK_SIZEOF(char)
  63 AC_CHECK_SIZEOF(short)
  64 AC_CHECK_SIZEOF(long)
  65 AC_CHECK_SIZEOF(int)
  66 AC_CHECK_SIZEOF(void *)
  67
  68 # long doubles were not used, and a portability problem
  69 # AC_C_LONG_DOUBLE
  70 AC_C_CONST
  71 AC_C_INLINE
  72
  73 AC_CHECK_HEADERS(float.h, AC_DEFINE(HAVE_FLOAT_H))
  74 AC_CHECK_HEADERS(limits.h, AC_DEFINE(HAVE_LIMITS_H))
  75 AC_CHECK_HEADERS(values.h, AC_DEFINE(HAVE_VALUES_H))
  76
  77 # Check for strerror, strsignal, memmove, vsnprintf, and strcasecmp functions
  78 AC_CHECK_FUNCS(strerror strsignal memmove vsnprintf strcasecmp)
  79
  80 # Check for sys_errlist
  81 AC_MSG_CHECKING(sys_errlist)
  82 AC_TRY_LINK(, [
  83 extern char *sys_errlist[];
  84 extern int sys_nerr;
  85 sys_errlist[sys_nerr-1][0] = 0;
  86 ], glib_ok=yes, glib_ok=no)
  87 AC_MSG_RESULT($glib_ok)
  88 if test $glib_ok = no; then
  89     AC_DEFINE(NO_SYS_ERRLIST)
  90 fi
  91
  92 # Check for sys_siglist
  93 AC_MSG_CHECKING(sys_siglist)
  94 AC_TRY_LINK(, [
  95 extern char *sys_siglist[];
  96 sys_siglist[1][0] = 0;
  97 ], glib_ok=yes, glib_ok=no)
  98 AC_MSG_RESULT($glib_ok)
  99 if test $glib_ok = no; then
 100     AC_DEFINE(NO_SYS_SIGLIST)
 101 fi
 102
 103 # Check for sys/select.h
 104
 105 AC_MSG_CHECKING([fd_set and sys/select])
 106 AC_TRY_COMPILE([#include <sys/types.h>],
 107         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 108 if test $gtk_ok = no; then
 109     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 110     if test $gtk_ok = yes; then
 111         AC_DEFINE(HAVE_SYS_SELECT_H)
 112     fi
 113 fi
 114 AC_MSG_RESULT($gtk_ok)
 115 if test $gtk_ok = no; then
 116     AC_DEFINE(NO_FD_SET)
 117 fi
 118
 119 # This stuff is here, only so that we can define these
 120 # things in glibconfig.h. If ../config.h was installed
 121 # (under some other name?) then the definitions would
 122 # belong there. (They are only used in GDK)
 123
 124 # Check for wchar.h
 125
 126 AC_MSG_CHECKING(for wchar.h)
 127 AC_TRY_CPP([#include <wchar.h>], gtk_ok=yes, gtk_ok=no)
 128 if test $gtk_ok = yes; then
 129    AC_DEFINE(HAVE_WCHAR_H)
 130 fi
 131 AC_MSG_RESULT($gtk_ok)
 132
 133 # Check for wctype.h (for iswalnum)
 134
 135 AC_MSG_CHECKING(for wctype.h)
 136 AC_TRY_CPP([#include <wctype.h>], gtk_ok=yes, gtk_ok=no)
 137 if test $gtk_ok = yes; then
 138    AC_DEFINE(HAVE_WCTYPE_H)
 139 fi
 140 AC_MSG_RESULT($gtk_ok)
 141
 142 # The following is necessary for Linux libc-5.4.38
 143
 144 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 145 AC_TRY_LINK([#include <stdlib.h>],[
 146 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 147 #  ifdef HAVE_WCTYPE_H
 148 #    include <wctype.h>
 149 #  else
 150 #    ifdef HAVE_WCHAR_H
 151 #      include <wchar.h>
 152 #    endif
 153 #  endif
 154 #else
 155 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 156 #endif
 157 iswalnum((wchar_t) 0);
 158 ], gtk_ok=yes, gtk_ok=no)
 159
 160 if test $gtk_ok = no; then
 161    AC_DEFINE(HAVE_BROKEN_WCTYPE)
 162 fi
 163 AC_MSG_RESULT($gtk_ok)
 164
 165 AC_OUTPUT(Makefile)